File: factr.f90

package info (click to toggle)
elkcode 5.4.24-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 12,840 kB
  • sloc: f90: 48,415; fortran: 22,457; perl: 965; makefile: 384; sh: 369; python: 105; ansic: 67
file content (62 lines) | stat: -rw-r--r-- 1,161 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

! Copyright (C) 2002-2005 J. K. Dewhurst, S. Sharma and C. Ambrosch-Draxl.
! This file is distributed under the terms of the GNU Lesser General Public
! License. See the file COPYING for license details.

!BOP
! !ROUTINE: factr
! !INTERFACE:
real(8) function factr(n,d)
! !INPUT/OUTPUT PARAMETERS:
!   n : numerator (in,integer)
!   d : denominator (in,integer)
! !DESCRIPTION:
!   Returns the ratio $n!/d!$ for $n,d\ge 0$. Performs no under- or overflow
!   checking.
!
! !REVISION HISTORY:
!   Created October 2002 (JKD)
!EOP
!BOC
implicit none
! arguments
integer, intent(in) :: n,d
! local variables
integer i
! external functions
real(8) factnm
external factnm
if (n.lt.0) then
  write(*,*)
  write(*,'("Error(factr): n < 0 : ",I8)') n
  write(*,*)
  stop
end if
if (d.lt.0) then
  write(*,*)
  write(*,'("Error(factr): d < 0 : ",I8)') d
  write(*,*)
  stop
end if
if (d.eq.1) then
  factr=factnm(n,1)
  return
end if
if (n.lt.d) then
  factr=dble(n+1)
  do i=n+2,d
    factr=factr*dble(i)
  end do
  factr=1.d0/factr
else if (n.eq.d) then
  factr=1.d0
else
  factr=dble(d+1)
  do i=d+2,n
    factr=factr*dble(i)
  end do
end if
return
end function
!EOC