1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
|
package Debian::DpkgLists;
use strict;
use warnings;
use Cwd;
=head1 NAME
Debian::DpkgLists - scan /var/lib/dpkg/info/*.list for files/patterns
=head1 SYNOPSIS
my @packages = Debian::DpkgLists->scan_full_path('/full/file/path');
my @packages = Debian::DpkgLists->scan_partial_path('file/path');
my @packages = Debian::DpkgLists->scan_pattern(qr{freedom$});
my @packages = Debian::DpkgLists->scan_perl_mod('Some::Module');
=head1 DESCRIPTION
B<Debian::DpkgLists> is a module for easy searching of L<dpkg(1)>'s package
file lists. These are located in F</var/lib/dpkg/info/*.list> and contain a
simple list of full fiile names (including the leading slash).
There are a couple of different class methods for searching by full or partial
path, a regular expression or a Perl module name.
Note that dpkg's file lists represent only dpkg's idea of what is installed on
the system. If you want to also search in packages, available from the Debian
archive but not installed locally, see L<Debian::AptContents>.
=cut
sub _cat_lists
{
my ( $class, $callback ) = @_;
while ( defined( my $f = </var/lib/dpkg/info/*.list> ) ) {
my $pkg = $f;
$pkg =~ s{^/var/lib/dpkg/info/}{};
$pkg =~ s/\.list$//;
open my $fh, '<', $f or die "open($f): $!\n";
while ( defined( my $l = <$fh> ) ) {
chomp $l;
&$callback( $pkg, $l );
}
}
}
=head1 CLASS-METHODS
=over
=item scan_full_path ( I<path> )
Scans dpkg file lists for files, whose full path is equal to I<path>. Use when
you have the full path of the file you want, like C</usr/bin/perl>.
Returns a (possibly empty) list of packages containing I<path>.
=cut
sub scan_full_path
{
my ( $class, $path ) = @_;
my %found;
$class->_cat_lists(
sub {
$found{ $_[0] } = 1 if $_[1] eq $path;
}
);
return sort keys %found;
}
=item scan_partial_path ( I<path> )
Scans dpkg file lists for files, whose full path ends with I<path>. Use when
you only care about the file name or other trailing portion of the full path
like C<bin/perl> (matches C</usr/bin/perl> and C</sbin/perl>).
Returns a (possibly empty) list of packages containing files whose full path
ends with I<path>.
=cut
sub scan_partial_path {
my ( $class, $path ) = @_;
my $start = -length($path);
my %result;
$class->_cat_lists(
sub {
$result{ $_[0] } = 1 if substr( $_[1], $start ) eq $path;
}
);
return sort keys %result;
}
=item scan_pattern ( I<pattern> )
Scans dpkg file lists for files, whose full path matched I<pattern>.
Returns a (possibly empty) list of packages containing files whose full path
matches I<pattern>.
=cut
sub scan_pattern {
my ( $class, $pat ) = @_;
my %result;
$class->_cat_lists(
sub {
$result{ $_[0] } = 1 if $_[1] =~ $pat;
}
);
return sort keys %result;
}
=item scan_perl_mod ( I<Module::Name> )
Scans dpkg file lists for files, corresponding to given I<Module::Name>. This
is a shorthand method for L</scan_pattern> with a pattern that matches
C</Module/Name.pm$> in all directories in C<@INC>.
Returns a (possibly empty) list of packages containing possible I<Module::Name>
files.
=cut
sub scan_perl_mod {
my ( $class, $mod ) = @_;
$mod =~ s{::}{/}g;
$mod .= ".pm" unless $mod =~ /\.pm$/;
my @dirs = grep { defined and m{^/} and not m{/usr/local/} }
map { Cwd::realpath($_) } @INC;
my $re
= "^(?:"
. join( '|', map( quotemeta($_), @dirs ) ) . ")/"
. quotemeta($mod) . "\$";
$re = qr($re);
return $class->scan_pattern($re);
}
=back
=head1 AUTHOR
=over 4
=item Damyan Ivanov <dmn@debian.org>
=back
=head1 COPYRIGHT & LICENSE
=over 4
=item Copyright (C) 2010 Damyan Ivanov <dmn@debian.org>
=back
This program is free software; you can redistribute it and/or modify it under
the terms of the GNU General Public License version 2 as published by the Free
Software Foundation.
This program is distributed in the hope that it will be useful, but WITHOUT ANY
WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
PARTICULAR PURPOSE. See the GNU General Public License for more details.
You should have received a copy of the GNU General Public License along with
this program; if not, write to the Free Software Foundation, Inc., 51 Franklin
Street, Fifth Floor, Boston, MA 02110-1301 USA.
=cut
1;
|
