1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
declare name "lowcut";
declare version "1.0";
declare author "Grame";
declare license "BSD";
declare copyright "(c)GRAME 2006";
//------------------------------------------------------------------
// DAFX, Digital Audio Effects (Wiley ed.)
// chapter 2 : filters
// section 2.3 : Equalizers
// page 53 : second order shelving filter design
//------------------------------------------------------------------
import("music.lib");
//------------------- low-frequency shelving cut (table 2.3) --------------------
V0(g) = pow(10,g/-20.0);
K(fc) = tan(PI*fc/SR);
square(x) = x*x;
denom(fc,g) = 1 + sqrt(2*V0(g))*K(fc) + V0(g)*square(K(fc));
lfcut(fc, g) = TF2( (1 + sqrt(2)*K(fc) + square(K(fc))) / denom(fc,g),
2 * (square(K(fc)) - 1) / denom(fc,g),
(1 - sqrt(2)*K(fc) + square(K(fc))) / denom(fc,g),
2 * (V0(g)*square(K(fc)) - 1) / denom(fc,g),
(1 - sqrt(2*V0(g))*K(fc) + V0(g)*square(K(fc))) / denom(fc,g)
);
//------------------------------ User Interface -----------------------------------
freq = hslider("freq [unit:Hz][style:knob]", 100, 20, 5000, 1);
att = hslider("attenuation [unit:dB][style:knob]", 0, -96, 10, 0.1);
//----------------------------------- Process -------------------------------------
process = vgroup("low-freq shelving cut", lfcut(freq,att));
|
