File: src.pro

package info (click to toggle)
fraqtive 0.4.3-2
  • links: PTS
  • area: main
  • in suites: lenny
  • size: 988 kB
  • ctags: 1,249
  • sloc: cpp: 8,387; sh: 103; makefile: 45
file content (175 lines) | stat: -rw-r--r-- 5,115 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
include( ../config.pri )

TEMPLATE = app
TARGET = fraqtive

QT += opengl

HEADERS   += abstractjobprovider.h \
             abstractview.h \
             advancedsettingspage.h \
             animationpage.h \
             bookmarklistview.h \
             bookmarkmodel.h \
             colorsettingspage.h \
             colorwidget.h \
             configurationdata.h \
             datafunctions.h \
             datastructures.h \
             doubleedit.h \
             doubleslider.h \
             fractaldata.h \
             fractalgenerator.h \
             fractalmodel.h \
             fractalpresenter.h \
             fractaltypedialog.h \
             fractaltypewidget.h \
             fraqtiveapplication.h \
             fraqtivemainwindow.h \
             generatorcore.h \
             gradientdialog.h \
             gradientwidget.h \
             imageview.h \
             jobscheduler.h \
             loadbookmarkdialog.h \
             loadpresetdialog.h \
             meshview.h \
             multiiconengine.h \
             parameterspage.h \
             presetlistview.h \
             presetmodel.h \
             propertytoolbox.h \
             renamedialog.h \
             savebookmarkdialog.h \
             savepresetdialog.h \
             shadewidget.h \
             tutorialdialog.h \
             viewcontainer.h

SOURCES   += advancedsettingspage.cpp \
             animationpage.cpp \
             bookmarklistview.cpp \
             bookmarkmodel.cpp \
             colorsettingspage.cpp \
             colorwidget.cpp \
             configurationdata.cpp \
             datafunctions.cpp \
             datastructures.cpp \
             doubleedit.cpp \
             doubleslider.cpp \
             fractaldata.cpp \
             fractalgenerator.cpp \
             fractalmodel.cpp \
             fractalpresenter.cpp \
             fractaltypedialog.cpp \
             fractaltypewidget.cpp \
             fraqtiveapplication.cpp \
             fraqtivemainwindow.cpp \
             gradientdialog.cpp \
             gradientwidget.cpp \
             imageview.cpp \
             jobscheduler.cpp \
             loadbookmarkdialog.cpp \
             loadpresetdialog.cpp \
             main.cpp \
             meshview.cpp \
             multiiconengine.cpp \
             parameterspage.cpp \
             presetlistview.cpp \
             presetmodel.cpp \
             propertytoolbox.cpp \
             renamedialog.cpp \
             savebookmarkdialog.cpp \
             savepresetdialog.cpp \
             shadewidget.cpp \
             tutorialdialog.cpp \
             viewcontainer.cpp

FORMS     += advancedsettingspage.ui \
             animationpage.ui \
             colorsettingspage.ui \
             fractaltypedialog.ui \
             fractaltypewidget.ui \
             fraqtivemainwindow.ui \
             gradientdialog.ui \
             gradientwidget.ui \
             loadbookmarkdialog.ui \
             loadpresetdialog.ui \
             parameterspage.ui \
             renamedialog.ui \
             savebookmarkdialog.ui \
             savepresetdialog.ui \
             tutorialdialog.ui

RESOURCES += data.qrc \
             icons.qrc \
             tutorial.qrc

win32 {
    HEADERS += windowsmodernstyle.h
    SOURCES += windowsmodernstyle.cpp
}

no-sse2|win32-msvc|win32-g++: CONFIG -= sse2

sse2 {
    DEFINES += HAVE_SSE2
    win32-g++|!win32:!*-icc* {
        SSE2_SOURCES += generatorcore.cpp
        sse2_compiler.commands = $$QMAKE_CXX -c -msse2 $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
        sse2_compiler.dependency_type = TYPE_C
        sse2_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
        sse2_compiler.input = SSE2_SOURCES
        sse2_compiler.variable_out = OBJECTS
        sse2_compiler.name = compiling[sse2] ${QMAKE_FILE_IN}
        silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
        QMAKE_EXTRA_COMPILERS += sse2_compiler
    } else {
        SOURCES += generatorcore.cpp
    }
} else {
    SOURCES += generatorcore.cpp
}

INCLUDEPATH += .

PRECOMPILED_HEADER = fraqtive_pch.h

win32 {
    RC_FILE = fraqtive.rc
    LIBS += -lshell32
}

MOC_DIR = ../tmp
RCC_DIR = ../tmp
UI_DIR = ../tmp
CONFIG( debug, debug|release ) {
    OBJECTS_DIR = ../tmp/debug
    DESTDIR = ../debug
} else {
    OBJECTS_DIR = ../tmp/release
    DESTDIR = ../release
}

win32-msvc* {
    QMAKE_CXXFLAGS += -Fd\$(IntDir)
}

target.path = $$PREFIX/bin
INSTALLS += target

unix {
    desktop.files = fraqtive.desktop
    desktop.path = $$PREFIX/share/applications
    INSTALLS += desktop

    ICON_SIZES = 16 22 32 48
    for( size, ICON_SIZES ) {
        path = $$PREFIX/share/icons/hicolor/$${size}x$${size}/apps
        file = $(INSTALL_ROOT)$$path/fraqtive.png
        eval( icon-$${size}.path = $$path )
        eval( icon-$${size}.commands = -$(INSTALL_FILE) $$IN_PWD/icons/fraqtive-$${size}.png $$file )
        eval( icon-$${size}.uninstall = -$(DEL_FILE) $$file )
        INSTALLS += icon-$${size}
    }
}