1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
|
!
! Copyright (C) 2018 Quantum ESPRESSO Foundation
! This file is distributed under the terms of the
! GNU General Public License. See the file `License'
! in the root directory of the present distribution,
! or http://www.gnu.org/copyleft/gpl.txt .
!
!--------------------------------------------------------------------
! Various routines computing gradient and similar quantities via FFT
!--------------------------------------------------------------------
! FIXME: there is a dependency upon "cell_base" via variable tpiba
! (2\pi/a) that maybe should be taken out from here?
!--------------------------------------------------------------------
SUBROUTINE external_gradient( a, grada )
!--------------------------------------------------------------------
!
! Interface for computing gradients of a real function in real space,
! to be called by an external module
!
USE kinds, ONLY : DP
USE fft_base, ONLY : dfftp
USE gvect, ONLY : g
!
IMPLICIT NONE
!
REAL( DP ), INTENT(IN) :: a( dfftp%nnr )
REAL( DP ), INTENT(OUT) :: grada( 3, dfftp%nnr )
! A in real space, grad(A) in real space
CALL fft_gradient_r2r( dfftp, a, g, grada )
RETURN
END SUBROUTINE external_gradient
!----------------------------------------------------------------------------
SUBROUTINE fft_gradient_r2r( dfft, a, g, ga )
!----------------------------------------------------------------------------
!
! ... Calculates ga = \grad a
! ... input : dfft FFT descriptor
! ... a(:) a real function on the real-space FFT grid
! ... g(3,:) G-vectors, in 2\pi/a units
! ... output: ga(3,:) \grad a, real, on the real-space FFT grid
!
USE kinds, ONLY : DP
USE cell_base, ONLY : tpiba
USE fft_interfaces,ONLY : fwfft, invfft
USE fft_types, ONLY : fft_type_descriptor
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
REAL(DP), INTENT(IN) :: a(dfft%nnr), g(3,dfft%ngm)
REAL(DP), INTENT(OUT) :: ga(3,dfft%nnr)
!
INTEGER :: ipol
COMPLEX(DP), ALLOCATABLE :: aux(:), gaux(:)
!
ALLOCATE( aux( dfft%nnr ) )
ALLOCATE( gaux( dfft%nnr ) )
!
aux = CMPLX( a(:), 0.0_dp, kind=DP)
!
! ... bring a(r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... multiply by (iG) to get (\grad_ipol a)(G) ...
!
DO ipol = 1, 3
!
gaux(:) = (0.0_dp, 0.0_dp)
!
gaux(dfft%nl(:)) = g(ipol,:) * CMPLX( -AIMAG( aux(dfft%nl(:)) ), &
REAL( aux(dfft%nl(:)) ), kind=DP)
!
IF ( dfft%lgamma ) THEN
!
gaux(dfft%nlm(:)) = CMPLX( REAL( gaux(dfft%nl(:)) ), &
-AIMAG( gaux(dfft%nl(:)) ), kind=DP)
!
END IF
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ...and add the factor 2\pi/a missing in the definition of G
!
ga(ipol,:) = tpiba * DBLE( gaux(:) )
!
END DO
!
DEALLOCATE( gaux )
DEALLOCATE( aux )
!
RETURN
!
END SUBROUTINE fft_gradient_r2r
!
!--------------------------------------------------------------------
SUBROUTINE fft_qgradient (dfft, a, xq, g, ga)
!--------------------------------------------------------------------
!
! Like fft_gradient_r2r, for complex arrays having a e^{iqr} behavior
! ... input : dfft FFT descriptor
! ... a(:) a complex function on the real-space FFT grid
! ... xq(3) q-vector, in 2\pi/a units
! ... g(3,:) G-vectors, in 2\pi/a units
! ... output: ga(3,:) \grad a, complex, on the real-space FFT grid
!
USE kinds, ONLY: dp
USE cell_base, ONLY: tpiba
USE fft_types, ONLY : fft_type_descriptor
USE fft_interfaces, ONLY: fwfft, invfft
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
!
COMPLEX(DP), INTENT(IN) :: a(dfft%nnr)
REAL(DP), INTENT(IN):: xq(3), g(3,dfft%ngm)
COMPLEX(DP), INTENT(OUT) :: ga(3,dfft%nnr)
INTEGER :: n, ipol
COMPLEX(DP), ALLOCATABLE :: aux(:), gaux(:)
ALLOCATE (gaux(dfft%nnr))
ALLOCATE (aux (dfft%nnr))
! bring a(r) to G-space, a(G) ...
aux (:) = a(:)
CALL fwfft ('Rho', aux, dfft)
! multiply by i(q+G) to get (\grad_ipol a)(q+G) ...
DO ipol = 1, 3
gaux (:) = (0.0_dp, 0.0_dp)
DO n = 1, dfft%ngm
gaux(dfft%nl(n)) = CMPLX( 0.0_dp, xq (ipol) + g(ipol,n), kind=DP ) * &
aux (dfft%nl(n))
IF ( dfft%lgamma ) gaux(dfft%nlm(n)) = CONJG( gaux (dfft%nl(n)) )
END DO
! bring back to R-space, (\grad_ipol a)(r) ...
CALL invfft ('Rho', gaux, dfft)
! ...and add the factor 2\pi/a missing in the definition of q+G
DO n = 1, dfft%nnr
ga (ipol,n) = gaux (n) * tpiba
END DO
END DO
DEALLOCATE (aux)
DEALLOCATE (gaux)
RETURN
END SUBROUTINE fft_qgradient
!
!----------------------------------------------------------------------------
SUBROUTINE fft_gradient_g2r( dfft, a, g, ga )
!----------------------------------------------------------------------------
!
! ... Calculates ga = \grad a - like fft_gradient with a(G) instead of a(r)
! ... input : dfft FFT descriptor
! ... a(:) a(G), a complex function in G-space
! ... g(3,:) G-vectors, in 2\pi/a units
! ... output: ga(3,:) \grad a, real, on the real-space FFT grid
!
USE cell_base, ONLY : tpiba
USE kinds, ONLY : DP
USE fft_interfaces,ONLY : invfft
USE fft_types, ONLY : fft_type_descriptor
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
COMPLEX(DP), INTENT(IN) :: a(dfft%ngm)
REAL(DP), INTENT(IN) :: g(3,dfft%ngm)
REAL(DP), INTENT(OUT) :: ga(3,dfft%nnr)
!
INTEGER :: ipol, n
COMPLEX(DP), ALLOCATABLE :: gaux(:)
!
!
ALLOCATE( gaux( dfft%nnr ) )
ga(:,:) = 0.D0
!
IF ( dfft%lgamma) THEN
!
! ... Gamma tricks: perform 2 FFT's in a single shot
! x and y
ipol = 1
gaux(:) = (0.0_dp,0.0_dp)
!
! ... multiply a(G) by iG to get the gradient in real space
!
DO n = 1, dfft%ngm
gaux(dfft%nl (n)) = CMPLX( 0.0_dp, g(ipol, n), kind=DP )* a(n) - &
g(ipol+1,n) * a(n)
gaux(dfft%nlm(n)) = CMPLX( 0.0_dp,-g(ipol, n), kind=DP )*CONJG(a(n)) +&
g(ipol+1,n) * CONJG(a(n))
ENDDO
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ... bring back to R-space, (\grad_ipol a)(r)
! ... add the factor 2\pi/a missing in the definition of q+G
!
DO n = 1, dfft%nnr
ga (ipol , n) = REAL( gaux(n) ) * tpiba
ga (ipol+1, n) = AIMAG( gaux(n) ) * tpiba
ENDDO
! z
ipol = 3
gaux(:) = (0.0_dp,0.0_dp)
!
! ... multiply a(G) by iG to get the gradient in real space
!
gaux(dfft%nl (:)) = g(ipol,:) * CMPLX( -AIMAG(a(:)), REAL(a(:)), kind=DP)
gaux(dfft%nlm(:)) = CONJG( gaux(dfft%nl(:)) )
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ...and add the factor 2\pi/a missing in the definition of G
!
ga(ipol,:) = tpiba * REAL( gaux(:) )
!
ELSE
!
DO ipol = 1, 3
!
gaux(:) = (0.0_dp,0.0_dp)
!
! ... multiply a(G) by iG to get the gradient in real space
!
gaux(dfft%nl(:)) = g(ipol,:) * CMPLX( -AIMAG(a(:)), REAL(a(:)), kind=DP)
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ...and add the factor 2\pi/a missing in the definition of G
!
ga(ipol,:) = tpiba * REAL( gaux(:) )
!
END DO
!
END IF
!
DEALLOCATE( gaux )
!
RETURN
!
END SUBROUTINE fft_gradient_g2r
!----------------------------------------------------------------------------
SUBROUTINE fft_graddot( dfft, a, g, da )
!----------------------------------------------------------------------------
!
! ... Calculates da = \sum_i \grad_i a_i in R-space
! ... input : dfft FFT descriptor
! ... a(3,:) a real function on the real-space FFT grid
! ... g(3,:) G-vectors, in 2\pi/a units
! ... output: ga(:) \sum_i \grad_i a_i, real, on the real-space FFT grid
!
USE cell_base, ONLY : tpiba
USE kinds, ONLY : DP
USE fft_interfaces,ONLY : fwfft, invfft
USE fft_types, ONLY : fft_type_descriptor
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
REAL(DP), INTENT(IN) :: a(3,dfft%nnr), g(3,dfft%ngm)
REAL(DP), INTENT(OUT) :: da(dfft%nnr)
!
INTEGER :: n, ipol
COMPLEX(DP), ALLOCATABLE :: aux(:), gaux(:)
COMPLEX(DP) :: fp, fm, aux1, aux2
!
ALLOCATE( aux(dfft%nnr) )
ALLOCATE( gaux(dfft%nnr) )
!
gaux(:) = (0.0_dp,0.0_dp)
!
IF ( dfft%lgamma ) THEN
!
! Gamma tricks: perform 2 FFT's in a single shot
! x and y
ipol = 1
aux(:) = CMPLX( a(ipol,:), a(ipol+1,:), kind=DP)
!
! ... bring a(ipol,r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... multiply by iG to get the gradient in G-space
!
DO n = 1, dfft%ngm
!
fp = (aux(dfft%nl(n)) + aux (dfft%nlm(n)))*0.5_dp
fm = (aux(dfft%nl(n)) - aux (dfft%nlm(n)))*0.5_dp
aux1 = CMPLX( REAL(fp), AIMAG(fm), kind=DP)
aux2 = CMPLX(AIMAG(fp), -REAL(fm), kind=DP)
gaux (dfft%nl(n)) = &
CMPLX(0.0_dp, g(ipol ,n),kind=DP) * aux1 + &
CMPLX(0.0_dp, g(ipol+1,n),kind=DP) * aux2
ENDDO
! z
ipol = 3
aux(:) = CMPLX( a(ipol,:), 0.0_dp, kind=DP)
!
! ... bring a(ipol,r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... multiply by iG to get the gradient in G-space
! ... fill both gaux(G) and gaux(-G) = gaux*(G)
!
DO n = 1, dfft%ngm
gaux(dfft%nl(n)) = gaux(dfft%nl(n)) + g(ipol,n) * &
CMPLX( -AIMAG( aux(dfft%nl(n)) ), &
REAL( aux(dfft%nl(n)) ), kind=DP)
gaux(dfft%nlm(n)) = CONJG( gaux(dfft%nl(n)) )
END DO
!
ELSE
!
DO ipol = 1, 3
!
aux = CMPLX( a(ipol,:), 0.0_dp, kind=DP)
!
! ... bring a(ipol,r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... multiply by iG to get the gradient in G-space
!
DO n = 1, dfft%ngm
gaux(dfft%nl(n)) = gaux(dfft%nl(n)) + g(ipol,n) * &
CMPLX( -AIMAG( aux(dfft%nl(n)) ), &
REAL( aux(dfft%nl(n)) ), kind=DP)
END DO
!
END DO
!
END IF
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ... add the factor 2\pi/a missing in the definition of G and sum
!
da(:) = tpiba * REAL( gaux(:) )
!
DEALLOCATE( aux, gaux )
!
RETURN
!
END SUBROUTINE fft_graddot
!--------------------------------------------------------------------
SUBROUTINE fft_qgraddot ( dfft, a, xq, g, da)
!--------------------------------------------------------------------
!
! Like fft_graddot, for complex arrays having a e^{iqr} dependency
! ... input : dfft FFT descriptor
! ... a(3,:) a complex function on the real-space FFT grid
! ... xq(3) q-vector, in 2\pi/a units
! ... g(3,:) G-vectors, in 2\pi/a units
! ... output: ga(:) \sum_i \grad_i a_i, complex, on the real-space FFT grid
!
USE kinds, ONLY : DP
USE cell_base, ONLY : tpiba
USE fft_interfaces, ONLY : fwfft, invfft
USE fft_types, ONLY : fft_type_descriptor
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
COMPLEX(DP), INTENT(IN) :: a(3,dfft%nnr)
REAL(DP), INTENT(IN) :: xq(3), g(3,dfft%ngm)
COMPLEX(DP), INTENT(OUT) :: da(dfft%nnr)
INTEGER :: n, ipol
COMPLEX(DP), allocatable :: aux (:)
ALLOCATE (aux (dfft%nnr))
da(:) = (0.0_dp, 0.0_dp)
DO ipol = 1, 3
! copy a(ipol,r) to a complex array...
DO n = 1, dfft%nnr
aux (n) = a (ipol, n)
END DO
! bring a(ipol,r) to G-space, a(G) ...
CALL fwfft ('Rho', aux, dfft)
! multiply by i(q+G) to get (\grad_ipol a)(q+G) ...
DO n = 1, dfft%ngm
da (dfft%nl(n)) = da (dfft%nl(n)) + &
CMPLX(0.0_dp, xq (ipol) + g (ipol, n),kind=DP) * aux(dfft%nl(n))
END DO
END DO
IF ( dfft%lgamma ) THEN
DO n = 1, dfft%ngm
da (dfft%nlm(n)) = CONJG( da (dfft%nl(n)) )
END DO
END IF
! bring back to R-space, (\grad_ipol a)(r) ...
CALL invfft ('Rho', da, dfft)
! ...add the factor 2\pi/a missing in the definition of q+G
da (:) = da (:) * tpiba
DEALLOCATE(aux)
RETURN
END SUBROUTINE fft_qgraddot
!--------------------------------------------------------------------
! Routines computing laplacian via FFT
!--------------------------------------------------------------------
!--------------------------------------------------------------------
SUBROUTINE external_laplacian( a, lapla )
!--------------------------------------------------------------------
!
! Interface for computing laplacian in real space, to be called by
! an external module
!
USE kinds, ONLY : DP
USE fft_base, ONLY : dfftp
USE gvect, ONLY : gg
!
IMPLICIT NONE
!
REAL( DP ), INTENT(IN) :: a( dfftp%nnr )
REAL( DP ), INTENT(OUT) :: lapla( dfftp%nnr )
! A in real space, lapl(A) in real space
CALL fft_laplacian( dfftp, a, gg, lapla )
RETURN
END SUBROUTINE external_laplacian
!--------------------------------------------------------------------
SUBROUTINE fft_laplacian( dfft, a, gg, lapla )
!--------------------------------------------------------------------
!
! ... Calculates lapla = laplacian(a)
! ... input : dfft FFT descriptor
! ... a(:) a real function on the real-space FFT grid
! ... gg(:) square modules of G-vectors, in (2\pi/a)^2 units
! ... output: lapla(:) \nabla^2 a, real, on the real-space FFT grid
!
USE kinds, ONLY : DP
USE cell_base, ONLY : tpiba2
USE fft_types, ONLY : fft_type_descriptor
USE fft_interfaces,ONLY : fwfft, invfft
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
REAL(DP), INTENT(IN) :: a(dfft%nnr), gg(dfft%ngm)
REAL(DP), INTENT(OUT) :: lapla(dfft%nnr)
!
INTEGER :: ig
COMPLEX(DP), ALLOCATABLE :: aux(:), laux(:)
!
!
ALLOCATE( aux( dfft%nnr ) )
ALLOCATE( laux( dfft%nnr ) )
!
aux = CMPLX( a(:), 0.0_dp, kind=DP)
!
! ... bring a(r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... Compute the laplacian
!
laux(:) = (0.0_dp, 0.0_dp)
!
DO ig = 1, dfft%ngm
!
laux(dfft%nl(ig)) = -gg(ig)*aux(dfft%nl(ig))
!
END DO
!
IF ( dfft%lgamma ) THEN
!
laux(dfft%nlm(:)) = CMPLX( REAL(laux(dfft%nl(:)) ), &
-AIMAG(laux(dfft%nl(:)) ), kind=DP)
!
ENDIF
!
! ... bring back to R-space, (\lapl a)(r) ...
!
CALL invfft ('Rho', laux, dfft)
!
! ... add the missing factor (2\pi/a)^2 in G
!
lapla = tpiba2 * REAL( laux )
!
DEALLOCATE( laux )
DEALLOCATE( aux )
!
RETURN
!
END SUBROUTINE fft_laplacian
!
!--------------------------------------------------------------------
! Routines computing hessian via FFT
!--------------------------------------------------------------------
!
!----------------------------------------------------------------------
SUBROUTINE fft_hessian_g2r ( dfft, a, g, ha )
!----------------------------------------------------------------------
!
! ... Calculates ha = hessian(a)
! ... input : dfft FFT descriptor
! ... a(:) a real function on the real-space FFT grid
! ... g(3,:) G-vectors, in (2\pi/a)^2 units
! ... output: ha(6,:) hessian(a), real, on the real-space FFT grid
! ... lower-packed matrix indeces 1-6 correspond to:
! ... 1 = xx, 2 = yx, 3 = yy, 4 = zx, 5 = zy, 6 = zz
!
USE kinds, ONLY : DP
USE cell_base, ONLY : tpiba
USE fft_types, ONLY : fft_type_descriptor
USE fft_interfaces,ONLY : fwfft, invfft
USE fft_helper_subroutines, ONLY: fftx_oned2threed
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
REAL(DP), INTENT(IN) :: g(3,dfft%ngm)
COMPLEX(DP), INTENT(IN) :: a(dfft%ngm)
REAL(DP), INTENT(OUT) :: ha( 6, dfft%nnr )
!
INTEGER :: ig, ir
COMPLEX(DP), ALLOCATABLE :: aux(:), haux(:,:)
!
IF ( .NOT. dfft%lgamma ) CALL errore ('fft_hessian_g2r',&
'only gamma case is implemented',1)
ALLOCATE ( aux(dfft%nnr))
ALLOCATE (haux(dfft%ngm,2))
! xx, yx
DO ig=1,dfft%ngm
haux(ig,1) = -tpiba**2*g(1,ig)**2 *a(ig)
haux(ig,2) = -tpiba**2*g(1,ig)*g(2,ig)*a(ig)
END DO
CALL fftx_oned2threed( dfft, aux, haux(:,1), haux(:,2) )
CALL invfft('Rho', aux, dfft)
DO ir=1,dfft%nnr
ha(1,ir) = DBLE(aux(ir))
ha(2,ir) =AIMAG(aux(ir))
END DO
! yy, zx
DO ig=1,dfft%ngm
haux(ig,1) = -tpiba**2*g(2,ig)**2 *a(ig)
haux(ig,2) = -tpiba**2*g(1,ig)*g(3,ig)*a(ig)
END DO
CALL fftx_oned2threed( dfft, aux, haux(:,1), haux(:,2) )
CALL invfft('Rho', aux, dfft)
DO ir=1,dfft%nnr
ha(3,ir) = DBLE(aux(ir))
ha(4,ir) =AIMAG(aux(ir))
END DO
! zy, zz
DO ig=1,dfft%ngm
haux(ig,1) = -tpiba**2*g(2,ig)*g(3,ig)*a(ig)
haux(ig,2) = -tpiba**2*g(3,ig)**2 *a(ig)
END DO
CALL fftx_oned2threed( dfft, aux, haux(:,1), haux(:,2) )
CALL invfft('Rho', aux, dfft)
DO ir=1,dfft%nnr
ha(5,ir) = DBLE(aux(ir))
ha(6,ir) =AIMAG(aux(ir))
END DO
!
DEALLOCATE(aux)
DEALLOCATE(haux)
END SUBROUTINE fft_hessian_g2r
!--------------------------------------------------------------------
SUBROUTINE fft_hessian( dfft, a, g, ga, ha )
!--------------------------------------------------------------------
!
! ... Calculates ga = \grad a and ha = hessian(a)
! ... input : dfft FFT descriptor
! ... a(:) a real function on the real-space FFT grid
! ... g(3,:) G-vectors, in (2\pi/a)^2 units
! ... output: ga(3,:) \grad a, real, on the real-space FFT grid
! ... ha(3,3,:) hessian(a), real, on the real-space FFT grid
!
USE kinds, ONLY : DP
USE cell_base, ONLY : tpiba
USE fft_types, ONLY : fft_type_descriptor
USE fft_interfaces,ONLY : fwfft, invfft
!
IMPLICIT NONE
!
TYPE(fft_type_descriptor),INTENT(IN) :: dfft
REAL(DP), INTENT(IN) :: a(dfft%nnr), g(3,dfft%ngm)
REAL(DP), INTENT(OUT) :: ga( 3, dfft%nnr )
REAL(DP), INTENT(OUT) :: ha( 3, 3, dfft%nnr )
!
INTEGER :: ipol, jpol
COMPLEX(DP), ALLOCATABLE :: aux(:), gaux(:), haux(:)
!
!
ALLOCATE( aux( dfft%nnr ) )
ALLOCATE( gaux( dfft%nnr ) )
ALLOCATE( haux( dfft%nnr ) )
!
aux = CMPLX( a(:), 0.0_dp, kind=DP)
!
! ... bring a(r) to G-space, a(G) ...
!
CALL fwfft ('Rho', aux, dfft)
!
! ... multiply by (iG) to get (\grad_ipol a)(G) ...
!
DO ipol = 1, 3
!
gaux(:) = (0.0_dp,0.0_dp)
!
gaux(dfft%nl(:)) = g(ipol,:) * CMPLX( -AIMAG( aux(dfft%nl(:)) ), &
REAL( aux(dfft%nl(:)) ), kind=DP )
!
IF ( dfft%lgamma ) THEN
!
gaux(dfft%nlm(:)) = CMPLX( REAL( gaux(dfft%nl(:)) ), &
-AIMAG( gaux(dfft%nl(:)) ), kind=DP)
!
END IF
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', gaux, dfft)
!
! ...and add the factor 2\pi/a missing in the definition of G
!
ga(ipol,:) = tpiba * REAL( gaux(:) )
!
! ... compute the second derivatives
!
DO jpol = 1, ipol
!
haux(:) = (0.0_dp,0.0_dp)
!
haux(dfft%nl(:)) = - g(ipol,:) * g(jpol,:) * &
CMPLX( REAL( aux(dfft%nl(:)) ), &
AIMAG( aux(dfft%nl(:)) ), kind=DP)
!
IF ( dfft%lgamma ) THEN
!
haux(dfft%nlm(:)) = CMPLX( REAL( haux(dfft%nl(:)) ), &
-AIMAG( haux(dfft%nl(:)) ), kind=DP)
!
END IF
!
! ... bring back to R-space, (\grad_ipol a)(r) ...
!
CALL invfft ('Rho', haux, dfft)
!
! ...and add the factor 2\pi/a missing in the definition of G
!
ha(ipol, jpol, :) = tpiba * tpiba * REAL( haux(:) )
!
ha(jpol, ipol, :) = ha(ipol, jpol, :)
!
END DO
!
END DO
!
DEALLOCATE( haux )
DEALLOCATE( gaux )
DEALLOCATE( aux )
!
RETURN
!
END SUBROUTINE fft_hessian
!--------------------------------------------------------------------
SUBROUTINE external_hessian( a, grada, hessa )
!--------------------------------------------------------------------
!
! Interface for computing hessian in real space, to be called by
! an external module
!
USE kinds, ONLY : DP
USE fft_base, ONLY : dfftp
USE gvect, ONLY : g
!
IMPLICIT NONE
!
REAL( DP ), INTENT(IN) :: a( dfftp%nnr )
REAL( DP ), INTENT(OUT) :: grada( 3, dfftp%nnr )
REAL( DP ), INTENT(OUT) :: hessa( 3, 3, dfftp%nnr )
! A in real space, grad(A) and hess(A) in real space
CALL fft_hessian( dfftp, a, g, grada, hessa )
RETURN
END SUBROUTINE external_hessian
!--------------------------------------------------------------------
|
