File: efl_compiler.m4

package info (click to toggle)
efl 1.8.6-2.5
  • links: PTS, VCS
  • area: main
  • in suites: stretch
  • size: 122,896 kB
  • ctags: 52,058
  • sloc: ansic: 503,707; sh: 12,299; cpp: 11,154; makefile: 1,756; lisp: 433; pascal: 398; python: 233; asm: 209; objc: 101; xml: 35; sed: 16
file content (90 lines) | stat: -rw-r--r-- 2,493 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
dnl Copyright (C) 2012 Vincent Torri <vincent dot torri at gmail dot com>
dnl This code is public domain and can be freely used or copied.

dnl Macro that check if compiler of linker flags are available


dnl Macro that checks for a compiler flag availability
dnl
dnl _EFL_CHECK_COMPILER_FLAGS(EFL, FLAGS)
dnl AC_SUBST : EFL_CFLAGS (EFL being replaced by its value)
dnl have_flag: yes or no.
AC_DEFUN([_EFL_CHECK_COMPILER_FLAGS],
[dnl
m4_pushdef([UPEFL], m4_translit([[$1]], [-a-z], [_A-Z]))dnl

dnl store in options -Wfoo if -Wno-foo is passed
option="m4_bpatsubst([[$2]], [-Wno-], [-W])"
CFLAGS_save="${CFLAGS}"
CFLAGS="${CFLAGS} ${option}"
AC_LANG_PUSH([C])

AC_MSG_CHECKING([whether the compiler supports $2])
AC_COMPILE_IFELSE(
   [AC_LANG_PROGRAM([[]])],
   [have_flag="yes"],
   [have_flag="no"])
AC_MSG_RESULT([${have_flag}])

AC_LANG_POP([C])
CFLAGS="${CFLAGS_save}"
if test "x${have_flag}" = "xyes" ; then
   UPEFL[_CFLAGS]="${UPEFL[_CFLAGS]} [$2]"
fi
AC_SUBST(UPEFL[_CFLAGS])dnl
m4_popdef([UPEFL])dnl
])

dnl EFL_CHECK_COMPILER_FLAGS(EFL, FLAGS)
dnl Checks if FLAGS are supported and add to EFL_CLFAGS.
dnl
dnl It will first try every flag at once, if one fails will try them one by one.
AC_DEFUN([EFL_CHECK_COMPILER_FLAGS],
[dnl
_EFL_CHECK_COMPILER_FLAGS([$1], [$2])
if test "${have_flag}" != "yes"; then
m4_foreach_w([flag], [$2], [_EFL_CHECK_COMPILER_FLAGS([$1], m4_defn([flag]))])
fi
])


dnl Macro that checks for a linker flag availability
dnl
dnl _EFL_CHECK_LINKER_FLAGS(EFL, FLAGS)
dnl AC_SUBST : EFL_LDFLAGS (EFL being replaced by its value)
dnl have_flag: yes or no
AC_DEFUN([_EFL_CHECK_LINKER_FLAGS],
[dnl
m4_pushdef([UPEFL], m4_translit([[$1]], [-a-z], [_A-Z]))dnl

LDFLAGS_save="${LDFLAGS}"
LDFLAGS="${LDFLAGS} $2"
AC_LANG_PUSH([C])

AC_MSG_CHECKING([whether the linker supports $2])
AC_LINK_IFELSE(
   [AC_LANG_PROGRAM([[]])],
   [have_flag="yes"],
   [have_flag="no"])
AC_MSG_RESULT([${have_flag}])

AC_LANG_POP([C])
LDFLAGS="${LDFLAGS_save}"
if test "x${have_flag}" = "xyes" ; then
   UPEFL[_LDFLAGS]="${UPEFL[_LDFLAGS]} [$2]"
fi
AC_SUBST(UPEFL[_LDFLAGS])dnl
m4_popdef([UPEFL])dnl
])

dnl EFL_CHECK_LINKER_FLAGS(EFL, FLAGS)
dnl Checks if FLAGS are supported and add to EFL_CLFAGS.
dnl
dnl It will first try every flag at once, if one fails will try them one by one.
AC_DEFUN([EFL_CHECK_LINKER_FLAGS],
[dnl
_EFL_CHECK_LINKER_FLAGS([$1], [$2])
if test "${have_flag}" != "yes"; then
m4_foreach_w([flag], [$2], [_EFL_CHECK_LINKER_FLAGS([$1], m4_defn([flag]))])
fi
])dnl