1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
# If you add a dependency, please add the corresponding rosdep key as a
# dependency in package.xml.
#======================================
# Mandatory dependencies for DART core
#======================================
if(DART_VERBOSE)
message(STATUS "")
message(STATUS "[ Mandatory dependencies for DART core ]")
endif()
# Eigen
dart_find_package(Eigen3)
dart_check_required_package(EIGEN3 "eigen3")
# CCD
dart_find_package(ccd)
dart_check_required_package(ccd "libccd")
# FCL
dart_find_package(fcl)
dart_check_required_package(fcl "fcl")
# ASSIMP
dart_find_package(assimp)
dart_check_required_package(assimp "assimp")
if(ASSIMP_FOUND)
# Check for missing symbols in ASSIMP (see #451)
include(CheckCXXSourceCompiles)
set(CMAKE_REQUIRED_DEFINITIONS "")
if (NOT ASSIMP_VERSION VERSION_LESS 3.3.0 AND NOT MSVC)
set(CMAKE_REQUIRED_FLAGS "-std=c++11 -w")
else()
set(CMAKE_REQUIRED_FLAGS "-w")
endif()
set(CMAKE_REQUIRED_INCLUDES ${ASSIMP_INCLUDE_DIRS})
set(CMAKE_REQUIRED_LIBRARIES ${ASSIMP_LIBRARIES})
check_cxx_source_compiles(
"
#include <assimp/scene.h>
int main()
{
aiScene* scene = new aiScene;
delete scene;
return 1;
}
"
ASSIMP_AISCENE_CTOR_DTOR_DEFINED)
if(NOT ASSIMP_AISCENE_CTOR_DTOR_DEFINED)
if(DART_VERBOSE)
message(WARNING "The installed version of ASSIMP (${ASSIMP_VERSION}) is "
"missing symbols for the constructor and/or destructor of "
"aiScene. DART will use its own implementations of these "
"functions. We recommend using a version of ASSIMP that "
"does not have this issue, once one becomes available.")
endif()
endif(NOT ASSIMP_AISCENE_CTOR_DTOR_DEFINED)
check_cxx_source_compiles(
"
#include <assimp/material.h>
int main()
{
aiMaterial* material = new aiMaterial;
delete material;
return 1;
}
"
ASSIMP_AIMATERIAL_CTOR_DTOR_DEFINED)
if(NOT ASSIMP_AIMATERIAL_CTOR_DTOR_DEFINED)
if(DART_VERBOSE)
message(WARNING "The installed version of ASSIMP (${ASSIMP_VERSION}) is "
"missing symbols for the constructor and/or destructor of "
"aiMaterial. DART will use its own implementations of "
"these functions. We recommend using a version of ASSIMP "
"that does not have this issue, once one becomes available.")
endif()
endif(NOT ASSIMP_AIMATERIAL_CTOR_DTOR_DEFINED)
unset(CMAKE_REQUIRED_FLAGS)
unset(CMAKE_REQUIRED_INCLUDES)
unset(CMAKE_REQUIRED_LIBRARIES)
endif()
# Boost
dart_find_package(Boost)
# octomap
dart_find_package(octomap)
if(MSVC)
# Supporting Octomap on Windows is disabled for the following issue:
# https://github.com/OctoMap/octomap/pull/213
message(WARNING "Octomap ${octomap_VERSION} is found, but Octomap "
"is not supported on Windows until "
"'https://github.com/OctoMap/octomap/pull/213' "
"is resolved.")
set(HAVE_OCTOMAP FALSE CACHE BOOL "Check if octomap found." FORCE)
else()
if(OCTOMAP_FOUND OR octomap_FOUND)
if(NOT DEFINED octomap_VERSION)
set(HAVE_OCTOMAP FALSE CACHE BOOL "Check if octomap found." FORCE)
message(WARNING "Looking for octomap - octomap_VERSION is not defined, "
"please install octomap with version information"
)
else()
set(HAVE_OCTOMAP TRUE CACHE BOOL "Check if octomap found." FORCE)
if(DART_VERBOSE)
message(STATUS "Looking for octomap - version ${octomap_VERSION} found")
endif()
endif()
else()
set(HAVE_OCTOMAP FALSE CACHE BOOL "Check if octomap found." FORCE)
message(WARNING "Looking for octomap - NOT found, to use VoxelGridShape, "
"please install octomap"
)
endif()
endif()
#--------------------
# Misc. dependencies
#--------------------
# Doxygen
find_package(Doxygen QUIET)
dart_check_optional_package(DOXYGEN "generating API documentation" "doxygen")
|
