File: dhmlaa.f90

package info (click to toggle)
elkcode 5.4.24-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 12,840 kB
  • sloc: f90: 48,415; fortran: 22,457; perl: 965; makefile: 384; sh: 369; python: 105; ansic: 67
file content (94 lines) | stat: -rw-r--r-- 2,788 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94

! Copyright (C) 2012 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine dhmlaa(ias,ngp,ngpq,apwalm,apwalmq,dapwalm,dapwalmq,ld,dh)
use modmain
use modphonon
implicit none
! arguments
integer, intent(in) :: ias
integer, intent(in) :: ngp,ngpq
complex(8), intent(in) :: apwalm(ngkmax,apwordmax,lmmaxapw)
complex(8), intent(in) :: apwalmq(ngkmax,apwordmax,lmmaxapw)
complex(8), intent(in) :: dapwalm(ngkmax,apwordmax,lmmaxapw)
complex(8), intent(in) :: dapwalmq(ngkmax,apwordmax,lmmaxapw)
integer, intent(in) :: ld
complex(8), intent(inout) :: dh(ld,*)
! local variables
integer is,io,jo
integer l1,l2,l3,m1,m2,m3
integer lm1,lm2,lm3
real(8) t0
complex(8) z1,zsum
! automatic arrays
complex(8) x1(ngpq),y1(ngp),y2(ngp)
is=idxis(ias)
t0=0.5d0*rmt(is)**2
lm1=0
do l1=0,lmaxapw
  do m1=-l1,l1
    lm1=lm1+1
    do io=1,apword(l1,is)
      y1(:)=0.d0
      lm3=0
      do l3=0,lmaxapw
        do m3=-l3,l3
          lm3=lm3+1
          do jo=1,apword(l3,is)
            zsum=0.d0
            do l2=0,lmaxo
              if (mod(l1+l2+l3,2).eq.0) then
                do m2=-l2,l2
                  lm2=idxlm(l2,m2)
                  zsum=zsum+gntyyy(lm1,lm2,lm3)*dhaa(lm2,jo,l3,io,l1,ias)
                end do
              end if
            end do
            if (abs(dble(zsum))+abs(aimag(zsum)).gt.1.d-14) then
              call zaxpy(ngp,zsum,apwalm(:,jo,lm3),1,y1,1)
            end if
          end do
        end do
      end do
      if (ias.eq.iasph) then
        y2(:)=0.d0
        lm3=0
        do l3=0,lmaxapw
          do m3=-l3,l3
            lm3=lm3+1
            do jo=1,apword(l3,is)
              zsum=0.d0
              do l2=0,lmaxo
                if (mod(l1+l2+l3,2).eq.0) then
                  do m2=-l2,l2
                    lm2=idxlm(l2,m2)
                    zsum=zsum+gntyry(lm1,lm2,lm3)*haa(lm2,jo,l3,io,l1,ias)
                  end do
                end if
              end do
              if (abs(dble(zsum))+abs(aimag(zsum)).gt.1.d-14) then
                call zaxpy(ngp,zsum,dapwalm(:,jo,lm3),1,y1,1)
                call zaxpy(ngp,zsum,apwalm(:,jo,lm3),1,y2,1)
              end if
            end do
          end do
        end do
! kinetic surface contribution
        do jo=1,apword(l1,is)
          z1=t0*apwfr(nrmt(is),1,io,l1,ias)*apwdfr(jo,l1,ias)
          call zaxpy(ngp,z1,dapwalm(:,jo,lm1),1,y1,1)
          call zaxpy(ngp,z1,apwalm(:,jo,lm1),1,y2,1)
        end do
        x1(1:ngpq)=conjg(dapwalmq(1:ngpq,io,lm1))
        call zgerci(ngpq,ngp,x1,y2,ld,dh)
      end if
      x1(1:ngpq)=conjg(apwalmq(1:ngpq,io,lm1))
      call zgerci(ngpq,ngp,x1,y1,ld,dh)
    end do
  end do
end do
return
end subroutine