1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
|
SUBROUTINE DG01OD( SCR, WGHT, N, A, W, INFO )
C
C SLICOT RELEASE 5.0.
C
C Copyright (c) 2002-2009 NICONET e.V.
C
C This program is free software: you can redistribute it and/or
C modify it under the terms of the GNU General Public License as
C published by the Free Software Foundation, either version 2 of
C the License, or (at your option) any later version.
C
C This program is distributed in the hope that it will be useful,
C but WITHOUT ANY WARRANTY; without even the implied warranty of
C MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
C GNU General Public License for more details.
C
C You should have received a copy of the GNU General Public License
C along with this program. If not, see
C <http://www.gnu.org/licenses/>.
C
C PURPOSE
C
C To compute the (scrambled) discrete Hartley transform of
C a real signal.
C
C ARGUMENTS
C
C Mode Parameters
C
C SCR CHARACTER*1
C Indicates whether the signal is scrambled on input or
C on output as follows:
C = 'N': the signal is not scrambled at all;
C = 'I': the input signal is bit-reversed;
C = 'O': the output transform is bit-reversed.
C
C WGHT CHARACTER*1
C Indicates whether the precomputed weights are available
C or not, as follows:
C = 'A': available;
C = 'N': not available.
C Note that if N > 1 and WGHT = 'N' on entry, then WGHT is
C set to 'A' on exit.
C
C Input/Output Parameters
C
C N (input) INTEGER
C Number of real samples. N must be a power of 2.
C N >= 0.
C
C A (input/output) DOUBLE PRECISION array, dimension (N)
C On entry with SCR = 'N' or SCR = 'O', this array must
C contain the input signal.
C On entry with SCR = 'I', this array must contain the
C bit-reversed input signal.
C On exit with SCR = 'N' or SCR = 'I', this array contains
C the Hartley transform of the input signal.
C On exit with SCR = 'O', this array contains the
C bit-reversed Hartley transform.
C
C W (input/output) DOUBLE PRECISION array,
C dimension (N - LOG2(N))
C On entry with WGHT = 'A', this array must contain the long
C weight vector computed by a previous call of this routine
C with the same value of N. If WGHT = 'N', the contents of
C this array on entry is ignored.
C On exit, this array contains the long weight vector.
C
C Error Indicator
C
C INFO INTEGER
C = 0: successful exit;
C < 0: if INFO = -i, the i-th argument had an illegal
C value.
C
C METHOD
C
C This routine uses a Hartley butterfly algorithm as described
C in [1].
C
C REFERENCES
C
C [1] Van Loan, Charles.
C Computational frameworks for the fast Fourier transform.
C SIAM, 1992.
C
C NUMERICAL ASPECTS
C
C The algorithm is backward stable and requires O(N log(N))
C floating point operations.
C
C CONTRIBUTOR
C
C D. Kressner, Technical Univ. Berlin, Germany, April 2001.
C
C REVISIONS
C
C V. Sima, Research Institute for Informatics, Bucharest, Apr. 2000.
C
C KEYWORDS
C
C Digital signal processing, fast Hartley transform, real signals.
C
C ******************************************************************
C
C .. Parameters ..
DOUBLE PRECISION ONE, TWO, FOUR
PARAMETER ( ONE = 1.0D0, TWO = 2.0D0, FOUR = 4.0D0 )
C .. Scalar Arguments ..
CHARACTER SCR, WGHT
INTEGER INFO, N
C .. Array Arguments ..
DOUBLE PRECISION A(*), W(*)
C .. Local Scalars ..
INTEGER I, J, L, LEN, M, P1, P2, Q1, Q2, R1, R2, S1, S2,
$ WPOS
LOGICAL LFWD, LSCR, LWGHT
DOUBLE PRECISION CF, SF, T1, T2, TH
C .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
C .. External Subroutines ..
EXTERNAL XERBLA
C .. Intrinsic Functions ..
INTRINSIC ATAN, COS, DBLE, MOD, SIN
C .. Executable Statements ..
C
INFO = 0
LFWD = LSAME( SCR, 'N' ) .OR. LSAME( SCR, 'I' )
LSCR = LSAME( SCR, 'I' ) .OR. LSAME( SCR, 'O' )
LWGHT = LSAME( WGHT, 'A' )
C
C Test the input scalar arguments.
C
IF( .NOT.( LFWD .OR. LSCR ) ) THEN
INFO = -1
ELSE IF( .NOT.LWGHT .AND. .NOT.LSAME( WGHT, 'N' ) ) THEN
INFO = -2
ELSE
M = 0
J = 0
IF( N.GE.1 ) THEN
J = N
C WHILE ( MOD( J, 2 ).EQ.0 ) DO
10 CONTINUE
IF ( MOD( J, 2 ).EQ.0 ) THEN
J = J/2
M = M + 1
GO TO 10
END IF
C END WHILE 10
IF ( J.NE.1 ) INFO = -3
ELSE IF ( N.LT.0 ) THEN
INFO = -3
END IF
END IF
C
IF ( INFO.NE.0 ) THEN
C
C Error return.
C
CALL XERBLA( 'DG01OD', -INFO )
RETURN
END IF
C
C Quick return if possible.
C
IF ( N.LE.1 )
$ RETURN
C
IF ( .NOT. LWGHT ) THEN
C
C Compute the long weight vector via subvector scaling.
C
R1 = 1
LEN = 1
TH = FOUR*ATAN( ONE ) / DBLE( N )
C
DO 30 L = 1, M - 2
LEN = 2*LEN
TH = TWO*TH
CF = COS(TH)
SF = SIN(TH)
W(R1) = CF
W(R1+1) = SF
R1 = R1 + 2
C
DO 20 I = 1, LEN - 2, 2
W(R1) = CF*W(I) - SF*W(I+1)
W(R1+1) = SF*W(I) + CF*W(I+1)
R1 = R1 + 2
20 CONTINUE
C
30 CONTINUE
C
P1 = 3
Q1 = R1 - 2
C
DO 50 L = M - 2, 1, -1
C
DO 40 I = P1, Q1, 4
W(R1) = W(I)
W(R1+1) = W(I+1)
R1 = R1 + 2
40 CONTINUE
C
P1 = Q1 + 4
Q1 = R1 - 2
50 CONTINUE
C
WGHT = 'A'
C
END IF
C
IF ( LFWD .AND. .NOT.LSCR ) THEN
C
C Inplace shuffling of data.
C
J = 1
C
DO 70 I = 1, N
IF ( J.GT.I ) THEN
T1 = A(I)
A(I) = A(J)
A(J) = T1
END IF
L = N/2
C REPEAT
60 IF ( J.GT.L ) THEN
J = J - L
L = L/2
IF ( L.GE.2 ) GO TO 60
END IF
C UNTIL ( L.LT.2 )
J = J + L
70 CONTINUE
C
END IF
C
IF ( LFWD ) THEN
C
C Compute Hartley transform with butterfly operators.
C
DO 110 J = 2, N, 2
T1 = A(J)
A(J) = A(J-1) - T1
A(J-1) = A(J-1) + T1
110 CONTINUE
C
LEN = 1
WPOS = N - 2*M + 1
C
DO 140 L = 1, M - 1
LEN = 2*LEN
P2 = 1
Q2 = LEN + 1
R2 = LEN / 2 + 1
S2 = R2 + Q2 - 1
C
DO 130 I = 0, N/( 2*LEN ) - 1
T1 = A(Q2)
A(Q2) = A(P2) - T1
A(P2) = A(P2) + T1
T1 = A(S2)
A(S2) = A(R2) - T1
A(R2) = A(R2) + T1
C
P1 = P2 + 1
Q1 = P1 + LEN
R1 = Q1 - 2
S1 = R1 + LEN
C
DO 120 J = WPOS, WPOS + LEN - 3, 2
CF = W(J)
SF = W(J+1)
T1 = CF*A(Q1) + SF*A(S1)
T2 = -CF*A(S1) + SF*A(Q1)
A(Q1) = A(P1) - T1
A(P1) = A(P1) + T1
A(S1) = A(R1) - T2
A(R1) = A(R1) + T2
P1 = P1 + 1
Q1 = Q1 + 1
R1 = R1 - 1
S1 = S1 - 1
120 CONTINUE
C
P2 = P2 + 2*LEN
Q2 = Q2 + 2*LEN
R2 = R2 + 2*LEN
S2 = S2 + 2*LEN
130 CONTINUE
C
WPOS = WPOS - 2*LEN + 2
140 CONTINUE
C
ELSE
C
C Compute Hartley transform with transposed butterfly operators.
C
WPOS = 1
LEN = N
C
DO 230 L = M - 1, 1, -1
LEN = LEN / 2
P2 = 1
Q2 = LEN + 1
R2 = LEN / 2 + 1
S2 = R2 + Q2 - 1
C
DO 220 I = 0, N/( 2*LEN ) - 1
T1 = A(Q2)
A(Q2) = A(P2) - T1
A(P2) = A(P2) + T1
T1 = A(S2)
A(S2) = A(R2) - T1
A(R2) = A(R2) + T1
C
P1 = P2 + 1
Q1 = P1 + LEN
R1 = Q1 - 2
S1 = R1 + LEN
C
DO 210 J = WPOS, WPOS + LEN - 3, 2
CF = W(J)
SF = W(J+1)
T1 = A(P1) - A(Q1)
T2 = A(R1) - A(S1)
A(P1) = A(P1) + A(Q1)
A(R1) = A(R1) + A(S1)
A(Q1) = CF*T1 + SF*T2
A(S1) = -CF*T2 + SF*T1
P1 = P1 + 1
Q1 = Q1 + 1
R1 = R1 - 1
S1 = S1 - 1
210 CONTINUE
C
P2 = P2 + 2*LEN
Q2 = Q2 + 2*LEN
R2 = R2 + 2*LEN
S2 = S2 + 2*LEN
220 CONTINUE
C
WPOS = WPOS + LEN - 2
230 CONTINUE
C
DO 240 J = 2, N, 2
T1 = A(J)
A(J) = A(J-1) - T1
A(J-1) = A(J-1) + T1
240 CONTINUE
C
END IF
RETURN
C *** Last line of DG01OD ***
END
|
