1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# AC_SEARCH_LIBS_FNARG(FUNCTION, SEARCH-LIBS, [ARGS], [INCLUDES],
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
# [OTHER-LIBRARIES])
# --------------------------------------------------------
# Search for a library defining FUNC, if it's not already available.
AC_DEFUN([AC_SEARCH_LIBS_FNARG],
[AS_VAR_PUSHDEF([ac_Search], [ac_cv_search_$1])dnl
AC_CACHE_CHECK([for library containing $1], [ac_Search],
[ac_func_search_save_LIBS=$LIBS
codeline="$1($3);"
AC_LANG_CONFTEST([AC_LANG_PROGRAM([$4], [[$codeline]])])
for ac_lib in '' $2; do
if test -z "$ac_lib"; then
ac_res="none required"
else
ac_res=-l$ac_lib
LIBS="-l$ac_lib $7 $ac_func_search_save_LIBS"
fi
AC_LINK_IFELSE([], [AS_VAR_SET([ac_Search], [$ac_res])])
AS_VAR_SET_IF([ac_Search], [break])
done
AS_VAR_SET_IF([ac_Search], , [AS_VAR_SET([ac_Search], [no])])
rm conftest.$ac_ext
LIBS=$ac_func_search_save_LIBS])
AS_VAR_COPY([ac_res], [ac_Search])
AS_IF([test "$ac_res" != no],
[test "$ac_res" = "none required" || LIBS="$ac_res $LIBS"
$5],
[$6])
AS_VAR_POPDEF([ac_Search])dnl
])
# AC_CHECK_FUNC_FNARG(FUNCTION, [ARGS], [INCLUDES],
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
# -----------------------------------------------------------------
# Check whether FUNCTION links in the current language. Execute
# ACTION-IF-FOUND or ACTION-IF-NOT-FOUND.
AC_DEFUN([AC_CHECK_FUNC_FNARG],
[AC_MSG_CHECKING($1)
codeline="$1($2);"
AC_LINK_IFELSE([AC_LANG_PROGRAM([$3],[$codeline])],
[ac_func_fnarg_found=yes],
[ac_func_fnarg_found=no])
AC_MSG_RESULT([$ac_func_fnarg_found])
AS_IF([test "$ac_func_fnarg_found" != no],
[AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_]$1),[1], [Define to 1 if $1 is present]) $4],
[$5])
])
# AC_SEARCH_LIBS_ENV32(FUNCTION, SEARCH-LIBS,
# [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND],
# [OTHER-LIBRARIES])
# --------------------------------------------------------
# Search for a library defining FUNC, if it's not already available.
AC_DEFUN([AC_SEARCH_LIBS_ENV32],
[AS_VAR_PUSHDEF([ac_Search], [ac_cv_search_32b_$1])dnl
AC_CACHE_CHECK([for 32bits library containing $1], [ac_Search],
[save_CFLAGS=$CFLAGS; CFLAGS="$CFLAGS -m32"
ac_func_search_save_LIBS=$LIBS
ac_func_search_save_LIBS32=$LIBS32
AC_LANG_CONFTEST([AC_LANG_CALL([], [$1])])
for ac_lib in '' $2; do
if test -z "$ac_lib"; then
ac_res="none required"
else
ac_res=-l$ac_lib
LIBS="-l$ac_lib $5 $ac_func_search_save_LIBS32"
fi
AC_LINK_IFELSE([], [AS_VAR_SET([ac_Search], [$ac_res])])
AS_VAR_SET_IF([ac_Search], [break])
done
AS_VAR_SET_IF([ac_Search], , [AS_VAR_SET([ac_Search], [no])])
rm conftest.$ac_ext
LIBS32=$ac_func_search_save_LIBS32
LIBS=$ac_func_search_save_LIBS
CFLAGS=$save_CFLAGS])
AS_VAR_COPY([ac_res], [ac_Search])
AS_IF([test "$ac_res" != no],
[test "$ac_res" = "none required" || LIBS32="$ac_res $LIBS32"
$3],
[$4])
AS_VAR_POPDEF([ac_Search])dnl
])
|
