1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# SPDX-FileCopyrightText: 2015 Alex Merry <alex.merry@kde.org>
#
# SPDX-License-Identifier: BSD-3-Clause
#[=======================================================================[.rst:
FindQCollectionGenerator
------------------------
Try to find the Qt help collection generator.
This will define the following variables:
``QCollectionGenerator_FOUND``
True if (the requested version of) Sphinx is available
``QCollectionGenerator_VERSION``
The version of the Qt help collection generator. Note that this not the
same as the version of Qt it is provided by.
``QCollectionGenerator_QT_VERSION``
The version of Qt that the Qt help collection generator is from.
``QCollectionGenerator_EXECUTABLE``
The path to the Qt help collection generator executable.
If ``QCollectionGenerator_FOUND`` is TRUE, it will also define the following
imported target:
``QCollectionGenerator::Generator``
The Qt help collection generator.
In general we recommend using the imported target, as it is easier to use.
Since 5.17.0.
#]=======================================================================]
find_program(QCollectionGenerator_EXECUTABLE
NAMES
qcollectiongenerator
qcollectiongenerator-qt4
qcollectiongenerator-qt5
DOC "Qt help collection generator"
)
if (QCollectionGenerator_EXECUTABLE)
if(NOT TARGET QCollectionGenerator::Generator)
add_executable(QCollectionGenerator::Generator IMPORTED)
set_target_properties(QCollectionGenerator::Generator PROPERTIES
IMPORTED_LOCATION "${QCollectionGenerator_EXECUTABLE}"
)
endif()
execute_process(
COMMAND "${QCollectionGenerator_EXECUTABLE}" -v
OUTPUT_VARIABLE _QCollectionGenerator_version_raw
ERROR_VARIABLE _QCollectionGenerator_version_raw
)
if (_QCollectionGenerator_version_raw MATCHES "^Qt Collection Generator version ([0-9]+(\\.[0-9]+)*) \\(Qt ([0-9]+(\\.[0-9]+)*)\\)")
set(QCollectionGenerator_VERSION "${CMAKE_MATCH_1}")
set(QCollectionGenerator_QT_VERSION "${CMAKE_MATCH_3}")
endif()
unset(_QCollectionGenerator_version_raw)
endif()
include(FindPackageHandleStandardArgs)
find_package_handle_standard_args(QCollectionGenerator
FOUND_VAR
QCollectionGenerator_FOUND
REQUIRED_VARS
QCollectionGenerator_EXECUTABLE
VERSION_VAR
QCollectionGenerator_VERSION
)
mark_as_advanced(QCollectionGenerator_EXECUTABLE)
|
