File: genexpmt.f90

package info (click to toggle)
elkcode 5.4.24-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 12,840 kB
  • sloc: f90: 48,415; fortran: 22,457; perl: 965; makefile: 384; sh: 369; python: 105; ansic: 67
file content (58 lines) | stat: -rw-r--r-- 1,402 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

! Copyright (C) 2009 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

subroutine genexpmt(ngp,jlgpr,ylmgp,ld,sfacgp,expmt)
use modmain
implicit none
! arguments
integer, intent(in) :: ngp
real(8), intent(in) :: jlgpr(njcmax,nspecies,ngp)
complex(8), intent(in) :: ylmgp(lmmaxo,ngp)
integer, intent(in) :: ld
complex(8), intent(in) :: sfacgp(ld,natmtot)
complex(8), intent(out) :: expmt(npcmtmax,natmtot,ngp)
! local variables
integer ig,is,ia,ias
integer nrc,nrci,irc,npc
integer lmax,l,m,lm,i,j
complex(8) z1
! automatic arrays
complex(8) ylm(lmmaxo)
complex(8) zfmt1(npcmtmax),zfmt2(npcmtmax)
do ig=1,ngp
  ylm(:)=conjg(ylmgp(:,ig))
  do is=1,nspecies
    nrc=nrcmt(is)
    nrci=nrcmti(is)
    npc=npcmt(is)
    lmax=lmaxi
    i=0
    j=0
    do irc=1,nrc
      lm=0
      do l=0,lmax
        j=j+1
        z1=jlgpr(j,is,ig)*zil(l)
        do m=-l,l
          lm=lm+1
          i=i+1
          zfmt1(i)=z1*ylm(lm)
        end do
      end do
      if (irc.eq.nrci) lmax=lmaxo
    end do
! convert to spherical coordinates
    call zbsht(nrc,nrci,zfmt1,zfmt2)
! mutiply by phase factors and store for all atoms
    do ia=1,natoms(is)
      ias=idxas(ia,is)
      z1=fourpi*sfacgp(ig,ias)
      expmt(1:npc,ias,ig)=z1*zfmt2(1:npc)
    end do
  end do
end do
return
end subroutine