1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
|
SUBROUTINE SB16CY( DICO, JOBCF, N, M, P, A, LDA, B, LDB, C, LDC,
$ F, LDF, G, LDG, SCALEC, SCALEO, S, LDS, R, LDR,
$ DWORK, LDWORK, INFO )
C
C SLICOT RELEASE 5.0.
C
C Copyright (c) 2002-2009 NICONET e.V.
C
C This program is free software: you can redistribute it and/or
C modify it under the terms of the GNU General Public License as
C published by the Free Software Foundation, either version 2 of
C the License, or (at your option) any later version.
C
C This program is distributed in the hope that it will be useful,
C but WITHOUT ANY WARRANTY; without even the implied warranty of
C MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
C GNU General Public License for more details.
C
C You should have received a copy of the GNU General Public License
C along with this program. If not, see
C <http://www.gnu.org/licenses/>.
C
C PURPOSE
C
C To compute, for a given open-loop model (A,B,C,0), and for
C given state feedback gain F and full observer gain G,
C such that A+B*F and A+G*C are stable, the Cholesky factors
C Su and Ru of a controllability Grammian P = Su*Su' and of
C an observability Grammian Q = Ru'*Ru corresponding to a
C frequency-weighted model reduction of the left or right coprime
C factors of the state-feedback controller.
C
C ARGUMENTS
C
C Mode Parameters
C
C DICO CHARACTER*1
C Specifies the type of the open-loop system as follows:
C = 'C': continuous-time system;
C = 'D': discrete-time system.
C
C JOBCF CHARACTER*1
C Specifies whether a left or right coprime factorization
C of the state-feedback controller is to be used as follows:
C = 'L': use a left coprime factorization;
C = 'R': use a right coprime factorization.
C
C Input/Output Parameters
C
C N (input) INTEGER
C The order of the open-loop state-space representation,
C i.e., the order of the matrix A. N >= 0.
C
C M (input) INTEGER
C The number of system inputs. M >= 0.
C
C P (input) INTEGER
C The number of system outputs. P >= 0.
C
C A (input) DOUBLE PRECISION array, dimension (LDA,N)
C The leading N-by-N part of this array must contain the
C state matrix A of the open-loop system.
C
C LDA INTEGER
C The leading dimension of array A. LDA >= MAX(1,N).
C
C B (input) DOUBLE PRECISION array, dimension (LDB,M)
C The leading N-by-M part of this array must contain the
C input/state matrix B of the open-loop system.
C
C LDB INTEGER
C The leading dimension of array B. LDB >= MAX(1,N).
C
C C (input) DOUBLE PRECISION array, dimension (LDC,N)
C The leading P-by-N part of this array must contain the
C state/output matrix C of the open-loop system.
C
C LDC INTEGER
C The leading dimension of array C. LDC >= MAX(1,P).
C
C F (input) DOUBLE PRECISION array, dimension (LDF,N)
C The leading M-by-N part of this array must contain a
C stabilizing state feedback matrix.
C
C LDF INTEGER
C The leading dimension of array F. LDF >= MAX(1,M).
C
C G (input) DOUBLE PRECISION array, dimension (LDG,P)
C The leading N-by-P part of this array must contain a
C stabilizing observer gain matrix.
C
C LDG INTEGER
C The leading dimension of array G. LDG >= MAX(1,N).
C
C SCALEC (output) DOUBLE PRECISION
C Scaling factor for the controllability Grammian.
C See METHOD.
C
C SCALEO (output) DOUBLE PRECISION
C Scaling factor for the observability Grammian.
C See METHOD.
C
C S (output) DOUBLE PRECISION array, dimension (LDS,N)
C The leading N-by-N upper triangular part of this array
C contains the Cholesky factor Su of frequency-weighted
C cotrollability Grammian P = Su*Su'. See METHOD.
C
C LDS INTEGER
C The leading dimension of the array S. LDS >= MAX(1,N).
C
C R (output) DOUBLE PRECISION array, dimension (LDR,N)
C The leading N-by-N upper triangular part of this array
C contains the Cholesky factor Ru of the frequency-weighted
C observability Grammian Q = Ru'*Ru. See METHOD.
C
C LDR INTEGER
C The leading dimension of the array R. LDR >= MAX(1,N).
C
C Workspace
C
C DWORK DOUBLE PRECISION array, dimension (LDWORK)
C On exit, if INFO = 0, DWORK(1) returns the optimal value
C of LDWORK.
C
C LDWORK INTEGER
C The length of the array DWORK.
C LDWORK >= MAX(1, N*(N + MAX(N,M) + MIN(N,M) + 6)),
C if JOBCF = 'L';
C LDWORK >= MAX(1, N*(N + MAX(N,P) + MIN(N,P) + 6)),
C if JOBCF = 'R'.
C For optimum performance LDWORK should be larger.
C An upper bound for both cases is
C LDWORK >= MAX(1, N*(N + MAX(N,M,P) + 7)).
C
C Error Indicator
C
C INFO INTEGER
C = 0: successful exit;
C < 0: if INFO = -i, the i-th argument had an illegal
C value;
C = 1: eigenvalue computation failure;
C = 2: the matrix A+G*C is not stable;
C = 3: the matrix A+B*F is not stable;
C = 4: the Lyapunov equation for computing the
C observability Grammian is (nearly) singular;
C = 5: the Lyapunov equation for computing the
C controllability Grammian is (nearly) singular.
C
C METHOD
C
C In accordance with the type of the coprime factorization
C of the controller (left or right), the Cholesky factors Su and Ru
C of the frequency-weighted controllability Grammian P = Su*Su' and
C of the frequency-weighted observability Grammian Q = Ru'*Ru are
C computed by solving appropriate Lyapunov or Stein equations [1].
C
C If JOBCF = 'L' and DICO = 'C', P and Q are computed as the
C solutions of the following Lyapunov equations:
C
C (A+B*F)*P + P*(A+B*F)' + scalec^2*B*B' = 0, (1)
C
C (A+G*C)'*Q + Q*(A+G*C) + scaleo^2*F'*F = 0. (2)
C
C If JOBCF = 'L' and DICO = 'D', P and Q are computed as the
C solutions of the following Stein equations:
C
C (A+B*F)*P*(A+B*F)' - P + scalec^2*B*B' = 0, (3)
C
C (A+G*C)'*Q*(A+G*C) - Q + scaleo^2*F'*F = 0. (4)
C
C If JOBCF = 'R' and DICO = 'C', P and Q are computed as the
C solutions of the following Lyapunov equations:
C
C (A+B*F)*P + P*(A+B*F)' + scalec^2*G*G' = 0, (5)
C
C (A+G*C)'*Q + Q*(A+G*C) + scaleo^2*C'*C = 0. (6)
C
C If JOBCF = 'R' and DICO = 'D', P and Q are computed as the
C solutions of the following Stein equations:
C
C (A+B*F)*P*(A+B*F)' - P + scalec^2*G*G' = 0, (7)
C
C (A+G*C)'*Q*(A+G*C) - Q + scaleo^2*C'*C = 0. (8)
C
C REFERENCES
C
C [1] Liu, Y., Anderson, B.D.O. and Ly, O.L.
C Coprime factorization controller reduction with Bezout
C identity induced frequency weighting.
C Automatica, vol. 26, pp. 233-249, 1990.
C
C CONTRIBUTORS
C
C A. Varga, German Aerospace Center, Oberpfaffenhofen, October 2000.
C D. Sima, University of Bucharest, October 2000.
C V. Sima, Research Institute for Informatics, Bucharest, Oct. 2000.
C
C REVISIONS
C
C A. Varga, Australian National University, Canberra, November 2000.
C
C KEYWORDS
C
C Controller reduction, frequency weighting, multivariable system,
C state-space model, state-space representation.
C
C ******************************************************************
C
C .. Parameters ..
DOUBLE PRECISION ZERO, ONE
PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
C .. Scalar Arguments ..
CHARACTER DICO, JOBCF
INTEGER INFO, LDA, LDB, LDC, LDF, LDG, LDR, LDS, LDWORK,
$ M, N, P
DOUBLE PRECISION SCALEC, SCALEO
C .. Array Arguments ..
DOUBLE PRECISION A(LDA,*), B(LDB,*), C(LDC,*), DWORK(*),
$ F(LDF,*), G(LDG,*), R(LDR,*), S(LDS,*)
C .. Local Scalars ..
LOGICAL DISCR, LEFTW
INTEGER IERR, KAW, KU, KW, KWI, KWR, LDU, LW, ME, MP,
$ WRKOPT
C .. External Functions ..
LOGICAL LSAME
EXTERNAL LSAME
C .. External Subroutines ..
EXTERNAL DGEMM, DLACPY, SB03OD, XERBLA
C .. Intrinsic Functions ..
INTRINSIC INT, MAX, MIN
C .. Executable Statements ..
C
DISCR = LSAME( DICO, 'D' )
LEFTW = LSAME( JOBCF, 'L' )
C
INFO = 0
IF( LEFTW ) THEN
MP = M
ELSE
MP = P
END IF
LW = N*( N + MAX( N, MP ) + MIN( N, MP ) + 6 )
C
IF( .NOT. ( LSAME( DICO, 'C' ) .OR. DISCR ) ) THEN
INFO = -1
ELSE IF( .NOT.( LEFTW .OR. LSAME( JOBCF, 'R' ) ) ) THEN
INFO = -2
ELSE IF( N.LT.0 ) THEN
INFO = -3
ELSE IF( M.LT.0 ) THEN
INFO = -4
ELSE IF( P.LT.0 ) THEN
INFO = -5
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
INFO = -7
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
INFO = -9
ELSE IF( LDC.LT.MAX( 1, P ) ) THEN
INFO = -11
ELSE IF( LDF.LT.MAX( 1, M ) ) THEN
INFO = -13
ELSE IF( LDG.LT.MAX( 1, N ) ) THEN
INFO = -15
ELSE IF( LDS.LT.MAX( 1, N ) ) THEN
INFO = -19
ELSE IF( LDR.LT.MAX( 1, N ) ) THEN
INFO = -21
ELSE IF( LDWORK.LT.MAX( 1, LW ) ) THEN
INFO = -23
END IF
C
IF( INFO.NE.0 ) THEN
C
C Error return.
C
CALL XERBLA( 'SB16CY', -INFO )
RETURN
END IF
C
C Quick return if possible.
C
IF( MIN( N, M, P ).EQ.0 ) THEN
SCALEC = ONE
SCALEO = ONE
DWORK(1) = ONE
RETURN
END IF
C
C Allocate storage for work arrays.
C
KAW = 1
KU = KAW + N*N
KWR = KU + N*MAX( N, MP )
KWI = KWR + N
KW = KWI + N
C
C Form A+G*C.
C
CALL DLACPY( 'Full', N, N, A, LDA, DWORK(KAW), N )
CALL DGEMM( 'No-transpose', 'No-transpose', N, N, P, ONE,
$ G, LDG, C, LDC, ONE, DWORK(KAW), N )
C
C Form the factor H of the free term.
C
IF( LEFTW ) THEN
C
C H = F.
C
LDU = MAX( N, M )
ME = M
CALL DLACPY( 'Full', M, N, F, LDF, DWORK(KU), LDU )
ELSE
C
C H = C.
C
LDU = MAX( N, P )
ME = P
CALL DLACPY( 'Full', P, N, C, LDC, DWORK(KU), LDU )
END IF
C
C Solve for the Cholesky factor Ru of Q, Q = Ru'*Ru,
C the continuous-time Lyapunov equation (if DICO = 'C')
C
C (A+G*C)'*Q + Q*(A+G*C) + scaleo^2*H'*H = 0,
C
C or the discrete-time Lyapunov equation (if DICO = 'D')
C
C (A+G*C)'*Q*(A+G*C) - Q + scaleo^2*H'*H = 0.
C
C Workspace: need N*(N + MAX(N,M) + MIN(N,M) + 6) if JOBCF = 'L';
C N*(N + MAX(N,P) + MIN(N,P) + 6) if JOBCF = 'R'.
C prefer larger.
C
CALL SB03OD( DICO, 'NoFact', 'NoTransp', N, ME, DWORK(KAW), N,
$ R, LDR, DWORK(KU), LDU, SCALEO, DWORK(KWR),
$ DWORK(KWI), DWORK(KW), LDWORK-KW+1, IERR )
IF( IERR.NE.0 ) THEN
IF( IERR.EQ.2 ) THEN
INFO = 2
ELSE IF( IERR.EQ.1 ) THEN
INFO = 4
ELSE IF( IERR.EQ.6 ) THEN
INFO = 1
END IF
RETURN
END IF
C
WRKOPT = INT( DWORK(KW) ) + KW - 1
CALL DLACPY( 'Upper', N, N, DWORK(KU), LDU, R, LDR )
C
C Form A+B*F.
C
CALL DLACPY( 'Full', N, N, A, LDA, DWORK(KAW), N )
CALL DGEMM( 'No-transpose', 'No-transpose', N, N, M, ONE,
$ B, LDB, F, LDF, ONE, DWORK(KAW), N )
C
C Form the factor K of the free term.
C
LDU = N
IF( LEFTW ) THEN
C
C K = B.
C
ME = M
CALL DLACPY( 'Full', N, M, B, LDB, DWORK(KU), LDU )
ELSE
C
C K = G.
C
ME = P
CALL DLACPY( 'Full', N, P, G, LDG, DWORK(KU), LDU )
END IF
C
C Solve for the Cholesky factor Su of P, P = Su*Su',
C the continuous-time Lyapunov equation (if DICO = 'C')
C
C (A+B*F)*P + P*(A+B*F)' + scalec^2*K*K' = 0,
C
C or the discrete-time Lyapunov equation (if DICO = 'D')
C
C (A+B*F)*P*(A+B*F)' - P + scalec^2*K*K' = 0.
C
C Workspace: need N*(N + MAX(N,M) + MIN(N,M) + 6) if JOBCF = 'L';
C N*(N + MAX(N,P) + MIN(N,P) + 6) if JOBCF = 'R'.
C prefer larger.
C
CALL SB03OD( DICO, 'NoFact', 'Transp', N, ME, DWORK(KAW), N,
$ S, LDS, DWORK(KU), LDU, SCALEC, DWORK(KWR),
$ DWORK(KWI), DWORK(KW), LDWORK-KW+1, IERR )
IF( IERR.NE.0 ) THEN
IF( IERR.EQ.2 ) THEN
INFO = 3
ELSE IF( IERR.EQ.1 ) THEN
INFO = 5
ELSE IF( IERR.EQ.6 ) THEN
INFO = 1
END IF
RETURN
END IF
WRKOPT = MAX( WRKOPT, INT( DWORK(KW) ) + KW - 1 )
CALL DLACPY( 'Upper', N, N, DWORK(KU), LDU, S, LDS )
C
C Save the optimal workspace.
C
DWORK(1) = WRKOPT
C
RETURN
C *** Last line of SB16CY ***
END
|
