1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
|
!
! Copyright (C) 2001-2016 Quantum ESPRESSO group
! This file is distributed under the terms of the
! GNU General Public License. See the file `License'
! in the root directory of the present distribution,
! or http://www.gnu.org/copyleft/gpl.txt .
!
!-----------------------------------------------------------------------
SUBROUTINE partialdos (Emin, Emax, DeltaE, kresolveddos, filpdos)
!-----------------------------------------------------------------------
!
USE io_global, ONLY : stdout
USE ions_base, ONLY : ityp, atm
USE klist, ONLY: wk, nkstot, degauss, ngauss, lgauss, ltetra
USE lsda_mod, ONLY: nspin, isk, current_spin
USE wvfct, ONLY: et, nbnd
USE constants, ONLY: rytoev
USE ktetra, ONLY: tetra_type, opt_tetra_partialdos
!
USE projections
!
IMPLICIT NONE
CHARACTER (len=256) :: filpdos
REAL(DP) :: Emin, Emax, DeltaE
LOGICAL :: kresolveddos
!
CHARACTER (len=33) :: filextension
CHARACTER (len=256):: fileout
CHARACTER (len=1) :: l_label(0:3)=(/'s','p','d','f'/)
!
INTEGER :: nproj, ik, ibnd, m, &
c_tab, nwfc, ne, ie_mid, ie_delta, ie, is, nkseff, ikeff
REAL(DP) :: etev, delta, Elw, Eup, wkeff
REAL(DP), ALLOCATABLE :: dostot(:,:,:), pdos(:,:,:,:), pdostot(:,:,:), &
ldos(:,:,:)
REAL(DP), EXTERNAL :: w0gauss
!
! this can be either natomwfc or nkb, depending upon the projection
!
nproj = SIZE(proj,1)
!
! find band extrema
!
Elw = et (1, 1)
Eup = et (nbnd, 1)
DO ik = 2, nkstot
Elw = min (Elw, et (1, ik) )
Eup = max (Eup, et (nbnd, ik) )
ENDDO
IF (degauss/=0.d0) THEN
Eup = Eup + 3d0 * degauss
Elw = Elw - 3d0 * degauss
ENDIF
Emin = max (Emin/rytoev, Elw)
Emax = min (Emax/rytoev, Eup)
DeltaE = DeltaE/rytoev
ne = nint ( (Emax - Emin) / DeltaE+0.500001d0)
!
IF (kresolveddos) THEN
IF ( nspin==2 ) THEN
nkseff=nkstot/2
ELSE
nkseff=nkstot
ENDIF
ELSE
nkseff=1
ENDIF
!
ALLOCATE (pdos(0:ne,nproj,nspin,nkseff))
ALLOCATE (dostot(0:ne,nspin,nkseff), pdostot(0:ne,nspin,nkseff), ldos(0:ne,nspin,nkseff) )
pdos(:,:,:,:) = 0.d0
dostot(:,:,:) = 0.d0
pdostot(:,:,:)= 0.d0
!
current_spin = 1
ie_delta = 5 * degauss / DeltaE + 1
IF ( ltetra .AND. tetra_type == 1 .OR. tetra_type == 2 ) THEN
!
! Tetrahedron method
!
CALL opt_tetra_partialdos(nspin,kresolveddos,ne,nproj,nkseff, &
& Emin,DeltaE, proj, pdos, dostot, nspin)
!
ELSE
!
DO ik = 1,nkstot
!
IF (kresolveddos) THEN
! set equal weight to all k-points
wkeff=1.D0
!
IF (( nspin==2 ).AND.( isk(ik)==2 )) THEN
ikeff=ik-nkstot/2
ELSE
ikeff=ik
ENDIF
ELSE
! use true weights
wkeff=wk(ik)
! contributions from all k-points are summed in pdos(:,:,:,ikeff)
ikeff=1
ENDIF
!
IF ( nspin == 2 ) current_spin = isk ( ik )
DO ibnd = 1, nbnd
etev = et(ibnd,ik)
ie_mid = nint( (etev-Emin)/DeltaE )
DO ie = max(ie_mid-ie_delta, 0), min(ie_mid+ie_delta, ne)
delta = w0gauss((Emin+DeltaE*ie-etev)/degauss,ngauss) &
/ degauss / rytoev
!
! pdos(:,nwfc,ns,ik) = DOS (states/eV) for spin "ns"
! projected over atomic wfc "nwfc"
! for k-point "ik" (or summed over all kp)
!
DO nwfc = 1, nproj
pdos(ie,nwfc,current_spin,ikeff) = pdos(ie,nwfc,current_spin,ikeff) + &
wkeff * delta * proj (nwfc, ibnd, ik)
ENDDO
!
! dostot(:,ns,ik) = total DOS (states/eV) for spin "ns"
! for k-point "ik" (or summed over all kp)
!
dostot(ie,current_spin,ikeff) = dostot(ie,current_spin,ikeff) + &
wkeff * delta
ENDDO
ENDDO
ENDDO
!
END IF
!
! pdostot(:,ns,ik) = sum of all projected DOS
!
DO ik=1,nkseff
DO is=1,nspin
DO ie=0,ne
pdostot(ie,is,ik) = sum(pdos(ie,:,is,ik))
ENDDO
ENDDO
ENDDO
DO nwfc = 1, nproj
IF (nlmchi(nwfc)%m == 1) THEN
filextension='.pdos_atm#'
! 12345678901
c_tab = 11
IF (nlmchi(nwfc)%na < 10) THEN
WRITE (filextension( c_tab : c_tab ),'(i1)') nlmchi(nwfc)%na
c_tab = c_tab + 1
ELSEIF (nlmchi(nwfc)%na < 100) THEN
WRITE (filextension( c_tab : c_tab+1 ),'(i2)') nlmchi(nwfc)%na
c_tab = c_tab + 2
ELSEIF (nlmchi(nwfc)%na < 1000) THEN
WRITE (filextension( c_tab : c_tab+2 ),'(i3)') nlmchi(nwfc)%na
c_tab = c_tab + 3
ELSEIF (nlmchi(nwfc)%na < 10000) THEN
WRITE (filextension( c_tab : c_tab+3 ),'(i4)') nlmchi(nwfc)%na
c_tab = c_tab + 4
ELSE
CALL errore('partialdos',&
'file extension not supporting so many atoms', nwfc)
ENDIF
WRITE (filextension(c_tab:c_tab+4),'(a1,a)') &
'(',trim(atm(ityp(nlmchi(nwfc)%na)))
c_tab = c_tab + len_trim(atm(ityp(nlmchi(nwfc)%na))) + 1
IF (nlmchi(nwfc)%l > 3) &
CALL errore('partialdos',&
'file extension not supporting so many l', nwfc)
IF (nlmchi(nwfc)%n < 10) THEN
WRITE (filextension(c_tab:),'(")_wfc#",i1,"(",a1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l)
ELSE IF (nlmchi(nwfc)%n < 100) THEN
WRITE (filextension(c_tab:),'(")_wfc#",i2,"(",a1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l)
ELSE
CALL errore('partialdos',&
'file extension not supporting so many atomic wfc', nwfc)
END IF
fileout = trim(filpdos)//trim(filextension)
OPEN (4,file=fileout,form='formatted', status='unknown')
IF (kresolveddos) THEN
WRITE (4,'("# ik ")', advance="NO")
ELSE
WRITE (4,'("#")', advance="NO")
ENDIF
IF (nspin == 1) THEN
WRITE (4,'(" E (eV) ldos(E) ")', advance="NO")
ELSE
WRITE (4,'(" E (eV) ldosup(E) ldosdw(E)")', advance="NO")
ENDIF
DO m=1,2 * nlmchi(nwfc)%l + 1
IF (nspin == 1) THEN
WRITE(4,'(" pdos(E) ")', advance="NO")
ELSE
WRITE(4,'(" pdosup(E) ")', advance="NO")
WRITE(4,'(" pdosdw(E) ")', advance="NO")
ENDIF
ENDDO
WRITE(4,*)
!
! ldos = PDOS summed over m (m=-l:+l)
!
ldos (:,:,:) = 0.d0
DO ik=1,nkseff
DO ie= 0, ne
DO is=1, nspin
DO m=1,2 * nlmchi(nwfc)%l + 1
ldos (ie, is, ik) = ldos (ie, is, ik) + pdos(ie,nwfc+m-1,is,ik)
ENDDO
ENDDO
ENDDO
ENDDO
DO ik=1,nkseff
DO ie= 0, ne
IF (kresolveddos) THEN
WRITE (4,'(i5," ")', advance="NO") ik
ENDIF
etev = Emin + ie * DeltaE
WRITE (4,'(f8.3,2e11.3,14e11.3)') etev*rytoev, &
(ldos(ie,is,ik), is=1,nspin), &
((pdos(ie,nwfc+m-1,is,ik), is=1,nspin), &
m=1,2*nlmchi(nwfc)%l+1)
ENDDO
IF (kresolveddos) WRITE (4,*)
ENDDO
CLOSE (4)
ENDIF
ENDDO
fileout = trim(filpdos)//".pdos_tot"
OPEN (4,file=fileout,form='formatted', status='unknown')
IF (kresolveddos) THEN
WRITE (4,'("# ik ")', advance="NO")
ELSE
WRITE (4,'("#")', advance="NO")
ENDIF
IF (nspin == 1) THEN
WRITE (4,'(" E (eV) dos(E) pdos(E)")')
ELSE
WRITE (4,'(" E (eV) dosup(E) dosdw(E) pdosup(E) pdosdw(E)")')
ENDIF
DO ik=1,nkseff
DO ie= 0, ne
IF (kresolveddos) THEN
WRITE (4,'(i5," ")', advance="NO") ik
ENDIF
etev = Emin + ie * DeltaE
WRITE (4,'(f8.3,4e11.3)') etev*rytoev, (dostot(ie,is,ik), is=1,nspin), &
(pdostot(ie,is,ik), is=1,nspin)
ENDDO
IF (kresolveddos) WRITE (4,*)
ENDDO
CLOSE (4)
DEALLOCATE (ldos, dostot, pdostot)
DEALLOCATE (pdos)
!
DEALLOCATE (nlmchi)
DEALLOCATE (proj)
!
RETURN
END SUBROUTINE partialdos
!
!-----------------------------------------------------------------------
SUBROUTINE partialdos_nc (Emin, Emax, DeltaE, kresolveddos, filpdos)
!-----------------------------------------------------------------------
!
USE io_global, ONLY : stdout
USE basis, ONLY : natomwfc
USE ions_base, ONLY : ityp, atm
USE klist, ONLY: wk, nkstot, degauss, ngauss, lgauss, ltetra
USE lsda_mod, ONLY: nspin
USE wvfct, ONLY: et, nbnd
USE constants, ONLY: rytoev
USE ktetra, ONLY: opt_tetra_partialdos
!
USE spin_orb, ONLY: lspinorb
USE projections
!
IMPLICIT NONE
CHARACTER (len=256) :: filpdos
REAL(DP) :: Emin, Emax, DeltaE
LOGICAL :: kresolveddos
!
CHARACTER (len=33) :: filextension
CHARACTER (len=256):: fileout
CHARACTER (len=1) :: l_label(0:3)=(/'s','p','d','f'/)
!
INTEGER :: ik, ibnd, ind, m, &
c_tab, nwfc, ne, ie_mid, ie_delta, ie, is, nkseff, ikeff, nspin0
REAL(DP) :: etev, delta, Elw, Eup, wkeff, fact(2)
REAL(DP), ALLOCATABLE :: dostot(:,:), pdos(:,:,:,:), pdostot(:,:,:), &
ldos(:,:,:)
REAL(DP), EXTERNAL :: w0gauss, spinor
!
!
! find band extrema
!
Elw = et (1, 1)
Eup = et (nbnd, 1)
DO ik = 2, nkstot
Elw = min (Elw, et (1, ik) )
Eup = max (Eup, et (nbnd, ik) )
ENDDO
IF (degauss/=0.d0) THEN
Eup = Eup + 3d0 * degauss
Elw = Elw - 3d0 * degauss
ENDIF
Emin = max (Emin/rytoev, Elw)
Emax = min (Emax/rytoev, Eup)
DeltaE = DeltaE/rytoev
ne = nint ( (Emax - Emin) / DeltaE+0.500001d0)
!
IF (lspinorb) THEN
nspin0 = 1
ELSE
nspin0 = 2
ENDIF
!
IF (kresolveddos) THEN
nkseff=nkstot
ELSE
nkseff=1
ENDIF
!
ALLOCATE (pdos(0:ne,natomwfc,nspin0,nkseff))
ALLOCATE (dostot(0:ne,nkseff), pdostot(0:ne,nspin0,nkseff), ldos(0:ne,nspin0,nkseff) )
pdos(:,:,:,:) = 0.d0
dostot(:,:) = 0.d0
pdostot(:,:,:)= 0.d0
ie_delta = 5 * degauss / DeltaE + 1
IF(ltetra) THEN
!
CALL opt_tetra_partialdos(nspin0,kresolveddos,ne,natomwfc,nkseff, &
& Emin,DeltaE, proj, pdos, dostot, 1)
!
IF(.NOT. lspinorb) THEN
DO nwfc = 1, natomwfc
IF ( nlmchi(nwfc)%ind > (2 * nlmchi(nwfc)%l+1)) THEN
pdos(0:ne,nwfc,2,1:nkseff) = pdos(0:ne,nwfc,1,1:nkseff)
pdos(0:ne,nwfc,1,1:nkseff) = 0.0_dp
ENDIF
ENDDO
END IF
!
ELSE
DO ik = 1,nkstot
!
IF (kresolveddos) THEN
! set equal weight to all k-points
wkeff=1.D0
ikeff=ik
ELSE
wkeff=wk(ik)
! contributions from all k-points are summed in pdos(:,:,:,ikeff)
ikeff=1
ENDIF
!
DO ibnd = 1, nbnd
etev = et(ibnd,ik)
ie_mid = nint( (etev-Emin)/DeltaE )
DO ie = max(ie_mid-ie_delta, 0), min(ie_mid+ie_delta, ne)
delta = w0gauss((Emin+DeltaE*ie-etev)/degauss,ngauss) &
/ degauss / rytoev
!
! pdos(:,nwfc,ns,ik) = DOS (states/eV) for spin "ns"
! projected over atomic wfc "nwfc"
! for k-point "ik" (or summed over all kp)
!
!
! dostot(:,ik) = total DOS (states/eV)
! for k-point "ik" (or summed over all kp)
!
IF (lspinorb) THEN
DO nwfc = 1, natomwfc
pdos(ie,nwfc,1,ikeff) = pdos(ie,nwfc,1,ikeff) + &
wkeff * delta * proj (nwfc, ibnd, ik)
ENDDO
dostot(ie,ikeff) = dostot(ie,ikeff) + wkeff * delta
ELSE
DO nwfc = 1, natomwfc
IF ( nlmchi(nwfc)%ind<=(2* nlmchi(nwfc)%l+1)) THEN
pdos(ie,nwfc,1,ikeff) = pdos(ie,nwfc,1,ikeff) + &
wkeff * delta * proj (nwfc, ibnd, ik)
pdos(ie,nwfc,2,ikeff) = 0.d0
ELSE
pdos(ie,nwfc,1,ikeff) = 0.d0
pdos(ie,nwfc,2,ikeff) = pdos(ie,nwfc,2,ikeff) + &
wkeff * delta * proj (nwfc, ibnd, ik)
ENDIF
ENDDO
dostot(ie,ikeff) = dostot(ie,ikeff) + wkeff * delta
ENDIF
ENDDO
ENDDO
ENDDO
!
END IF
!
! pdostot(:,ns,ik) = sum of all projected DOS
!
DO ik=1,nkseff
DO is=1,nspin0
DO ie=0,ne
pdostot(ie,is,ik) = sum(pdos(ie,:,is,ik))
ENDDO
ENDDO
ENDDO
DO nwfc = 1, natomwfc
IF (nlmchi(nwfc)%ind == 1) THEN
filextension='.pdos_atm#'
! 12345678901
c_tab = 11
IF (nlmchi(nwfc)%na < 10) THEN
WRITE (filextension( c_tab : c_tab ),'(i1)') nlmchi(nwfc)%na
c_tab = c_tab + 1
ELSEIF (nlmchi(nwfc)%na < 100) THEN
WRITE (filextension( c_tab : c_tab+1 ),'(i2)') nlmchi(nwfc)%na
c_tab = c_tab + 2
ELSEIF (nlmchi(nwfc)%na < 1000) THEN
WRITE (filextension( c_tab : c_tab+2 ),'(i3)') nlmchi(nwfc)%na
c_tab = c_tab + 3
ELSEIF (nlmchi(nwfc)%na < 10000) THEN
WRITE (filextension( c_tab : c_tab+3 ),'(i4)') nlmchi(nwfc)%na
c_tab = c_tab + 4
ELSE
CALL errore('partialdos_nc',&
'file extension not supporting so many atoms', nwfc)
ENDIF
WRITE (filextension(c_tab:c_tab+4),'(a1,a)') &
'(',trim(atm(ityp(nlmchi(nwfc)%na)))
c_tab = c_tab + len_trim(atm(ityp(nlmchi(nwfc)%na))) + 1
IF (nlmchi(nwfc)%l > 3) &
CALL errore('partialdos_nc',&
'file extension not supporting so many l', nwfc)
IF (nlmchi(nwfc)%n < 10) THEN
IF (lspinorb) THEN
WRITE (filextension(c_tab:),'(")_wfc#",i1,"(",a1,"_j",f3.1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l),nlmchi(nwfc)%jj
ELSE
WRITE (filextension(c_tab:),'(")_wfc#",i1,"(",a1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l)
ENDIF
ELSE IF (nlmchi(nwfc)%n < 100) THEN
IF (lspinorb) THEN
WRITE (filextension(c_tab:),'(")_wfc#",i2,"(",a1,"_j",f3.1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l),nlmchi(nwfc)%jj
ELSE
WRITE (filextension(c_tab:),'(")_wfc#",i2,"(",a1,")")') &
nlmchi(nwfc)%n, l_label(nlmchi(nwfc)%l)
ENDIF
ELSE
CALL errore('partialdos_nc',&
'file extension not supporting so many atomic wfc', nwfc)
ENDIF
fileout = trim(filpdos)//trim(filextension)
OPEN (4,file=fileout,form='formatted', status='unknown')
IF (kresolveddos) THEN
WRITE (4,'("# ik ")', advance="NO")
ELSE
WRITE (4,'("#")', advance="NO")
ENDIF
IF (nspin0 == 1) THEN
WRITE (4,'(" E (eV) ldos(E) ")', advance="NO")
ELSE
WRITE (4,'(" E (eV) ldosup(E) ldosdw(E)")', advance="NO")
ENDIF
IF (lspinorb) THEN
ind = 0
DO m = -nlmchi(nwfc)%l-1, nlmchi(nwfc)%l
fact(1) = spinor(nlmchi(nwfc)%l,nlmchi(nwfc)%jj,m,1)
fact(2) = spinor(nlmchi(nwfc)%l,nlmchi(nwfc)%jj,m,2)
IF (abs(fact(1))>1.d-8.or.abs(fact(2))>1.d-8) THEN
ind = ind + 1
WRITE(4,'("pdos(E)_",i1," ")', advance="NO") ind
ENDIF
ENDDO
ELSE
DO ind=1,2 * nlmchi(nwfc)%l + 1
WRITE(4,'(" pdosup(E) ")', advance="NO")
WRITE(4,'(" pdosdw(E) ")', advance="NO")
ENDDO
ENDIF
WRITE(4,*)
!
! ldos = PDOS summed over m (m=-l:+l)
!
ldos (:,:,:) = 0.d0
IF (lspinorb) THEN
DO ik=1,nkseff
DO ie= 0, ne
IF (abs(nlmchi(nwfc)%jj-nlmchi(nwfc)%l-0.5d0)<1.d-8) THEN
DO ind = 1, 2 * nlmchi(nwfc)%l + 2
ldos (ie, 1, ik) = ldos (ie, 1, ik) + pdos(ie,nwfc+ind-1,1,ik)
ENDDO
ELSEIF (abs(nlmchi(nwfc)%jj-nlmchi(nwfc)%l+0.5d0)<1.d-8) THEN
DO ind = 1, 2 * nlmchi(nwfc)%l
ldos (ie, 1, ik) = ldos (ie, 1, ik) + pdos(ie,nwfc+ind-1,1,ik)
ENDDO
ENDIF
ENDDO
ENDDO
DO ik=1,nkseff
DO ie= 0, ne
IF (kresolveddos) THEN
WRITE (4,'(i5," ")', advance="NO") ik
ENDIF
etev = Emin + ie * DeltaE
IF (abs(nlmchi(nwfc)%jj-nlmchi(nwfc)%l-0.5d0)<1.d-8) THEN
WRITE (4,'(f8.3,2e11.3,14e11.3)') etev*rytoev, ldos(ie,1,ik), &
(pdos(ie,nwfc+ind-1,1,ik), ind=1,2*nlmchi(nwfc)%l+2)
ELSEIF (abs(nlmchi(nwfc)%jj-nlmchi(nwfc)%l+0.5d0)<1.d-8) THEN
WRITE (4,'(f8.3,2e11.3,14e11.3)') etev*rytoev, ldos(ie,1,ik), &
(pdos(ie,nwfc+ind-1,1,ik), ind=1,2*nlmchi(nwfc)%l)
ENDIF
ENDDO
IF (kresolveddos) WRITE (4,*)
ENDDO
ELSE
DO ik=1,nkseff
DO ie= 0, ne
DO is=1, nspin0
DO ind=1,4 * nlmchi(nwfc)%l + 2
ldos (ie, is, ik) = ldos (ie, is, ik) + pdos(ie,nwfc+ind-1,is, ik)
ENDDO
ENDDO
ENDDO
ENDDO
DO ik=1,nkseff
DO ie= 0, ne
IF (kresolveddos) THEN
WRITE (4,'(i5," ")', advance="NO") ik
ENDIF
etev = Emin + ie * DeltaE
WRITE (4,'(f8.3,2e11.3,14e11.3)') etev*rytoev, &
(ldos(ie,is,ik), is=1,nspin0), &
((pdos(ie,nwfc+ind-1+(is-1)*(2*nlmchi(nwfc)%l+1),is,ik), is=1,nspin0), &
ind=1,2*nlmchi(nwfc)%l+1)
ENDDO
IF (kresolveddos) WRITE (4,*)
ENDDO
ENDIF
CLOSE (4)
ENDIF
ENDDO
fileout = trim(filpdos)//".pdos_tot"
OPEN (4,file=fileout,form='formatted', status='unknown')
IF (kresolveddos) THEN
WRITE (4,'("# ik ")', advance="NO")
ELSE
WRITE (4,'("#")', advance="NO")
ENDIF
IF (nspin0 == 1) THEN
WRITE (4,'(" E (eV) dos(E) pdos(E)")')
ELSE
WRITE (4,'(" E (eV) dos(E) pdosup(E) pdosdw(E)")')
ENDIF
DO ik=1,nkseff
DO ie= 0, ne
IF (kresolveddos) THEN
WRITE (4,'(i5," ")', advance="NO") ik
ENDIF
etev = Emin + ie * DeltaE
WRITE (4,'(f8.3,4e11.3)') etev*rytoev, dostot(ie,ik), &
(pdostot(ie,is,ik), is=1,nspin0)
ENDDO
IF (kresolveddos) WRITE (4,*)
ENDDO
CLOSE (4)
DEALLOCATE (ldos, dostot, pdostot)
DEALLOCATE (pdos)
!
DEALLOCATE (nlmchi)
DEALLOCATE (proj)
!
RETURN
END SUBROUTINE partialdos_nc
|
