1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
/*
* Linux DTrace
* Copyright (c) 2025, Oracle and/or its affiliates. All rights reserved.
* Licensed under the Universal Permissive License v 1.0 as shown at
* http://oss.oracle.com/licenses/upl.
*/
#!/usr/sbin/dtrace -qs
/*
* SYNOPSIS
* sudo ./012intro-predicates.d
*
* DESCRIPTION
* We have already seen that predicates can be used to
* conditionalize execution in a D scripts. (Other
* mechanisms include speculation and ternary operators.)
*/
BEGIN
{
ntimes = 0;
}
/*
* The write() system call has a file descriptor in arg0 and a
* requested number of bytes in arg2. If a nonzero number of
* bytes is requested, take note of the fd.
*/
syscall::write:entry
/ (self->nbytes_requested = arg2) != 0 /
{
ntimes++;
self->fd = arg0;
}
/*
* When the write() system call returns, we know the actual
* number of bytes written. Report it.
*/
syscall::write:return
/ self->nbytes_requested != 0 /
{
printf("fd %d: bytes requested %d, actual %d\n",
self->fd, self->nbytes_requested, arg1);
/* free memory associated with self-> variables */
self->nbytes_requested = 0;
self->fd = 0;
}
/*
* Only report a limited number of times.
*/
syscall::write:return
/ ntimes >= 5 /
{
exit(0);
}
|
