File: configure.ac

package info (click to toggle)
cpl-plugin-visir 4.3.7%2Bdfsg-1
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 12,088 kB
  • sloc: ansic: 62,372; sh: 4,241; python: 1,890; makefile: 582
file content (123 lines) | stat: -rw-r--r-- 3,313 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
# Process this file with autoconf to produce a configure script.

AC_INIT([VISIR Instrument Pipeline], [4.3.7], [usd-help@eso.org], [visir])
AC_PREREQ([2.59])

AC_CONFIG_SRCDIR([Makefile.am])
AC_CONFIG_AUX_DIR([admin])
AC_CONFIG_MACRO_DIR([m4macros])

AC_CANONICAL_HOST
AC_CANONICAL_TARGET

AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS([config.h])
AM_SILENT_RULES([yes])

AM_MAINTAINER_MODE([enable])

AC_CONFIG_SUBDIRS([swarp])

VISIR_SET_PREFIX(${PIPE_HOME:-/usr/local})

# Immediately before every release do:
#-------------------------------------
#   if (the interface is totally unchanged from previous release)
#       REVISION++;
#   else {
#       /* interfaces have been added, removed or changed */
#       REVISION = 0;
#       CURRENT++;
#       if (any interfaces have been _added_ since last release)
#           AGE++;
#       if (any interfaces have been _removed_ or incompatibly changed)
#           AGE = 0;
#   }

VISIR_SET_VERSION_INFO([$VERSION])

# Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AM_PROG_CC_C_O
AC_PROG_LN_S

# large file support
AC_SYS_LARGEFILE

ESO_GLIBC_MALLOC_CHECK
ESO_ENABLE_DEBUG(no)
ESO_ENABLE_STRICT(no)
CPL_OPENMP

# for nanosleep, mkstemp and posix_memalign
CPPFLAGS="$CPPFLAGS -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600"
ESO_PROG_CC_FLAG([std=c99], [CFLAGS="$CFLAGS -std=c99"])
ESO_PROG_CC_FLAG([fno-common], [CFLAGS="$CFLAGS -fno-common"])
ESO_PROG_CC_FLAG([fstrict-aliasing], [CFLAGS="$CFLAGS -fstrict-aliasing"])
ESO_PROG_CC_FLAG([Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
ESO_PROG_CC_FLAG([Werror=incompatible-pointer-types], [CFLAGS="$CFLAGS -Werror=incompatible-pointer-types"])

ESO_CHECK_DOCTOOLS

AC_ENABLE_STATIC(no)
AC_ENABLE_SHARED(yes)

# deprecated in favor of LT_INIT but not available on
# autoconf 2.59 and libtool 1.5.22 on SLC5.3
AC_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

# Checks for libraries.
AC_CHECK_LIB(m, pow, [LIBS="$LIBS -lm"])
# Needed by recipes/visir_util_run_swarp.c
AC_CHECK_LIB(pthread, sem_close, [LIBS="$LIBS -lpthread"])

# Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([string.h omp.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE

# Require the size of an unsigned long long to be (at least) 8
AC_CHECK_SIZEOF(unsigned long long)
fstype=no
AC_RUN_IFELSE([AC_LANG_PROGRAM([[]],[[return sizeof(unsigned long long) < 8;]])],
              [fstype=yes])
if test $fstype = no; then
  AC_MSG_ERROR([sizeof(unsigned long long) is too small])
fi


# Checks for library functions.
# On HP-UX and Solaris isnan() may be undeclared, but available at link time
AC_CHECK_DECLS([isnan])
AC_CHECK_DECLS([erf])
AC_CHECK_DECLS([posix_memalign])
AC_CHECK_FUNCS([floor pow sqrt isinf isnan erf posix_memalign sysconf posix_fadvise])
ESO_FUNC_STRDUP

# Check for CPL presence and usability
ESO_CHECK_CPL
ESO_ENABLE_COVERAGE([no])

VISIR_SET_PATHS
VISIR_CREATE_SYMBOLS

AM_WITH_DMALLOC


AC_CONFIG_FILES(Makefile
                Doxyfile
                visir/Makefile
                recipes/Makefile
                irplib/Makefile
		reflex/Makefile
		reflex/visir_image_reduce.xml
		reflex/visir_spectro_reduce.xml
                irplib/tests/Makefile
                visir/tests/Makefile
                recipes/tests/Makefile)
AC_OUTPUT