1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
|
;;; vc-mtn.el --- VC backend for Monotone -*- lexical-binding: t -*-
;; Copyright (C) 2007-2025 Free Software Foundation, Inc.
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
;; Keywords: vc
;; Package: vc
;; Obsolete-since: 29.1
;; This file is part of GNU Emacs.
;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;;
;;; TODO:
;; - The `previous-version' VC method needs to be supported, 'D' in
;; log-view-mode uses it.
;;; Code:
(eval-when-compile (require 'vc))
(defgroup vc-mtn nil
"VC Monotone (mtn) backend."
:version "24.1"
:group 'vc)
(defcustom vc-mtn-diff-switches t
"String or list of strings specifying switches for monotone diff under VC.
If nil, use the value of `vc-diff-switches'. If t, use no switches."
:type '(choice (const :tag "Unspecified" nil)
(const :tag "None" t)
(string :tag "Argument String")
(repeat :tag "Argument List" :value ("") string))
:version "23.1")
(defcustom vc-mtn-annotate-switches nil
"String or list of strings specifying switches for mtn annotate under VC.
If nil, use the value of `vc-annotate-switches'. If t, use no
switches."
:type '(choice (const :tag "Unspecified" nil)
(const :tag "None" t)
(string :tag "Argument String")
(repeat :tag "Argument List" :value ("") string))
:version "25.1")
(defcustom vc-mtn-program "mtn"
"Name of the monotone executable."
:type 'string)
;; Clear up the cache to force vc-call to check again and discover
;; new functions when we reload this file.
(put 'Mtn 'vc-functions nil)
(unless (executable-find vc-mtn-program)
;; vc-mtn.el is 100% non-functional without the `mtn' executable.
(setq vc-handled-backends (delq 'Mtn vc-handled-backends)))
;;;###autoload
(defconst vc-mtn-admin-dir "_MTN" "Name of the monotone directory.")
;;;###autoload
(defconst vc-mtn-admin-format (concat vc-mtn-admin-dir "/format")
"Name of the monotone directory's format file.")
;;;###autoload (defun vc-mtn-registered (file)
;;;###autoload (if (vc-find-root file vc-mtn-admin-format)
;;;###autoload (progn
;;;###autoload (load "vc-mtn" nil t)
;;;###autoload (vc-mtn-registered file))))
(defun vc-mtn-revision-granularity () 'repository)
(defun vc-mtn-checkout-model (_files) 'implicit)
(defun vc-mtn-root (file)
(setq file (expand-file-name file)
file (if (file-directory-p file)
(file-name-as-directory file)
(file-name-directory file)))
(or (vc-file-getprop file 'vc-mtn-root)
(vc-file-setprop file 'vc-mtn-root
(vc-find-root file vc-mtn-admin-format))))
(defun vc-mtn-find-admin-dir (file)
"Return the administrative directory of FILE."
(expand-file-name vc-mtn-admin-dir (vc-mtn-root file)))
(defun vc-mtn-find-ignore-file (file)
"Return the mtn ignore file that controls FILE."
(expand-file-name ".mtnignore" (vc-mtn-root file)))
(defun vc-mtn-registered (file)
(let ((root (vc-mtn-root file)))
(when root
(vc-mtn-state file))))
(defun vc-mtn-command (buffer okstatus files &rest flags)
"A wrapper around `vc-do-command' for use in vc-mtn.el."
(let ((process-environment
;; Avoid localization of messages so we can parse the output.
(cons "LC_MESSAGES=C" process-environment)))
(apply #'vc-do-command (or buffer "*vc*") okstatus vc-mtn-program
files flags)))
(defun vc-mtn-state (file)
;; If `mtn' fails or returns status>0, or if the search files, just
;; return nil.
(ignore-errors
(with-temp-buffer
(vc-mtn-command t 0 file "status")
(goto-char (point-min))
(re-search-forward
"^ \\(?:\\(patched\\)\\|\\(added\\) \\(?:.*\\)\\)\\|no changes$")
(cond ((match-end 1) 'edited)
((match-end 2) 'added)
(t 'up-to-date)))))
(defun vc-mtn-after-dir-status (update-function)
(let (result)
(goto-char (point-min))
(re-search-forward "\\(?:Current b\\|B\\)ranch: *\\(.*\\)\n?\nChanges against parent \\(.*\\)" nil t)
(while (re-search-forward
"^ \\(?:\\(patched \\)\\|\\(added \\)\\)\\(.*\\)$" nil t)
(cond ((match-end 1) (push (list (match-string 3) 'edited) result))
((match-end 2) (push (list (match-string 3) 'added) result))))
(funcall update-function result)))
;; dir-status-files called from vc-dir, which loads vc,
;; which loads vc-dispatcher.
(declare-function vc-exec-after "vc-dispatcher" (code &optional success))
(defun vc-mtn-dir-status-files (dir _files update-function)
(vc-mtn-command (current-buffer) 'async dir "status")
(vc-run-delayed
(vc-mtn-after-dir-status update-function)))
(defun vc-mtn-working-revision (file)
;; If `mtn' fails or returns status>0, or if the search fails, just
;; return nil.
(ignore-errors
(with-temp-buffer
(vc-mtn-command t 0 file "status")
(goto-char (point-min))
(re-search-forward "\\(?:Current b\\|B\\)ranch: *\\(.*\\)\n?\nChanges against parent \\(.*\\)")
(match-string 2))))
(defun vc-mtn-workfile-branch (file)
;; If `mtn' fails or returns status>0, or if the search files, just
;; return nil.
(ignore-errors
(with-temp-buffer
(vc-mtn-command t 0 file "status")
(goto-char (point-min))
(re-search-forward "\\(?:Current b\\|B\\)ranch: *\\(.*\\)\n?\nChanges against parent \\(.*\\)")
(match-string 1))))
;; Mode-line rewrite code copied from vc-arch.el.
(defcustom vc-mtn-mode-line-rewrite
'(("\\`[^:/#]*[:/#]" . "")) ;Drop the host part.
"Rewrite rules to shorten Mtn's revision names on the mode-line."
:type '(repeat (cons regexp string))
:version "22.2")
(defun vc-mtn-mode-line-string (file)
"Return a string for `vc-mode-line' to put in the mode line for FILE."
(let ((branch (vc-mtn-workfile-branch file)))
(if branch
(progn
(dolist (rule vc-mtn-mode-line-rewrite)
(if (string-match (car rule) branch)
(setq branch (replace-match (cdr rule) t nil branch))))
(format "Mtn%c%s"
(pcase (vc-state file)
((or 'up-to-date 'needs-update) ?-)
('added ?@)
(_ ?:))
branch))
"")))
(defun vc-mtn-register (files &optional _comment)
(vc-mtn-command nil 0 files "add"))
(defun vc-mtn-responsible-p (file) (vc-mtn-root file))
(declare-function log-edit-extract-headers "log-edit" (headers string))
(defun vc-mtn-checkin (files comment &optional _rev)
(apply #'vc-mtn-command nil 0 files
(nconc (list "commit" "-m")
(log-edit-extract-headers '(("Author" . "--author")
("Date" . "--date"))
comment))))
(defun vc-mtn-find-revision (file rev buffer)
;; null rev means latest revision
(if rev
(vc-mtn-command buffer 0 file "cat" "-r" rev)
(vc-mtn-command buffer 0 file "cat")))
;; (defun vc-mtn-checkout (file &optional rev)
;; )
(defun vc-mtn-revert (file &optional contents-done)
(unless contents-done
(vc-mtn-command nil 0 file "revert")))
(defun vc-mtn-print-log (files buffer &optional _shortlog start-revision limit)
"Print commit logs associated with FILES into specified BUFFER.
_SHORTLOG is ignored.
If START-REVISION is non-nil, it is the newest revision to show.
If LIMIT is non-nil, show no more than this many entries."
(apply #'vc-mtn-command buffer 0 files "log"
(append
(when start-revision (list "--from" (format "%s" start-revision)))
(when limit (list "--last" (format "%s" limit))))))
(defvar log-view-message-re)
(defvar log-view-file-re)
(defvar log-view-font-lock-keywords)
(defvar log-view-per-file-logs)
(define-derived-mode vc-mtn-log-view-mode log-view-mode "Mtn-Log-View"
;; Don't match anything.
(setq-local log-view-file-re regexp-unmatchable)
(setq-local log-view-per-file-logs nil)
;; TODO: Use a more precise regexp than "[ |/]+" to avoid false positives
;; in the ChangeLog text.
(setq-local log-view-message-re
"^[ |/]+Revision: \\([0-9a-f]+\\)")
(require 'add-log) ;For change-log faces.
(setq-local log-view-font-lock-keywords
(append log-view-font-lock-keywords
'(("^[ |]+Author: \\(.*\\)" (1 'change-log-email))
("^[ |]+Date: \\(.*\\)" (1 'change-log-date))))))
;; (defun vc-mtn-show-log-entry (revision)
;; )
(autoload 'vc-switches "vc")
(defun vc-mtn-diff (files &optional rev1 rev2 buffer _async)
"Get a difference report using monotone between two revisions of FILES."
(apply #'vc-mtn-command (or buffer "*vc-diff*")
1 ; bug#21969
files "diff"
(append
(vc-switches 'mtn 'diff)
(if rev1 (list "-r" rev1)) (if rev2 (list "-r" rev2)))))
(defun vc-mtn-annotate-command (file buf &optional rev)
(apply #'vc-mtn-command buf 'async file "annotate"
(append (vc-switches 'mtn 'annotate)
(if rev (list "-r" rev)))))
(declare-function vc-annotate-convert-time "vc-annotate" (&optional time))
(defconst vc-mtn-annotate-full-re
"^ *\\([0-9a-f]+\\)\\.* by [^ ]+ \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\): ")
(defconst vc-mtn-annotate-any-re
(concat "^\\(?: +: \\|" vc-mtn-annotate-full-re "\\)"))
(defun vc-mtn-annotate-time ()
(when (looking-at vc-mtn-annotate-any-re)
(goto-char (match-end 0))
(let ((year (match-string 2)))
(if (not year)
;; Look for the date on a previous line.
(save-excursion
(get-text-property (1- (previous-single-property-change
(point) 'vc-mtn-time nil (point-min)))
'vc-mtn-time))
(let ((time (vc-annotate-convert-time
(encode-time 0 0 0
(string-to-number (match-string 4))
(string-to-number (match-string 3))
(string-to-number year)
t))))
(let ((inhibit-read-only t)
(inhibit-modification-hooks t))
(put-text-property (match-beginning 0) (match-end 0)
'vc-mtn-time time))
time)))))
(defun vc-mtn-annotate-extract-revision-at-line ()
(save-excursion
(when (or (looking-at vc-mtn-annotate-full-re)
(re-search-backward vc-mtn-annotate-full-re nil t))
(match-string 1))))
;;; Revision completion.
(defun vc-mtn-list-tags ()
(with-temp-buffer
(vc-mtn-command t 0 nil "list" "tags")
(goto-char (point-min))
(let ((tags ()))
(while (re-search-forward "^[^ ]+" nil t)
(push (match-string 0) tags))
tags)))
(defun vc-mtn-list-branches ()
(with-temp-buffer
(vc-mtn-command t 0 nil "list" "branches")
(goto-char (point-min))
(let ((branches ()))
(while (re-search-forward "^.+" nil t)
(push (match-string 0) branches))
branches)))
(defun vc-mtn-list-revision-ids (prefix)
(with-temp-buffer
(vc-mtn-command t 0 nil "complete" "revision" prefix)
(goto-char (point-min))
(let ((ids ()))
(while (re-search-forward "^.+" nil t)
(push (match-string 0) ids))
ids)))
(defun vc-mtn-revision-completion-table (_files)
;; What about using `files'?!? --Stef
(lambda (string pred action)
(cond
;; Special chars for composite selectors.
((string-match ".*[^\\]\\(\\\\\\\\\\)*[/|;(]" string)
(completion-table-with-context (substring string 0 (match-end 0))
(vc-mtn-revision-completion-table nil)
(substring string (match-end 0))
pred action))
;; "Tag" selectors.
((string-match "\\`t:" string)
(complete-with-action action
(mapcar (lambda (tag) (concat "t:" tag))
(vc-mtn-list-tags))
string pred))
;; "Branch" or "Head" selectors.
((string-match "\\`[hb]:" string)
(let ((prefix (match-string 0 string)))
(complete-with-action action
(mapcar (lambda (tag) (concat prefix tag))
(vc-mtn-list-branches))
string pred)))
;; "ID" selectors.
((string-match "\\`i:" string)
(complete-with-action action
(mapcar (lambda (tag) (concat "i:" tag))
(vc-mtn-list-revision-ids
(substring string (match-end 0))))
string pred))
(t
(complete-with-action action
'("t:" "b:" "h:" "i:"
;; Completion not implemented for these.
"c:" "a:" "k:" "d:" "m:" "e:" "l:" "i:" "p:"
;; These have no arg to complete.
"u:" "w:"
;; Selector functions.
"difference(" "lca(" "max(" "ancestors("
"descendants(" "parents(" "children("
"pick(")
string pred)))))
(provide 'vc-mtn)
;;; vc-mtn.el ends here
|
