1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
# Feedback daemon
if get_option('daemon')
config_h = configuration_data()
config_h.set_quoted('PACKAGE_VERSION', meson.project_version())
config_h.set_quoted('PACKAGE_NAME', meson.project_name())
config_h.set('FBD_USE_MEDIA_ROLES', get_option('media-roles'))
configure_file(output: 'fbd-config.h', configuration: config_h)
fbd_enum_headers = files('fbd-event.h', 'fbd-feedback-led.h', 'fbd-feedback-vibra.h')
fbd_enum_sources = gnome.mkenums_simple('fbd-enums', sources: fbd_enum_headers)
sources = [
generated_dbus_sources,
fbd_enum_sources,
'fbd-error.c',
'fbd-dev-vibra.c',
'fbd-dev-sound.c',
'fbd-dev-led.c',
'fbd-dev-led-flash.c',
'fbd-dev-led-multicolor.c',
'fbd-dev-led-qcom.c',
'fbd-dev-led-qcom-multicolor.c',
'fbd-dev-leds.c',
'fbd-event.c',
'fbd-feedback-base.c',
'fbd-feedback-dummy.c',
'fbd-feedback-led.c',
'fbd-feedback-manager.c',
'fbd-feedback-profile.c',
'fbd-feedback-sound.c',
'fbd-feedback-theme.c',
'fbd-feedback-vibra.c',
'fbd-feedback-vibra-pattern.c',
'fbd-feedback-vibra-periodic.c',
'fbd-feedback-vibra-rumble.c',
'fbd-haptic-manager.c',
'fbd-theme-expander.c',
'fbd-udev.c',
]
fbd_deps = [
gio,
gio_unix,
glib,
gmobile,
gobject,
gsound,
gudev,
json_glib,
cc.find_library('m', required: false),
]
fbd_inc = [include_directories('.'), libfeedback_inc, dbus_inc]
fbd_lib = static_library(
'fbd',
sources,
include_directories: fbd_inc,
dependencies: fbd_deps,
c_args: '-DGMOBILE_USE_UNSTABLE_API',
install: false,
)
fbd_dep = declare_dependency(
sources: [generated_dbus_sources, fbd_enum_sources],
include_directories: fbd_inc,
link_with: fbd_lib,
dependencies: fbd_deps,
)
fbd_exe = executable(
'feedbackd',
sources: ['fbd.c', generated_dbus_sources[1]],
include_directories: fbd_inc,
dependencies: fbd_dep,
install: true,
install_dir: libexecdir,
)
executable(
'fbd-ledctrl',
sources: ['fbd-ledctrl.c'],
include_directories: fbd_inc,
dependencies: [glib],
install: true,
install_dir: libexecdir,
)
executable(
'fbd-alert-slider',
sources: ['fbd-alert-slider.c'],
include_directories: fbd_inc,
dependencies: [glib, gio, gio_unix, gudev, libfeedback_dep],
install: true,
install_dir: libexecdir,
)
executable(
'fbd-theme-validate',
sources: ['fbd-theme-validate.c'],
include_directories: fbd_inc,
dependencies: fbd_dep,
install: true,
install_dir: bindir,
)
endif
|
