File: meson.build

package info (click to toggle)
five-or-more 1:3.30.0-2
  • links: PTS, VCS
  • area: main
  • in suites: buster, sid
  • size: 4,072 kB
  • sloc: ansic: 2,241; xml: 56; python: 10; sh: 7; makefile: 6
file content (47 lines) | stat: -rw-r--r-- 1,358 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
project('five-or-more', ['c'],
	version: '3.30.0',
	meson_version: '>= 0.43.0',
	license: 'GPLv2'
)

gnome = import('gnome')
i18n = import('i18n')

locale_dir = join_paths(get_option('prefix'), get_option('localedir'))
po_dir = join_paths(meson.source_root(), 'po')
data_dir = join_paths (get_option ('prefix'), get_option ('datadir'))
pkgdata_dir = join_paths (data_dir, 'five-or-more')

# Dependencies
glib_min_version = '2.32'

gio_dep = dependency('gio-2.0', version: '>= ' + glib_min_version)
glib_dep = dependency('glib-2.0', version: '>= ' + glib_min_version)
gmodule_export_dep = dependency('gmodule-export-2.0')
gtk_dep = dependency('gtk+-3.0', version: '>= 3.20.0')
libgnome_games_support_dep = dependency('libgnome-games-support-1')
librsvg_dep = dependency('librsvg-2.0', version: '>= 2.32.0')

# Libraries
cc = meson.get_compiler('c')
libmath_dep = cc.find_library('m')

# Configuration
conf = configuration_data()

conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
conf.set_quoted('LOCALEDIR', locale_dir)
conf.set_quoted('DATA_DIRECTORY', pkgdata_dir)
conf.set_quoted('VERSION', meson.project_version())

configure_file(output: 'config.h', configuration: conf)
config_h_dir = include_directories('.')

# Extra scripts
meson.add_install_script('meson_post_install.py')

# Subdirs
subdir('data')
subdir('help')
subdir('po')
subdir('src')