1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
|
C Copyright 1981-2007 ECMWF
C
C Licensed under the GNU Lesser General Public License which
C incorporates the terms and conditions of version 3 of the GNU
C General Public License.
C See LICENSE and gpl-3.0.txt for details.
C
INTEGER FUNCTION IGDINS (KILATG, KINS, KOLATG, KONS, ONPOLE,
1 OSPOLE, KNSIND, KNSDIST, KPR, KERR)
C
C---->
C**** *IGDINS*
C
C PURPOSE
C _______
C
C Calculate the distances between points in an output latitude
C array and its North and South neighbours in the input latitude
C array.
C
C INTERFACE
C _________
C
C IERR = IGDINS (KILATG, KINS, KOLATG, KONS, ONPOLE, OSPOLE,
C 1 KNSIND, KNSDIST, KPR, KERR)
C
C Input parameters
C ________________
C
C KILATG - The array of input latitudes.
C
C KINS - The number of points in the North-South direction
C in the input field.
C
C KOLATG - The array of output latitudes.
C
C KONS - The number of points in the North-South direction
C in the output field.
C
C ONPOLE - This variable will be true if the input field
C includes the most Northerly line of latitude for
C the field type. This means latitude 90 North for
C a regular field and the first line of a Gaussian
C field.
C
C OSPOLE - This variable will be true if the input field
C includes the most Southerly line of latitude for
C the field type. This means latitude 90 South for
C a regular field and the last line of a Gaussian
C field.
C
C KPR - The debug print switch.
C 0 , No debugging output.
C 1 , Produce debugging output.
C
C KERR - The error control flag.
C -ve, No error message. Return error code.
C 0 , Hard failure with error message.
C +ve, Print error message. Return error code.
C
C Output parameters
C ________________
C
C KNSIND - This array will contain the array offsets of the
C North and South points in the input array required
C for interpolation.
C
C KNSDIST - This array will contain the distances to lines
C in input field from the associated lines of
C latitude in the output field.
C
C Return value
C ____________
C
C The error indicator (INTEGER).
C
C Error and Warning Return Values
C _______________________________
C
C 24501 An output latitude was found that was outside the area
C spanned by the input latitudes.
C
C Common block usage
C __________________
C
C None
C
C EXTERNALS
C _________
C
C INTLOG(R) - Logs messages.
C
C METHOD
C ______
C
C This routine will create the arrays of offsets and distance as
C two arrays of length (2, Number of output latitudes).
C
C If an input Gaussian grid includes the "polar" line and the
C output field includes a line of latitude between this "polar"
C line and the pole then the position of this "polar" Gaussian
C line is assumed to be at the pole for that line of latitude only.
C
C REFERENCE
C _________
C
C None
C
C COMMENTS
C ________
C
C Program contains sections 0 to 2 and 9
C
C AUTHOR
C ______
C
C K. Fielding *ECMWF* Oct 1993
C
C MODIFICATIONS
C _____________
C
C None
C
C----<
C _______________________________________________________
C
C
C* Section 0. Definition of variables.
C _______________________________________________________
C
C* Prefix conventions for variable names
C
C Logical L (but not LP), global or common.
C O, dummy argument
C G, local variable
C LP, parameter.
C Character C, global or common.
C H, dummy argument
C Y (but not YP), local variable
C YP, parameter.
C Integer M and N, global or common.
C K, dummy argument
C I, local variable
C J (but not JP), loop control
C JP, parameter.
C REAL A to F and Q to X, global or common.
C P (but not PP), dummy argument
C Z, local variable
C PP, parameter.
C
C Implicit statement to force declarations
C
IMPLICIT NONE
C
#include "parim.h"
C
C Dummy arguments
LOGICAL ONPOLE, OSPOLE
INTEGER KINS, KONS, KPR, KERR
INTEGER KILATG (KINS), KOLATG (KONS)
INTEGER KNSIND (2, KONS), KNSDIST (2, KONS)
C
C Local variables
INTEGER IBASE
INTEGER JOUT, JINP
INTEGER JPROUTINE
PARAMETER (JPROUTINE = 24500)
C
C _______________________________________________________
C
C* Section 1. Initialisation
C _______________________________________________________
C
100 CONTINUE
C
IF (KPR.GE.1) CALL INTLOG(JP_DEBUG,'IGDINS: Section 1.',JPQUIET)
C
IGDINS = 0
C
IF (KPR .GE. 1) THEN
CALL INTLOG(JP_DEBUG,'IGDINS: Input parameters.',JPQUIET)
CALL INTLOG(JP_DEBUG,'IGDINS: No.input fld lines = ',KINS)
CALL INTLOG(JP_DEBUG,'IGDINS: No.output fld lines = ',KONS)
CALL INTLOG(JP_DEBUG,'IGDINS: Input fld spread from ',KILATG(1))
CALL INTLOG(JP_DEBUG,'IGDINS: to ', KILATG(KINS))
CALL INTLOG(JP_DEBUG,'IGDINS: Outpt fld spread from ',KOLATG(1))
CALL INTLOG(JP_DEBUG,'IGDINS: to ', KOLATG(KONS))
C
IF ( ONPOLE ) THEN
CALL INTLOG(JP_DEBUG,'IGDINS: N. pole in inpt field.',JPQUIET)
ELSE
CALL INTLOG(JP_DEBUG,'IGDINS: N.pole NOT in inpt fld',JPQUIET)
ENDIF
C
IF ( OSPOLE ) THEN
CALL INTLOG(JP_DEBUG,'IGDINS: S. pole in inpt field.',JPQUIET)
ELSE
CALL INTLOG(JP_DEBUG,'IGDINS: S.pole NOT in inpt fld',JPQUIET)
ENDIF
ENDIF
C
C _______________________________________________________
C
C* Section 2. Select points along a line of meridian
C _______________________________________________________
C
200 CONTINUE
C
IF (KPR.GE.1) CALL INTLOG(JP_DEBUG,'IGDINS: Section 2.',JPQUIET)
C
C Last latitude found to be used as start of search
C for next latitude
C
IBASE = 1
C
DO 220 JOUT = 1, KONS
C
C Allow special code for points beyond North limit of
C Gaussian grid which has all points up to pole
C
C Sinisa remove check for pole - already exist in iagcntl
IF (IBASE .EQ. 1 .AND. KOLATG(JOUT).GT.KILATG (1) ) THEN
C
KNSIND (JP_I_N, JOUT) = 1
KNSIND (JP_I_S, JOUT) = 2
IBASE = 1
C
KNSDIST (JP_I_N, JOUT) = JP90 - KOLATG (JOUT)
KNSDIST (JP_I_S, JOUT) = KOLATG (JOUT) - KILATG (2)
C
GO TO 220
C
ENDIF
C
DO 210 JINP = IBASE, KINS - 1
C
C This test allows the exact match at both ends to be treated
C correctly. Although the point is checked for equality at
C both ends the first test will be used except for the South
C Gaussian limit.
C
IF (KOLATG (JOUT) .LE. KILATG (JINP) .AND.
X KOLATG (JOUT) .GE. KILATG (JINP + 1) ) THEN
C
KNSIND (JP_I_N, JOUT) = JINP
KNSIND (JP_I_S, JOUT) = JINP + 1
IBASE = JINP
C
KNSDIST (JP_I_N, JOUT) = KILATG (JINP) -
X KOLATG (JOUT)
KNSDIST (JP_I_S, JOUT) = KOLATG (JOUT) -
X KILATG (JINP + 1)
C
GO TO 220
C
ENDIF
C
210 CONTINUE
C
C Allow special code for points beyond South limit of
C Gaussian grid which has all points up to pole
C
C Sinisa remove check for pole - already exist in iagcntl
IF (KOLATG (JOUT) .LT. KILATG (KINS) ) THEN
C
KNSIND (JP_I_N, JOUT) = KINS - 1
KNSIND (JP_I_S, JOUT) = KINS
IBASE = KINS
C
KNSDIST (JP_I_N, JOUT) = KILATG (KINS - 1) -
X KOLATG (JOUT)
KNSDIST (JP_I_S, JOUT) = KOLATG (JOUT) - JP90
C
ELSE
C
IGDINS = JPROUTINE + 1
IF (KERR .GE. 0) THEN
CALL INTLOGR(JP_ERROR,
X 'IGDINS: Output lat. value ',REAL(KOLATG(JOUT))/PPMULT)
CALL INTLOGR(JP_ERROR,
X 'IGDINS: outside input range = ',REAL(KILATG(1))/PPMULT)
CALL INTLOGR(JP_ERROR,
X 'IGDINS: to ',REAL(KILATG(KINS))/PPMULT)
ENDIF
C
IF (KERR .EQ. 0) CALL INTLOGR(JP_FATAL,
X 'IGDINS: Interpolation failing.',IGDINS)
C
GO TO 900
C
ENDIF
C
220 CONTINUE
C
C
C _______________________________________________________
C
C* Section 9. Return to calling routine. Format statements
C _______________________________________________________
C
900 CONTINUE
C
IF (KPR.GE.1) CALL INTLOG(JP_DEBUG,'IGDINS: Section 9.',JPQUIET)
C
RETURN
END
|
