1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
|
/*
This file is part of darktable,
copyright (c) 2019 Heiko Bauke
Copyright (C) 2023 darktable developers.
darktable is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.
darktable is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with darktable. If not, see <http://www.gnu.org/licenses/>.
*/
#include "common.h"
kernel void guided_filter_split_rgb_image(const int width,
const int height,
read_only image2d_t guide,
write_only image2d_t out_r,
write_only image2d_t out_g,
write_only image2d_t out_b,
const float guide_weight)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float4 weight = { guide_weight, guide_weight, guide_weight, 0.0f };
const float4 pixel = weight * fmin(100.0, fmax(0.0, read_imagef(guide, sampleri, (int2)(x, y))));
write_imagef(out_r, (int2)(x, y), pixel.x);
write_imagef(out_g, (int2)(x, y), pixel.y);
write_imagef(out_b, (int2)(x, y), pixel.z);
}
// Kahan summation algorithm
#define Kahan_sum(m, c, add) \
{ \
const float t1 = (add) - (c); \
const float t2 = (m) + t1; \
c = (t2 - m) - t1; \
m = t2; \
}
kernel void guided_filter_box_mean_x(const int width,
const int height,
read_only image2d_t in,
write_only image2d_t out,
const int w)
{
const int y = get_global_id(0);
if(y >= height) return;
float m = 0.f, n_box = 0.f, c = 0.f;
if(width > 2 * w)
{
for(int i = 0, i_end = w + 1; i < i_end; i++)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(i, y)).x);
n_box += 1.f;
}
for(int i = 0, i_end = w; i < i_end; i++)
{
write_imagef(out, (int2)(i, y), m / n_box);
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(i + w + 1, y)).x);
n_box += 1.f;
}
for(int i = w, i_end = width - w - 1; i < i_end; i++)
{
write_imagef(out, (int2)(i, y), m / n_box);
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(i + w + 1, y)).x);
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(i - w, y)).x);
}
for(int i = width - w - 1, i_end = width; i < i_end; i++)
{
write_imagef(out, (int2)(i, y), m / n_box);
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(i - w, y)).x);
n_box -= 1.f;
}
}
else
{
for(int i = 0, i_end = min(w + 1, width); i < i_end; i++)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(i, y)).x);
n_box += 1.f;
}
for(int i = 0; i < width; i++)
{
write_imagef(out, (int2)(i, y), m / n_box);
if(i - w >= 0)
{
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(i - w, y)).x);
n_box -= 1.f;
}
if(i + w + 1 < width)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(i + w + 1, y)).x);
n_box += 1.f;
}
}
}
}
kernel void guided_filter_box_mean_y(const int width,
const int height,
read_only image2d_t in,
write_only image2d_t out,
const int w)
{
const int x = get_global_id(0);
if(x >= width) return;
float m = 0.f, n_box = 0.f, c = 0.f;
if(height > 2 * w)
{
for(int i = 0, i_end = w + 1; i < i_end; i++)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(x, i)).x);
n_box += 1.f;
}
for(int i = 0, i_end = w; i < i_end; i++)
{
write_imagef(out, (int2)(x, i), m / n_box);
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(x, i + w + 1)).x);
n_box += 1.f;
}
for(int i = w, i_end = height - w - 1; i < i_end; i++)
{
write_imagef(out, (int2)(x, i), m / n_box);
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(x, i + w + 1)).x);
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(x, i - w)).x);
}
for(int i = height - w - 1, i_end = height; i < i_end; i++)
{
write_imagef(out, (int2)(x, i), m / n_box);
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(x, i - w)).x);
n_box -= 1.f;
}
}
else
{
for(int i = 0, i_end = min(w + 1, height); i < i_end; i++)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(x, i)).x);
n_box += 1.f;
}
for(int i = 0; i < height; i++)
{
write_imagef(out, (int2)(x, i), m / n_box);
if(i - w >= 0)
{
Kahan_sum(m, c, -read_imagef(in, sampleri, (int2)(x, i - w)).x);
n_box -= 1.f;
}
if(i + w + 1 < height)
{
Kahan_sum(m, c, read_imagef(in, sampleri, (int2)(x, i + w + 1)).x);
n_box += 1.f;
}
}
}
}
kernel void guided_filter_covariances(const int width,
const int height,
read_only image2d_t guide,
read_only image2d_t img,
write_only image2d_t cov_imgg_img_r,
write_only image2d_t cov_imgg_img_g,
write_only image2d_t cov_imgg_img_b,
const float guide_weight)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float4 weight = { guide_weight, guide_weight, guide_weight, 0.0f };
const float img_ = read_imagef(img, sampleri, (int2)(x, y)).x;
const float4 imgv = { img_, img_, img_, 0.0f };
const float4 pixel = imgv * weight * fmin(100.0, fmax(0.0, read_imagef(guide, sampleri, (int2)(x, y))));
write_imagef(cov_imgg_img_r, (int2)(x, y), pixel.x);
write_imagef(cov_imgg_img_g, (int2)(x, y), pixel.y);
write_imagef(cov_imgg_img_b, (int2)(x, y), pixel.z);
}
kernel void guided_filter_variances(const int width,
const int height,
read_only image2d_t guide,
write_only image2d_t var_imgg_rr,
write_only image2d_t var_imgg_rg,
write_only image2d_t var_imgg_rb,
write_only image2d_t var_imgg_gg,
write_only image2d_t var_imgg_gb,
write_only image2d_t var_imgg_bb,
const float guide_weight)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float4 weight = { guide_weight, guide_weight, guide_weight, 0.0f };
const float4 pixel = weight * fmin(100.0, fmax(0.0, read_imagef(guide, sampleri, (int2)(x, y))));
write_imagef(var_imgg_rr, (int2)(x, y), pixel.x * pixel.x);
write_imagef(var_imgg_rg, (int2)(x, y), pixel.x * pixel.y);
write_imagef(var_imgg_rb, (int2)(x, y), pixel.x * pixel.z);
write_imagef(var_imgg_gg, (int2)(x, y), pixel.y * pixel.y);
write_imagef(var_imgg_gb, (int2)(x, y), pixel.y * pixel.z);
write_imagef(var_imgg_bb, (int2)(x, y), pixel.z * pixel.z);
}
kernel void guided_filter_update_covariance(const int width,
const int height,
read_only image2d_t in,
write_only image2d_t out,
read_only image2d_t a,
read_only image2d_t b,
const float eps)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float i_val = read_imagef(in, samplerA, (int2)(x, y)).x;
const float a_val = read_imagef(a, samplerA, (int2)(x, y)).x;
const float b_val = read_imagef(b, samplerA, (int2)(x, y)).x;
write_imagef(out, (int2)(x, y), i_val - a_val * b_val + eps);
}
kernel void guided_filter_solve(const int width,
const int height,
read_only image2d_t img_mean,
read_only image2d_t imgg_mean_r,
read_only image2d_t imgg_mean_g,
read_only image2d_t imgg_mean_b,
read_only image2d_t cov_imgg_img_r,
read_only image2d_t cov_imgg_img_g,
read_only image2d_t cov_imgg_img_b,
read_only image2d_t var_imgg_rr,
read_only image2d_t var_imgg_rg,
read_only image2d_t var_imgg_rb,
read_only image2d_t var_imgg_gg,
read_only image2d_t var_imgg_gb,
read_only image2d_t var_imgg_bb,
write_only image2d_t a_r,
write_only image2d_t a_g,
write_only image2d_t a_b,
write_only image2d_t b)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float Sigma_0_0 = read_imagef(var_imgg_rr, sampleri, (int2)(x, y)).x;
const float Sigma_0_1 = read_imagef(var_imgg_rg, sampleri, (int2)(x, y)).x;
const float Sigma_0_2 = read_imagef(var_imgg_rb, sampleri, (int2)(x, y)).x;
const float Sigma_1_1 = read_imagef(var_imgg_gg, sampleri, (int2)(x, y)).x;
const float Sigma_1_2 = read_imagef(var_imgg_gb, sampleri, (int2)(x, y)).x;
const float Sigma_2_2 = read_imagef(var_imgg_bb, sampleri, (int2)(x, y)).x;
const float cov_imgg_img[3] = { read_imagef(cov_imgg_img_r, sampleri, (int2)(x, y)).x,
read_imagef(cov_imgg_img_g, sampleri, (int2)(x, y)).x,
read_imagef(cov_imgg_img_b, sampleri, (int2)(x, y)).x };
const float det0 = Sigma_0_0 * (Sigma_1_1 * Sigma_2_2 - Sigma_1_2 * Sigma_1_2)
- Sigma_0_1 * (Sigma_0_1 * Sigma_2_2 - Sigma_0_2 * Sigma_1_2)
+ Sigma_0_2 * (Sigma_0_1 * Sigma_1_2 - Sigma_0_2 * Sigma_1_1);
float a_r_ = 0.0f;
float a_g_ = 0.0f;
float a_b_ = 0.0f;
float b_ = read_imagef(img_mean, sampleri, (int2)(x, y)).x;
if(fabs(det0) > 4.f * FLT_EPSILON)
{
const float det1 = cov_imgg_img[0] * (Sigma_1_1 * Sigma_2_2 - Sigma_1_2 * Sigma_1_2)
- Sigma_0_1 * (cov_imgg_img[1] * Sigma_2_2 - cov_imgg_img[2] * Sigma_1_2)
+ Sigma_0_2 * (cov_imgg_img[1] * Sigma_1_2 - cov_imgg_img[2] * Sigma_1_1);
const float det2 = Sigma_0_0 * (cov_imgg_img[1] * Sigma_2_2 - cov_imgg_img[2] * Sigma_1_2)
- cov_imgg_img[0] * (Sigma_0_1 * Sigma_2_2 - Sigma_0_2 * Sigma_1_2)
+ Sigma_0_2 * (Sigma_0_1 * cov_imgg_img[2] - Sigma_0_2 * cov_imgg_img[1]);
const float det3 = Sigma_0_0 * (Sigma_1_1 * cov_imgg_img[2] - Sigma_1_2 * cov_imgg_img[1])
- Sigma_0_1 * (Sigma_0_1 * cov_imgg_img[2] - Sigma_0_2 * cov_imgg_img[1])
+ cov_imgg_img[0] * (Sigma_0_1 * Sigma_1_2 - Sigma_0_2 * Sigma_1_1);
a_r_ = det1 / det0;
a_g_ = det2 / det0;
a_b_ = det3 / det0;
b_ = b_
- a_r_ * read_imagef(imgg_mean_r, sampleri, (int2)(x, y)).x
- a_g_ * read_imagef(imgg_mean_g, sampleri, (int2)(x, y)).x
- a_b_ * read_imagef(imgg_mean_b, sampleri, (int2)(x, y)).x;
}
write_imagef(a_r, (int2)(x, y), a_r_);
write_imagef(a_g, (int2)(x, y), a_g_);
write_imagef(a_b, (int2)(x, y), a_b_);
write_imagef(b, (int2)(x, y), b_);
}
kernel void guided_filter_generate_result(const int width,
const int height,
read_only image2d_t guide,
read_only image2d_t a_r,
read_only image2d_t a_g,
read_only image2d_t a_b,
read_only image2d_t b,
write_only image2d_t res,
const float guide_weight,
const float minval,
const float maxval)
{
const int x = get_global_id(0);
const int y = get_global_id(1);
if(x >= width || y >= height) return;
const float4 pixel = fmin(100.0, fmax(0.0, read_imagef(guide, sampleri, (int2)(x, y))));
const float a_r_ = pixel.x * read_imagef(a_r, sampleri, (int2)(x, y)).x;
const float a_g_ = pixel.y * read_imagef(a_g, sampleri, (int2)(x, y)).x;
const float a_b_ = pixel.z * read_imagef(a_b, sampleri, (int2)(x, y)).x;
const float b_ = read_imagef(b, sampleri, (int2)(x, y)).x;
const float res_ = guide_weight * (a_r_ + a_g_ + a_b_)+ b_;
write_imagef(res, (int2)(x, y), fmin(maxval, fmax(minval, res_)));
}
|
