File: double-slash-root.m4

package info (click to toggle)
cpio 2.9-13lenny1
  • links: PTS, VCS
  • area: main
  • in suites: lenny
  • size: 5,440 kB
  • ctags: 4,093
  • sloc: ansic: 28,096; sh: 5,955; yacc: 1,208; makefile: 228; sed: 16
file content (38 lines) | stat: -rw-r--r-- 1,452 bytes parent folder | download | duplicates (13)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# double-slash-root.m4 serial 2   -*- Autoconf -*-
dnl Copyright (C) 2006 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_DOUBLE_SLASH_ROOT],
[
  AC_REQUIRE([AC_CANONICAL_HOST])
  AC_CACHE_CHECK([whether // is distinct from /], [gl_cv_double_slash_root],
    [ if test x"$cross_compiling" = xyes ; then
	# When cross-compiling, there is no way to tell whether // is special
	# short of a list of hosts.  However, the only known hosts to date
	# that have a distinct // are Apollo DomainOS (too old to port to),
	# Cygwin, and z/OS.  If anyone knows of another system for which // has
	# special semantics and is distinct from /, please report it to
	# <bug-gnulib@gnu.org>.
	case $host in
	  *-cygwin | i370-ibm-openedition)
	    gl_cv_double_slash_root=yes ;;
	  *)
	    # Be optimistic and assume that / and // are the same when we
	    # don't know.
	    gl_cv_double_slash_root='unknown, assuming no' ;;
	esac
      else
	set x `ls -di / //`
	if test $[2] = $[4] && wc //dev/null >/dev/null 2>&1; then
	  gl_cv_double_slash_root=no
	else
	  gl_cv_double_slash_root=yes
	fi
      fi])
  if test "$gl_cv_double_slash_root" = yes; then
    AC_DEFINE([DOUBLE_SLASH_IS_DISTINCT_ROOT], 1,
      [Define to 1 if // is a file system root distinct from /.])
  fi
])