File: rdmdedc.f90

package info (click to toggle)
elkcode 5.4.24-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 12,840 kB
  • sloc: f90: 48,415; fortran: 22,457; perl: 965; makefile: 384; sh: 369; python: 105; ansic: 67
file content (57 lines) | stat: -rw-r--r-- 1,421 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

! Copyright (C) 2007 J. K. Dewhurst, S. Sharma and E. K. U. Gross.
! This file is distributed under the terms of the GNU General Public License.
! See the file COPYING for license details.

!BOP
! !ROUTINE: rdmdedc
! !INTERFACE:
subroutine rdmdedc(dedc)
! !USES:
use modmain
use modrdm
use modomp
! !INPUT/OUTPUT PARAMETERS:
!   dedc : energy derivative (out,complex(nstsv,nstsv,nkpt))
! !DESCRIPTION:
!   Calculates the derivative of the total energy w.r.t. the second-variational
!   coefficients {\tt evecsv}.
!
! !REVISION HISTORY:
!   Created 2008 (Sharma)
!EOP
!BOC
implicit none
! arguments
complex(8), intent(out) :: dedc(nstsv,nstsv,nkpt)
! local variables
integer ik,ist,nthd
! allocatable arrays
complex(8), allocatable :: evecsv(:,:),c(:,:)
call omp_hold(nkpt,nthd)
!$OMP PARALLEL DEFAULT(SHARED) &
!$OMP PRIVATE(evecsv,c,ist) &
!$OMP NUM_THREADS(nthd)
!$OMP DO
do ik=1,nkpt
  allocate(evecsv(nstsv,nstsv))
  allocate(c(nstsv,nstsv))
! get the eigenvectors from file
  call getevecsv(filext,ik,vkl(:,ik),evecsv)
! kinetic and Coulomb potential contribution
  call zgemm('N','N',nstsv,nstsv,nstsv,zone,evecsv,nstsv,vclmat(:,:,ik),nstsv, &
   zzero,c,nstsv)
  do ist=1,nstsv
    dedc(:,ist,ik)=occsv(ist,ik)*(dkdc(:,ist,ik)+c(:,ist))
  end do
  deallocate(evecsv,c)
end do
!$OMP END DO
!$OMP END PARALLEL
call omp_free(nthd)
! exchange-correlation contribution
call rdmdexcdc(dedc)
return
end subroutine
!EOC