AC_INIT(src/applet.c)

AC_PREREQ(2.53)

AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(fast-user-switch-applet, 2.24.0)

AM_MAINTAINER_MODE


##############################
# Standard Junk
##############################

IT_PROG_INTLTOOL([0.35.0])
AC_ISC_POSIX
AC_PROG_CC
AC_STDC_HEADERS
AC_PROG_LIBTOOL

AC_SUBST(VERSION)
AC_CONFIG_MACRO_DIR([m4])


##############################
# Custom Junk
##############################

AC_DEFUN([AC_DEFINE_PATH], [
  test "x$prefix" = xNONE && prefix="$ac_default_prefix"
  test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  ac_define_path=`eval echo [$]$2`
  ac_define_path=`eval echo [$]ac_define_path`
  $1="$ac_define_path"
  AC_SUBST($1)
  ifelse($3, ,
    AC_DEFINE_UNQUOTED($1, "$ac_define_path"),
    AC_DEFINE_UNQUOTED($1, "$ac_define_path", $3))
])


##############################
# Dependencies
##############################

GTK_REQUIRED_VERSION=2.8.0
PANEL_REQUIRED_VERSION=2.0.0
GLADE_REQUIRED_VERSION=2.0.0
GLIB_REQUIRED_VERSION=2.15.3

PKG_CHECK_MODULES(APPLET, gtk+-2.0 >= $GTK_REQUIRED_VERSION
	     libpanelapplet-2.0 >= $PANEL_REQUIRED_VERSION
	     libgnomeui-2.0 >= $PANEL_REQUIRED_VERSION
	     libglade-2.0 >= $GLADE_REQUIRED_VERSION
	     gio-2.0 >= $GLIB_REQUIRED_VERSION)
AC_SUBST(APPLET_CFLAGS)
AC_SUBST(APPLET_LIBS)

AC_CHECK_FUNCS([setresuid setenv unsetenv clearenv])

AC_PATH_PROG(GLIB_MKENUMS, glib-mkenums)
AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal)
AC_PATH_PROG(GCONFTOOL, gconftool-2)
dnl Specify the gconf configuration source,
dnl default to xml::$(sysconfdir)/gconf/gconf.xml.defaults

AM_GCONF_SOURCE_2

#############################
# X, Xau, Xmu
#############################
#
# If Pango included the shared library dependencies from X11 in
# the pkg-config output, then we use that (to avoid duplicates).
# but if they were omitted to avoid binary compatibility problems
# then we need to repeat the checks.
#
if $PKG_CONFIG --exists pangoxft ; then
  PANGO_PACKAGES="pangox pangoxft"
else
  PANGO_PACKAGES="pangox"
fi

x_libs="`$PKG_CONFIG --libs $PANGO_PACKAGES`"
case x_libs in
  *-lX11*) pango_omitted_x_deps=no ;;
  *)       pango_omitted_x_deps=yes ;;
esac

if test $pango_omitted_x_deps = yes ; then
  AC_PATH_XTRA

  if test x$no_x = xyes ; then
    AC_MSG_ERROR([X development libraries not found])
  else
    X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
  fi
fi

fusa_save_LDFLAGS=$LDFLAGS
LDFLAGS="$LDFLAGS $X_LIBS"
AC_CHECK_LIB(Xau, XauFileName,
	     X_LIBS="$X_LIBS -lXau",
	     [AC_MSG_ERROR([Xau development libraries not found])])
AC_CHECK_LIB(Xmu, XmuClientWindow,
	     X_LIBS="$X_LIBS -lXmu",
	     [AC_MSG_ERROR([Xmu development libraries not found])])
LDFLAGS=$fusa_save_LDFLAGS


##############################
# Users & Groups Config
##############################

USERS_ADMIN=

AC_ARG_WITH([users_admin],
	    AC_HELP_STRING([--with-users-admin=program],
			   [The command line to run a users and groups configuration tool]),
	    [users_admin_cmd="$withval"])

if test "x$users_admin_cmd" = "x"; then
	AC_PATH_PROG(users_admin, users-admin)
	if test "x$users_admin" = "x"; then
		users_admin_cmd="disabled"
	else
		users_admin_cmd="$users_admin"
	fi
else
	if test "x$users_admin_cmd" = "xno"; then
		AC_MSG_RESULT([disabling users and groups admin command])
		users_admin=
		users_admin_cmd="disabled"
	else
		AC_MSG_RESULT([using "$users_admin_cmd" as the users and groups admin command])
		users_admin="$users_admin_cmd"
	fi
fi

if test "x$users_admin" != "x"; then
	AC_DEFINE_UNQUOTED(USERS_ADMIN, "$users_admin",
			   [The command line to a users and groups configuration tool])
fi


##############################
# GDM Setup App
##############################

GDM_SETUP=

AC_ARG_WITH([gdm_setup],
	    AC_HELP_STRING([--with-gdm-setup=program],
			   [The command line to the login screen setup tool]),
	    [gdm_setup_cmd="$withval"])

if test "x$gdm_setup_cmd" = "x"; then
	AC_PATH_PROG(gdm_setup, gdmsetup)
	if test "x$gdm_setup" = "x"; then
		gdm_setup_cmd="disabled"
	else
		gdm_setup_cmd="$gdm_setup"
	fi
