File: getpagesize.m4

package info (click to toggle)
ffcall 2.1-2
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 5,808 kB
  • sloc: asm: 43,409; ansic: 23,224; sh: 5,383; makefile: 1,517; cpp: 2
file content (47 lines) | stat: -rw-r--r-- 1,575 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
dnl -*- Autoconf -*-
dnl Copyright (C) 1993-2017 Free Software Foundation, Inc.
dnl This file is free software, distributed under the terms of the GNU
dnl General Public License as published by the Free Software Foundation;
dnl either version 2 of the License, or (at your option) any later version.
dnl As a special exception to the GNU General Public License, this file
dnl may be distributed as part of a program that contains a configuration
dnl script generated by Autoconf, under the same distribution terms as
dnl the rest of that program.

dnl From Bruno Haible, Marcus Daniels, Sam Steingold.

AC_PREREQ([2.57])

AC_DEFUN([CL_GETPAGESIZE],
[
  CL_LINK_CHECK([getpagesize], [cl_cv_func_getpagesize],
    [#ifdef HAVE_UNISTD_H
      #include <sys/types.h>
      #include <unistd.h>
     #endif
    ],
    [getpagesize();],
    [
      AC_DEFINE([HAVE_GETPAGESIZE], [], [have getpagesize()])
      have_getpagesize=1
    ])
  if test -n "$have_getpagesize"; then
    CL_PROTO([getpagesize],
      [CL_PROTO_RET(
         [#include <stdlib.h>
          #ifdef HAVE_UNISTD_H
           #include <unistd.h>
          #endif
         ],
         [int getpagesize();],
         [cl_cv_proto_getpagesize_ret], [int], [size_t])
      ],
      [extern $cl_cv_proto_getpagesize_ret getpagesize (void);])
    AC_DEFINE_UNQUOTED([RETGETPAGESIZETYPE], [$cl_cv_proto_getpagesize_ret],
      [return type of getpagesize()])
  else
    dnl Otherwise we use PAGESIZE defined in <sys/param.h>.
    dnl But mingw32 doesn't have <sys/param.h>.
    AC_CHECK_HEADERS([sys/param.h])
  fi
])