1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469
|
AC_INIT([dvdrtools], [0.3.1], [dvdrtools-users@nongnu.org])
AC_CANONICAL_SYSTEM
AC_ARG_PROGRAM
AM_INIT_AUTOMAKE
AC_PROG_CC
AC_PROG_RANLIB
AC_SYS_LARGEFILE
AM_CONFIG_HEADER(xconfig.h)
dnl ---- stuff from cdrecord base conf/aclocal.m4, needs cleaning up ----
AC_HEADER_STDC
AC_HEADER_INTTYPES
AC_HEADER_DIRENT
AC_HEADER_STAT
AC_HEADER_TIME
AC_HEADER_SYS_WAIT
AC_HEADER_SYS_SELECT
AC_HEADER_SELECT2
AC_CHECK_HEADERS(varargs.h stdarg.h stdlib.h string.h strings.h unistd.h \
fcntl.h sys/file.h getopt.h limits.h a.out.h aouthdr.h elf.h \
malloc.h termios.h termio.h pwd.h grp.h sys/acl.h acllib.h \
shadow.h syslog.h sys/times.h utime.h sys/utime.h sys/ioctl.h \
sys/filio.h sys/param.h sys/systeminfo.h sys/syscall.h \
mntent.h sys/mntent.h sys/mnttab.h sys/mount.h wait.h \
sys/resource.h sys/procfs.h sys/utsname.h sys/priocntl.h \
sys/rtpriocntl.h sys/mtio.h sys/mman.h linux/pg.h camlib.h \
sys/shm.h sys/ipc.h sys/dkio.h sys/dklabel.h sun/dkio.h sun/dklabel.h \
sys/types.h sys/stat.h types.h stat.h poll.h sys/poll.h sys/select.h \
netdb.h sys/socket.h ieeefp.h fp.h values.h float.h arpa/inet.h \
bsd/dev/scsireg.h OS.h sys/bsdtty.h inttypes.h stdint.h memory.h magic.h)
if test "$ac_cv_header_magic_h" != "yes"; then
LIBMAGIC=""
else
LIBMAGIC="-lmagic"
fi
AC_SUBST(LIBMAGIC)
dnl from aclocal.m4 (uses AC_TRY_COMPILE)
AC_HEADER_MAKEDEV
AC_CHECK_MINOR_BITS
AC_CHECK_MINOR_NONCONTIG
AC_HEADER_USG_STDIO
AC_HEADER_ERRNO_DEF
dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_BIGENDIAN
AC_C_BITFIELDS
AC_TYPE_SIGNAL
AC_TYPE_GETGROUPS
AC_TYPE_LONGLONG
AC_TYPE_PROTOTYPES
AC_USER_MALLOC
AC_TYPE_UID_T
AC_TYPE_SIZE_T
AC_CHECK_TYPE(ssize_t, int)
AC_TYPE_PID_T
AC_TYPE_OFF_T
AC_TYPE_MODE_T
AC_TYPE_TIME_T
AC_CHECK_TYPE(caddr_t, char *)
AC_CHECK_TYPE(daddr_t, long)
AC_CHECK_TYPE(dev_t, unsigned short)
AC_CHECK_TYPE(ino_t, unsigned long)
AC_CHECK_TYPE(nlink_t, unsigned long)
AC_TYPE_SOCKLEN_T
dnl These types are present on all UNIX systems but should be avoided
dnl for portability.
dnl On Apollo/Domain OS we don't have them....
dnl Better include <utypes.h> and use Uchar, Uint & Ulong
AC_CHECK_TYPE(u_char, unsigned char)
AC_CHECK_TYPE(u_short, unsigned short)
AC_CHECK_TYPE(u_int, unsigned int)
AC_CHECK_TYPE(u_long, unsigned long)
AC_CHECK_SIZEOF(char)
AC_CHECK_SIZEOF(short int)
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long int)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(char *)
AC_CHECK_SIZEOF(unsigned char)
AC_CHECK_SIZEOF(unsigned short int)
AC_CHECK_SIZEOF(unsigned int)
AC_CHECK_SIZEOF(unsigned long int)
AC_CHECK_SIZEOF(unsigned long long)
AC_CHECK_SIZEOF(unsigned char *)
dnl # AC_TYPE_SIZE_T_ # Defines HAVE_SIZE_T / NO_SIZE_T
AC_TYPE_CHAR
AC_TYPE_VA_LIST
AC_STRUCT_MTGET_TYPE
AC_STRUCT_MTGET_DSREG
AC_STRUCT_MTGET_ERREG
AC_STRUCT_MTGET_RESID
AC_STRUCT_MTGET_FILENO
AC_STRUCT_MTGET_BLKNO
AC_STRUCT_MTGET_FLAGS
AC_STRUCT_MTGET_BF
AC_STRUCT_RUSAGE
AC_STRUCT_UNION_SEMUN
AC_STRUCT_UNION_WAIT
AC_STRUCT_ST_SPARE1
AC_STRUCT_ST_NSEC
AC_STRUCT_ST_BLKSIZE
AC_STRUCT_ST_BLOCKS
AC_STRUCT_ST_RDEV
AC_STRUCT_ST_FLAGS
dnl Checks for library functions.
AC_FUNC_WAIT3
AC_FUNC_MLOCKALL
AC_FUNC_VA_COPY
AC_FUNC__VA_COPY
AC_FUNC_ECVT
AC_FUNC_FCVT
AC_FUNC_GCVT
AC_FUNC_DTOA
AC_FUNC_DTOA_R
jsAC_FUNC_MMAP
AC_MMAP_SIZEP
AC_FUNC_SMMAP
AC_FUNC_QUOTAIOCTL
AC_FUNC_FCNTL_LOCKF
AC_FUNC_UNAME
AC_FUNC_VFORK
AC_FUNC_SYS_SIGLIST
AC_CHECK_FUNCS(brk sbrk strerror nice memmove flock lockf fchdir statvfs quotactl \
getcwd shmat semget lstat readlink link rename mkfifo mknod \
setreuid setresuid seteuid setuid setregid setresgid setegid setgid \
getpgid setpgid getspnam getspwnam sync fsync fork wait4 waitid waitpid \
getrusage getrlimit setrlimit ulimit \
gethostid getdomainname getpagesize getdtablesize \
gettimeofday settimeofday time stime poll select lchown times utimes \
ecvt_r fcvt_r gcvt_r econvert fconvert gconvert isinf isnan \
rand drand48 setpriority DosSetPriority DosAllocSharedMem \
seekdir strsignal str2sig sig2str killpg sigrelse \
sigprocmask sigsetmask sigset nanosleep usleep \
putenv setenv strcasecmp strdup valloc \
madvise mlock chflags fchflags fflagstostr strtofflags \
fseeko ftello getopt_long strsep)
AC_CHECK_LIB(socket, rcmd, lib_socket="-lsocket")
ac_save_LIBS="$LIBS"
LIBS="$LIBS $lib_socket"
AC_CHECK_FUNCS(rcmd)
AC_CHECK_LIB(nsl, inet_ntoa, lib_nsl="-lnsl")
LIBS="$LIBS $lib_nsl"
AC_CHECK_FUNCS(inet_ntoa)
LIBS="$ac_save_LIBS"
dnl The test AC_HAVE_LARGEFILES will check whether ftello/fseeko
dnl are available in Large File mode
AC_HAVE_LARGEFILES
AC_DEFINE_UNQUOTED(HOST_ALIAS, "$host_alias", [Host alias])
AC_DEFINE_UNQUOTED(HOST_SUB, "$host", [Host subtype])
AC_DEFINE_UNQUOTED(HOST_CPU, "$host_cpu", [Host CPU])
AC_DEFINE_UNQUOTED(HOST_VENDOR, "$host_vendor", [Host Vendor])
AC_DEFINE_UNQUOTED(HOST_OS, "$host_os", [Host OS])
AC_DEFINE_UNQUOTED(SYSCONFDIR, "$sysconfdir", [System config directory])
AC_CHECK_LIB(c, crypt, lib_crypt="",
[AC_CHECK_LIB(crypt, crypt, lib_crypt="-lcrypt")])
if test $ac_cv_header_camlib_h = yes; then
scsi_lib=-lcam
fi
if test "$ac_cv_header_sys_acl_h" = yes; then
AC_CHECKING(for Posix Access Control List support)
AC_CHECK_LIB(acl, acl_get_file, lib_acl="-lacl")
AC_CHECK_LIB(pacl, acl_get_file, lib_acl="-lpacl")
ac_save_LIBS="$LIBS"
LIBS="$LIBS $lib_acl"
AC_CHECK_FUNCS(acl_get_file acl_set_file acl_from_text acl_to_text acl_free acl_delete_def_file)
LIBS="$ac_save_LIBS"
AC_CHECKING(for Solaris Access Control List support)
AC_CHECK_LIB(sec, acltotext, lib_acl="-lsec")
ac_save_LIBS="$LIBS"
LIBS="$LIBS $lib_acl"
AC_CHECK_FUNCS(acl facl aclfromtext acltotext)
LIBS="$ac_save_LIBS"
AC_CHECKING(for HP-UX Access Control List support)
AC_CHECK_FUNCS(getacl fgetacl setacl fsetacl strtoacl acltostr cpacl fcpacl chownacl setaclentry fsetaclentry)
fi
AC_SUBST(largefile_cc_opt)
AC_SUBST(lib_crypt)
AC_SUBST(scsi_lib)
AC_SUBST(lib_acl)
AC_CACHE_CHECK([whether bitorder in bitfields is htol], ac_cv_c_bitfields_htol,
[AC_TRY_RUN([
struct {
unsigned char x1:4;
unsigned char x2:4;
} a;
int main()
{
char *cp=(char *)&a;
*cp = 0x12;
exit(a.x1 == 2);}],
[ac_cv_c_bitfields_htol=yes],
[ac_cv_c_bitfields_htol=no])])
if test $ac_cv_c_bitfields_htol = yes; then
AC_DEFINE(BITFIELDS_HTOL, 1, [Define if your compiler orders bitfields high-to-low])
fi
dnl ---- end stuff from cdrecord base ----
dnl ---- Make cdda2wav happy ----
dnl extract cdrtools version from the cdrecord.c file
CDRTOOLS_VERSION=`sed -nf version.sed <dvdrecord/cdrecord.c`
AC_SUBST(CDRTOOLS_VERSION)
AC_ARG_WITH(audio-format,
[AC_HELP_STRING([--with-audio-format=FMT],
[Set default audio format for cdda2wav. Valid values for FMT are wav, au, cdr, aiff and aifc. Default: wav])])
AC_ARG_WITH(channels,
[AC_HELP_STRING([--with-channels=CH],
[Set default channels for cdda2wav (1=mono, 2=stereo). Default: 2])])
AC_ARG_WITH(bps,
[AC_HELP_STRING([--with-bps=BPS],
[Set default bits per second for cdda2wav (valid: 8, 12, 16). Default: 16])])
AC_ARG_WITH(filename,
[AC_HELP_STRING([--with-filename=fn],
[Set default filename for cdda2wav])])
AC_ARG_WITH(device,
[AC_HELP_STRING([--with-device=fn],
[Set default device for cdda2wav])])
AC_ARG_WITH(speed,
[AC_HELP_STRING([--with-speed=s],
[Set default speed for cdda2wav])])
AC_ARG_WITH(cddb,
[AC_HELP_STRING([--with-cddb=host:port],
[Set default cddb host/port, default: freedb.freedb.org:8880; use --without-cddb to disable cddb support])])
if test -z "$with_cddb" -o "$with_cddb" = "yes"; then
with_cddb="freedb.freedb.org:8880"
fi
if test $with_cddb != "no"; then
AC_DEFINE(CDDB_SUPPORT, 1, [Define if you want CDDB support in cdda2wav])
if echo $with_cddb |grep -q :; then
cddb_host="`echo $with_cddb |sed -e 's,:.*,,'`"
cddb_port="`echo $with_cddb |sed -e 's,.*:,,'`"
else
cddb_host="$with_cddb"
cddb_port=8880
fi
AC_DEFINE_UNQUOTED(CDDB_SITES_SERVER, "$cddb_host", [Default CDDB server])
AC_DEFINE_UNQUOTED(CDDB_SITES_SERVERPORT, $cddb_port, [Default CDDB port])
fi
test -z "$with_audio_format" && with_audio_format="wav"
case "$with_audio_format" in
wav|au|cdr|aiff|aifc)
DEFAUDIO="$with_audio_format"
;;
yes|no)
DEFAUDIO="wav"
;;
*)
AC_MSG_WARN([Invalid value $with_audio_format for --with-audio-format, assuming wav])
DEFAUDIO="wav"
;;
esac
AC_DEFINE_UNQUOTED(AUDIOTYPE, "$DEFAUDIO", [Default audio type for cdda2wav])
test -z "$with_channels" && with_channels="2"
if test "$with_channels" = "1" -o "$with_channels" = "2"; then
CHANNELS="$with_channels"
else
AC_MSG_WARN([Invalid value $with_channels for --with-channels, assuming 2])
CHANNELS="2"
fi
AC_DEFINE_UNQUOTED(CHANNELS, $CHANNELS, [Default number of channels for wave files])
test -z "$with_bps" && with_bps="16"
if test "$with_bps" = "8" -o "$with_bps" = "12" -o "$with_bps" = "16"; then
BPS="$with_bps"
else
AC_MSG_WARN([Invalid value $with_bps for --with-bps, assuming 16])
BPS="16"
fi
AC_DEFINE_UNQUOTED(BITS_P_S, $BPS, [Default number of bits per pixel])
test -z "$with_filename" && with_bps="audio"
test -z "$with_speed" && with_speed=0
AC_DEFINE_UNQUOTED(UNDERSAMPLING, 1, [Whatever - needs to be defined.])
AC_DEFINE_UNQUOTED(FILENAME, "$with_filename", [Default filename])
AC_DEFINE_UNQUOTED(DEF_INTERFACE, "generic_scsi", [interface])
AC_DEFINE_UNQUOTED(CD_DEVICE, "$with_device", [Default device])
AC_DEFINE_UNQUOTED(AUX_DEVICE, "/dev/cdrom", [Highlevel device])
AC_DEFINE_UNQUOTED(DEFAULT_SPEED, $with_speed, [Default speed])
AC_DEFINE_UNQUOTED(DURATION, 0, [Default time])
dnl check for posix4 library (for Solaris or SunOS)
AC_CHECK_LIB(posix4, sched_get_priority_max)
AC_CHECK_LIB(ossaudio, _oss_ioctl)
EXTRALIBS="$LIBS"
AC_SUBST(EXTRALIBS)
dnl check header files
AC_CHECK_HEADERS(sys/cdio.h)
AC_CHECK_HEADERS(sundev/srreg.h)
AC_CHECK_HEADERS(sys/audioio.h)
AC_CHECK_HEADERS(sun/audioio.h)
AC_CHECK_HEADERS(soundcard.h)
AC_CHECK_HEADERS(sys/soundcard.h)
AC_CHECK_HEADERS(linux/soundcard.h)
AC_CHECK_HEADERS(machine/soundcard.h)
case "${ac_cv_header_sys_cdio_h}""${ac_cv_header_sundev_srreg_h}" in
*yes*)
HAVE_SUN_IOCTL=1
;;
*)
HAVE_SUN_IOCTL=
;;
esac
AC_SUBST(HAVE_SUN_IOCTL)
case "${ac_cv_header_sys_audioio_h}""${ac_cv_header_sun_audioio_h}" in
*yes*)
HAVE_SUNSOUND=1
;;
*)
HAVE_SUNSOUND=
;;
esac
AC_SUBST(HAVE_SUNSOUND)
case "${ac_cv_header_machine_soundcard_h}""${ac_cv_header_sys_soundcard_h}""${ac_cv_header_linux_soundcard_h}" in
*yes*)
HAVE_OSS=1
;;
*)
HAVE_OSS=
;;
esac
AC_SUBST(HAVE_OSS)
AC_MSG_CHECKING([sound device])
SOUND_DEV=""
if test -c /dev/dsp; then
SOUND_DEV="/dev/dsp"
elif test -c /dev/audio; then
SOUND_DEV="/dev/audio"
fi
if test -z "$SOUND_DEV"; then
AC_MSG_RESULT(unknown)
else
AC_MSG_RESULT($SOUND_DEV)
AC_DEFINE_UNQUOTED(SOUND_DEV, "$SOUND_DEV", [Sound output device])
AC_DEFINE(ECHO_TO_SOUNDCARD, 1, [Define to get echo-to-soundcard support in cdda2wav])
fi
dnl Checks for library functions.
AC_CHECK_FUNCS(strtoul)
dnl ---- end cdda2wav ----
dnl ---- This used to be the align.h generation in cdrecord ----
AC_DEFUN([BERO_CHECK_ALIGN],
[AC_CHECK_SIZEOF($1)
AC_CACHE_CHECK([alignment of $1], AS_TR_SH([ac_cv_alignment_$1]),
[AC_TRY_RUN([
#include <stddef.h>
#ifndef offsetof
#define offsetof(TYPE, MEMBER) ((size_t) &((TYPE *)0)->MEMBER)
#endif
struct foo {
char a;
$1 b;
} foo;
int main(int argc, char **argv)
{
return offsetof(struct foo, b);
}], [AS_TR_SH(ac_cv_alignment_$1)=0],
[result=$?
if test $result = 0; then
AC_MSG_WARN([Autoconf bug detected. Attempting workaround.])
result=$ac_status
if test -z $result -o x$result = x0; then
AC_MSG_WARN([Autoconf bug workaround didn't work, please edit the ALIGN_* variables in xconfig.h!])
fi
fi
AS_TR_SH(ac_cv_alignment_$1)=$result],
[AS_TR_SH(ac_cv_alignment_$1)=$2])])
AC_DEFINE_UNQUOTED(AS_TR_CPP(ALIGN_$1), $AS_TR_SH([ac_cv_alignment_$1]), [Alignment of $1])
])
BERO_CHECK_ALIGN(short, 2)
BERO_CHECK_ALIGN(int, 4)
BERO_CHECK_ALIGN(long, 4)
BERO_CHECK_ALIGN(long long, 8)
BERO_CHECK_ALIGN(float, 8)
BERO_CHECK_ALIGN(char*, 4)
AC_DEFINE([ALIGN_SMASK], [ALIGN_SHORT - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_IMASK], [ALIGN_INT - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_LMASK], [ALIGN_LONG - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_LLONG], [ALIGN_LLONG - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_LLMASK], [ALIGN_LONG_LONG - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_FMASK], [ALIGN_FLOAT - 1], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_PTR], [ALIGN_CHARP], [Compatibility with cdrecord])
AC_DEFINE([ALIGN_PMASK], [ALIGN_CHARP - 1], [Compatibility with cdrecord])
AC_DEFINE([SIZE_LLONG], [SIZE_LONG_LONG], [Compatibility with cdrecord])
AC_DEFINE([SIZE_PTR], [SIZE_CHARP], [Compatibility with cdrecord])
AC_PATH_PROGS([TRANSCODE], [transcode], [NO])
if test "$TRANSCODE" = "NO"; then
AC_MSG_WARN([transcode was not found. Video DVD mastering tools will not be built.])
fi
AM_CONDITIONAL(VIDEO, test "$TRANSCODE" != "NO")
AC_OUTPUT(Makefile
libdeflt/Makefile
librscg/Makefile
libscg/Makefile
libschily/Makefile
dvdrecord/Makefile
cdda2wav/Makefile
libhfs_iso/Makefile
libunls/Makefile
mkisofs/Makefile
mkisofs/diag/Makefile
readcd/Makefile
video/Makefile
dvdrecord/dvdrecord.1
dvdrtools.spec
)
if test -z "$LIBMAGIC"; then
AC_MSG_WARN([Libmagic development headers not found.
Without libmagic, mkisofs can't identify file types.
It is highly recommended to install libmagic headers before
compiling dvdrtools.
On most Linux distributions, you can install a package named
libmagic-devel, libmagic-dev or similar.
Libmagic is part of the file program, if your OS doesn't have it,
grab it at ftp://ftp.astron.com/pub/file/
])
fi
|