else
	if test "x$gdm_setup_cmd" = "xno"; then
		AC_MSG_RESULT([disabling login screen setup command])
		gdm_setup=
		gdm_setup_cmd="disabled"
	else
		AC_MSG_RESULT([using "$gdm_setup_cmd" as the login screen setup command])
		gdm_setup="$gdm_setup_cmd"
	fi
fi

if test "x$gdm_setup" != "x"; then
	AC_DEFINE_UNQUOTED(GDM_SETUP, "$gdm_setup",
			   [The command line to the login screen setup tool])
fi


##############################
# GDM Config File
##############################

GDMCONFIGFILE=

AC_ARG_WITH([gdm_config],
	    AC_HELP_STRING([--with-gdm-config=file],
			   [The location of the GDM configuration file]),
	    [gdmconfigfile="$withval"])

if test "x$gdmconfigfile" = "x" -o "x$gdmconfigfile" = "xno"; then
	AC_MSG_CHECKING([for GDM configuration file])

	if test -f "/etc/gdm/gdm.conf"; then
		gdmconfigfile="/etc/gdm/gdm.conf"
	elif test -f "/etc/X11/gdm/gdm.conf"; then
		gdmconfigfile="/etc/X11/gdm/gdm.conf"
	elif test -f "/etc/gdm/custom.conf"; then
		gdmconfigfile="/etc/gdm/custom.conf"
	elif test -f "/etc/X11/gdm/custom.conf"; then
		gdmconfigfile="/etc/X11/gdm/custom.conf"
	elif test -f "/etc/gdm/gdm.conf-custom"; then
		gdmconfigfile="/etc/gdm/gdm.conf-custom"
	elif test -f "/etc/X11/gdm/gdm.conf-custom"; then
		gdmconfigfile="/etc/X11/gdm/gdm.conf-custom"
	else
		AC_MSG_ERROR([The GDM config file could not be found, please specify it manually])
	fi

	AC_MSG_RESULT([$gdmconfigfile])
else
	AC_MSG_RESULT([using "$gdmconfigfile" as the gdm.conf location])
fi

AC_DEFINE_PATH(GDMCONFIGFILE, "$gdmconfigfile", [The location of the GDM configuration file])


##############################
# Compile Flags
##############################

GNOME_COMPILE_WARNINGS(maximum)

AC_ARG_ENABLE(more-warnings,
[  --enable-more-warnings  Maximum compiler warnings],
set_more_warnings="$enableval",[set_more_warnings=yes])

if test "$GCC" = "yes" -a "x$set_more_warnings" = "xyes"; then
	for option in -Wcast-align -Wchar-subscripts -Wsign-compare -Wno-strict-aliasing; do
		fusa_save_CFLAGS="$CFLAGS"
		CFLAGS="$WARN_CFLAGS $option $CFLAGS"
		AC_MSG_CHECKING([whether gcc understands $option])
		AC_TRY_COMPILE([], [],
			has_option=yes,
			has_option=no,)
		CFLAGS="$fusa_save_CFLAGS"
		if test $has_option = yes; then
		  WARN_CFLAGS="$WARN_CFLAGS $option"
		fi
		AC_MSG_RESULT($has_option)
		unset has_option
		unset fusa_save_CFLAGS
	done
	unset option
fi

AC_SUBST(WARN_CFLAGS)


##############################
# I18n
##############################

GETTEXT_PACKAGE=fast-user-switch-applet
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Name of default gettext domain])
AC_DEFINE_PATH(GNOMELOCALEDIR, "${datadir}/locale", [locale directory])

AM_GLIB_GNU_GETTEXT


##############################
# Documentation
##############################

GNOME_DOC_INIT


##############################
# ./configure Flags messings
##############################

cflags_set=${CFLAGS+set}
# find the actual value for $prefix that we'll end up with
REAL_PREFIX=
if test "x$prefix" = "xNONE"; then
  REAL_PREFIX=$ac_default_prefix
else
  REAL_PREFIX=$prefix
fi

# Have to go $sysconfdir->$prefix/etc->/usr/local/etc   
# if you actually know how to code shell then fix this :-)
SYSCONFDIR_TMP="$sysconfdir"
old_prefix=$prefix
prefix=$REAL_PREFIX
EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
prefix=$old_prefix
AC_SUBST(EXPANDED_SYSCONFDIR)

dnl Save flags to aclocal
ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"

AC_DEFINE_PATH(PREFIX, "${prefix}", [prefix directory])
AC_DEFINE_PATH(SYSCONFDIR, "${sysconfdir}", [system configuration dir])
AC_DEFINE_PATH(LIBDIR, "${libdir}", [system configuration dir])

##############################
# Flags
##############################

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)


##############################
# Files
##############################

AC_OUTPUT([
Makefile
data/Makefile
help/Makefile
src/Makefile
po/Makefile.in
])


##############################
# Results
##############################

AC_MSG_NOTICE([

Fast User Switch Applet Configuration:

	Prefix:		 $prefix

	GDM Config File: $gdmconfigfile
	GDM Setup:	 $gdm_setup_cmd
	Users Admin:	 $users_admin_cmd
])