1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
|
SUBROUTINE MB04ID( N, M, P, L, A, LDA, B, LDB, TAU, DWORK, LDWORK,
$ INFO )
C
C SLICOT RELEASE 5.0.
C
C Copyright (c) 2002-2009 NICONET e.V.
C
C This program is free software: you can redistribute it and/or
C modify it under the terms of the GNU General Public License as
C published by the Free Software Foundation, either version 2 of
C the License, or (at your option) any later version.
C
C This program is distributed in the hope that it will be useful,
C but WITHOUT ANY WARRANTY; without even the implied warranty of
C MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
C GNU General Public License for more details.
C
C You should have received a copy of the GNU General Public License
C along with this program. If not, see
C <http://www.gnu.org/licenses/>.
C
C PURPOSE
C
C To compute a QR factorization of an n-by-m matrix A (A = Q * R),
C having a p-by-min(p,m) zero triangle in the lower left-hand side
C corner, as shown below, for n = 8, m = 7, and p = 2:
C
C [ x x x x x x x ]
C [ x x x x x x x ]
C [ x x x x x x x ]
C [ x x x x x x x ]
C A = [ x x x x x x x ],
C [ x x x x x x x ]
C [ 0 x x x x x x ]
C [ 0 0 x x x x x ]
C
C and optionally apply the transformations to an n-by-l matrix B
C (from the left). The problem structure is exploited. This
C computation is useful, for instance, in combined measurement and
C time update of one iteration of the time-invariant Kalman filter
C (square root information filter).
C
C ARGUMENTS
C
C Input/Output Parameters
C
C N (input) INTEGER
C The number of rows of the matrix A. N >= 0.
C
C M (input) INTEGER
C The number of columns of the matrix A. M >= 0.
C
C P (input) INTEGER
C The order of the zero triagle. P >= 0.
C
C L (input) INTEGER
C The number of columns of the matrix B. L >= 0.
C
C A (input/output) DOUBLE PRECISION array, dimension (LDA,M)
C On entry, the leading N-by-M part of this array must
C contain the matrix A. The elements corresponding to the
C zero P-by-MIN(P,M) lower trapezoidal/triangular part
C (if P > 0) are not referenced.
C On exit, the elements on and above the diagonal of this
C array contain the MIN(N,M)-by-M upper trapezoidal matrix
C R (R is upper triangular, if N >= M) of the QR
C factorization, and the relevant elements below the
C diagonal contain the trailing components (the vectors v,
C see Method) of the elementary reflectors used in the
C factorization.
C
C LDA INTEGER
C The leading dimension of array A. LDA >= MAX(1,N).
C
C B (input/output) DOUBLE PRECISION array, dimension (LDB,L)
C On entry, the leading N-by-L part of this array must
C contain the matrix B.
C On exit, the leading N-by-L part of this array contains
C the updated matrix B.
C If L = 0, this array is not referenced.
C
C LDB INTEGER
C The leading dimension of array B.
C LDB >= MAX(1,N) if L > 0;
C LDB >= 1 if L = 0.
C
C TAU (output) DOUBLE PRECISION array, dimension MIN(N,M)
C The scalar factors of the elementary reflectors used.
C
C Workspace
C
C DWORK DOUBLE PRECISION array, dimension (LDWORK)
C On exit, if INFO = 0, DWORK(1) returns the optimal value
C of LDWORK.
C
C LDWORK The length of the array DWORK.
C LDWORK >= MAX(1,M-1,M-P,L).
C For optimum performance LDWORK should be larger.
C
C If LDWORK = -1, then a workspace query is assumed;
C the routine only calculates the optimal size of the
C DWORK array, returns this value as the first entry of
C the DWORK array, and no error message related to LDWORK
C is issued by XERBLA.
C
C Error Indicator
C
C INFO INTEGER
C = 0: successful exit;
C < 0: if INFO = -i, the i-th argument had an illegal
C value.
C
C METHOD
C
C The routine uses min(N,M) Householder transformations exploiting
C the zero pattern of the matrix. A Householder matrix has the form
C
C ( 1 ),
C H = I - tau *u *u', u = ( v )
C i i i i i ( i)
C
C where v is an (N-P+I-2)-vector. The components of v are stored
C i i
C in the i-th column of A, beginning from the location i+1, and
C tau is stored in TAU(i).
C i
C
C NUMERICAL ASPECTS
C
C The algorithm is backward stable.
C
C CONTRIBUTORS
C
C V. Sima, Katholieke Univ. Leuven, Belgium, Feb. 1997.
C
C REVISIONS
C
C V. Sima, Research Institute for Informatics, Bucharest, Jan. 2009,
C Apr. 2009.
C
C KEYWORDS
C
C Elementary reflector, QR factorization, orthogonal transformation.
C
C ******************************************************************
C
C .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
C .. Scalar Arguments ..
INTEGER INFO, L, LDA, LDB, LDWORK, M, N, P
C .. Array Arguments ..
DOUBLE PRECISION A(LDA,*), B(LDB,*), DWORK(*), TAU(*)
C .. Local Scalars ..
LOGICAL LQUERY
INTEGER I, NB, WRKOPT
DOUBLE PRECISION FIRST
C .. External Functions ..
INTEGER ILAENV
EXTERNAL ILAENV
C .. External Subroutines ..
EXTERNAL DGEQRF, DLARF, DLARFG, DORMQR, XERBLA
C .. Intrinsic Functions ..
INTRINSIC INT, MAX, MIN
C .. Executable Statements ..
C
C Test the input scalar arguments.
C
INFO = 0
LQUERY = ( LDWORK.EQ.-1 )
IF( N.LT.0 ) THEN
INFO = -1
ELSE IF( M.LT.0 ) THEN
INFO = -2
ELSE IF( P.LT.0 ) THEN
INFO = -3
ELSE IF( L.LT.0 ) THEN
INFO = -4
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
INFO = -6
ELSE IF( LDB.LT.1 .OR. ( L.GT.0 .AND. LDB.LT.N ) ) THEN
INFO = -8
ELSE
I = MAX( 1, M - 1, M - P, L )
IF( LQUERY ) THEN
IF( M.GT.P ) THEN
NB = ILAENV( 1, 'DGEQRF', ' ', N-P, M-P, -1, -1 )
WRKOPT = MAX( I, ( M - P )*NB )
IF ( L.GT.0 ) THEN
NB = MIN( 64, ILAENV( 1, 'DORMQR', 'LT', N-P, L,
$ MIN(N,M)-P, -1 ) )
WRKOPT = MAX( WRKOPT, MAX( 1, L )*NB )
END IF
END IF
ELSE IF( LDWORK.LT.I ) THEN
INFO = -11
END IF
END IF
C
IF( INFO.NE.0 ) THEN
C
C Error return.
C
CALL XERBLA( 'MB04ID', -INFO )
RETURN
ELSE IF( LQUERY ) THEN
DWORK(1) = WRKOPT
RETURN
END IF
C
C Quick return if possible.
C
IF( MIN( M, N ).EQ.0 ) THEN
DWORK(1) = ONE
RETURN
ELSE IF( N.LE.P+1 ) THEN
DO 5 I = 1, MIN( N, M )
TAU(I) = ZERO
5 CONTINUE
DWORK(1) = ONE
RETURN
END IF
C
C Annihilate the subdiagonal elements of A and apply the
C transformations to B, if L > 0.
C Workspace: need MAX(M-1,L).
C
C (Note: Comments in the code beginning "Workspace:" describe the
C minimal amount of real workspace needed at that point in the
C code, as well as the preferred amount for good performance.
C NB refers to the optimal block size for the immediately
C following subroutine, as returned by ILAENV.)
C
DO 10 I = 1, MIN( P, M )
C
C Exploit the structure of the I-th column of A.
C
CALL DLARFG( N-P, A(I,I), A(I+1,I), 1, TAU(I) )
IF( TAU(I).NE.ZERO ) THEN
C
FIRST = A(I,I)
A(I,I) = ONE
C
IF ( I.LT.M ) CALL DLARF( 'Left', N-P, M-I, A(I,I), 1,
$ TAU(I), A(I,I+1), LDA, DWORK )
IF ( L.GT.0 ) CALL DLARF( 'Left', N-P, L, A(I,I), 1, TAU(I),
$ B(I,1), LDB, DWORK )
C
A(I,I) = FIRST
END IF
10 CONTINUE
C
WRKOPT = MAX( 1, M - 1, L )
C
C Fast QR factorization of the remaining right submatrix, if any.
C Workspace: need M-P; prefer (M-P)*NB.
C
IF( M.GT.P ) THEN
CALL DGEQRF( N-P, M-P, A(P+1,P+1), LDA, TAU(P+1), DWORK,
$ LDWORK, INFO )
WRKOPT = MAX( WRKOPT, INT( DWORK(1) ) )
C
IF ( L.GT.0 ) THEN
C
C Apply the transformations to B.
C Workspace: need L; prefer L*NB.
C
CALL DORMQR( 'Left', 'Transpose', N-P, L, MIN(N,M)-P,
$ A(P+1,P+1), LDA, TAU(P+1), B(P+1,1), LDB,
$ DWORK, LDWORK, INFO )
WRKOPT = MAX( WRKOPT, INT( DWORK(1) ) )
END IF
END IF
C
DWORK(1) = WRKOPT
RETURN
C *** Last line of MB04ID ***
END
|
