File: hello_world.ttcn

package info (click to toggle)
eclipse-titan 6.5.0-1
  • links: PTS
  • area: main
  • in suites: buster
  • size: 101,128 kB
  • sloc: cpp: 259,139; ansic: 47,560; yacc: 22,554; makefile: 14,074; sh: 12,630; lex: 9,101; xml: 5,362; java: 4,849; perl: 3,784; awk: 48; php: 32; python: 13
file content (83 lines) | stat: -rw-r--r-- 2,804 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
/******************************************************************************
 * Copyright (c) 2000-2018 Ericsson Telecom AB
 * All rights reserved. This program and the accompanying materials
 * are made available under the terms of the Eclipse Public License v2.0
 * which accompanies this distribution, and is available at
 * https://www.eclipse.org/org/documents/epl-2.0/EPL-2.0.html
 *
 * Contributors:
 *   Balasko, Jeno
 *
 ******************************************************************************/
module hello_world
{
//====================== Data Types ======================
type record of charstring RoC; //unconstrained array of character strings

//====================== Port Types ======================
type port MYPORT message {
  inout charstring
} with {extension "internal"}

//====================== Component Types ======================
type component MYCOMP {
  const integer c_MyCompDummyConstant := 42;
  var integer v_MyCompDummyVariable1, v_MyCompDummyVariable2 := 1;
  timer T_MyCompDummyTimer;
  port MYPORT myport
}

//====================== Constants ======================
const charstring ws0 := "(\n| )#(0,)"

//====================== Templates ======================
//Strings containing the words "hello" and "word", in all small, or
//all capital letters, or small letters with first letter capital;
//exclamation mark is optional; whitespaces allowed
template charstring t_expected :=
  pattern "{ws0}(((h|H)ello {ws0}(w|W)orld)|HELLO {ws0}WORLD){ws0}!#(0,1){ws0}"

//====================== Functions ======================
function f_PTC(charstring pl_toSend) runs on MYCOMP {
  myport.send(pl_toSend);
}

//====================== Testcases ======================
testcase TC(charstring pl_toSend) runs on MYCOMP {
  var charstring vl_received;
  var MYCOMP vl_PTC := MYCOMP.create alive;
  connect (self:myport,vl_PTC:myport);
  vl_PTC.start(f_PTC(pl_toSend));
  T_MyCompDummyTimer.start(5.0);
  alt {
    [] myport.receive(t_expected)-> value vl_received {
     setverdict(pass,"expected message received: ",vl_received)
    }
    [] myport.receive (charstring:?) -> value vl_received{
      setverdict(fail,"Unexpected message received: ",vl_received)
    }
    [] T_MyCompDummyTimer.timeout { setverdict(inconc);}
  }
}

//=========================================================================
// Control Part
//=========================================================================
control {
  var RoC vl_inputs := {
    "HELLO WORLD!",
    "hello world",
    "Hello World!",
    "hello WORLD!",
    "hELLO wORLD!",
    "helloworld!"
  }
  var integer i, vl_noStrings := sizeof(vl_inputs);
  for (i:=0; i< vl_noStrings; i:=i+1){
    execute (TC(vl_inputs[i]),5.0)
  }
  
  //3 pass, 3 fail expected
} // end of control part

}  // end of module