File: ln.m4

package info (click to toggle)
ffcall 2.1-2
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 5,808 kB
  • sloc: asm: 43,409; ansic: 23,224; sh: 5,383; makefile: 1,517; cpp: 2
file content (51 lines) | stat: -rw-r--r-- 1,558 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
dnl -*- Autoconf -*-
dnl Copyright (C) 1993-2017 Free Software Foundation, Inc.
dnl This file is free software, distributed under the terms of the GNU
dnl General Public License as published by the Free Software Foundation;
dnl either version 2 of the License, or (at your option) any later version.
dnl As a special exception to the GNU General Public License, this file
dnl may be distributed as part of a program that contains a configuration
dnl script generated by Autoconf, under the same distribution terms as
dnl the rest of that program.

dnl From Bruno Haible, Marcus Daniels, Sam Steingold.

AC_PREREQ([2.13])

AC_DEFUN([CL_PROG_LN],
[
  AC_CACHE_CHECK([how to make hard links], [cl_cv_prog_LN],
    [rm -f conftestdata conftestfile
     echo data > conftestfile
     if ln conftestfile conftestdata 2>/dev/null; then
       cl_cv_prog_LN=ln
     else
       cl_cv_prog_LN="cp -p"
     fi
     rm -f conftestdata conftestfile
    ])
  LN="$cl_cv_prog_LN"
  AC_SUBST([LN])
])

AC_DEFUN([CL_PROG_LN_S],
[
  AC_REQUIRE([CL_PROG_LN])
  dnl Make a symlink if possible; otherwise try a hard link. On filesystems
  dnl which support neither symlink nor hard link, use a plain copy.
  AC_CACHE_CHECK([whether ln -s works], [cl_cv_prog_LN_S_works],
    [rm -f conftestdata
     if ln -s X conftestdata 2>/dev/null; then
       cl_cv_prog_LN_S_works=yes
     else
       cl_cv_prog_LN_S_works=no
     fi
     rm -f conftestdata
    ])
  if test $cl_cv_prog_LN_S_works = yes; then
    LN_S="ln -s"
  else
    LN_S="$cl_cv_prog_LN"
  fi
  AC_SUBST([LN_S])
])