File: phoenix.pro

package info (click to toggle)
fritzing 0.9.3b+dfsg-9
  • links: PTS, VCS
  • area: main
  • in suites: bullseye, buster, sid
  • size: 38,868 kB
  • sloc: cpp: 102,277; ansic: 2,611; python: 2,523; xml: 1,981; sh: 261; makefile: 24
file content (252 lines) | stat: -rw-r--r-- 7,836 bytes parent folder | download | duplicates (2)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
# /*******************************************************************
#
# Part of the Fritzing project - http://fritzing.org
# Copyright (c) 2007-08 Fritzing
#
# Fritzing is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# Fritzing is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with Fritzing.  If not, see <http://www.gnu.org/licenses/>.
#
# ********************************************************************
#
# $Revision: 6960 $:
# $Author: irascibl@gmail.com $:
# $Date: 2013-04-10 12:15:14 +0200 (Mi, 10. Apr 2013) $
#
#********************************************************************/

# Fritzing requires two Qt-provided plugins in order to run correctly,
# however the QTPLUGIN syntax only seems to work if Qt is built statically,
# so QTPLUGIN is included here only for information purposes:
#
# QTPLUGIN  += qjpeg qsqlite


CONFIG += debug_and_release

win32 {
# release build using msvc 2010 needs to use Multi-threaded (/MT) for the code generation/runtime library option
# release build using msvc 2010 needs to add msvcrt.lib;%(IgnoreSpecificDefaultLibraries) to the linker/no default libraries option
        CONFIG -= embed_manifest_exe
        INCLUDEPATH += $$[QT_INSTALL_HEADERS]/QtZlib
        DEFINES += _CRT_SECURE_NO_DEPRECATE
        DEFINES += _WINDOWS
	RELEASE_SCRIPT = $$(RELEASE_SCRIPT)			# environment variable set from release script

        message("target arch: $${QMAKE_TARGET.arch}")
        contains(QMAKE_TARGET.arch, x86_64) {
                RELDIR = ../release64
                DEBDIR = ../debug64
                DEFINES += WIN64
       }
       !contains(QMAKE_TARGET.arch, x86_64) {
                RELDIR = ../release32
                DEBDIR = ../debug32
        }

	Release:DESTDIR = $${RELDIR}
	Release:OBJECTS_DIR = $${RELDIR}
	Release:MOC_DIR = $${RELDIR}
	Release:RCC_DIR = $${RELDIR}
	Release:UI_DIR = $${RELDIR}

	Debug:DESTDIR = $${DEBDIR}
	Debug:OBJECTS_DIR = $${DEBDIR}
	Debug:MOC_DIR = $${DEBDIR}
	Debug:RCC_DIR = $${DEBDIR}
	Debug:UI_DIR = $${DEBDIR}
}
macx {
        RELDIR = ../release64
        DEBDIR = ../debug64
        Release:DESTDIR = $${RELDIR}
        Release:OBJECTS_DIR = $${RELDIR}
        Release:MOC_DIR = $${RELDIR}
        Release:RCC_DIR = $${RELDIR}
        Release:UI_DIR = $${RELDIR}

        Debug:DESTDIR = $${DEBDIR}
        Debug:OBJECTS_DIR = $${DEBDIR}
        Debug:MOC_DIR = $${DEBDIR}
        Debug:RCC_DIR = $${DEBDIR}
        Debug:UI_DIR = $${DEBDIR}

        QMAKE_MAC_SDK = macosx10.11             # uncomment/adapt for your version of OSX
        CONFIG += x86_64 # x86 ppc
        QMAKE_INFO_PLIST = FritzingInfo.plist
        #DEFINES += QT_NO_DEBUG   		# uncomment this for xcode
        LIBS += -lz
        LIBS += /usr/lib/libz.dylib
        LIBS += /System/Library/Frameworks/CoreFoundation.framework/Versions/A/CoreFoundation
        LIBS += /System/Library/Frameworks/Carbon.framework/Carbon
        LIBS += /System/Library/Frameworks/IOKit.framework/Versions/A/IOKit
}
unix {
    !macx { # unix is defined on mac
        HARDWARE_PLATFORM = $$system(uname -m)
        contains( HARDWARE_PLATFORM, x86_64 ) {
            DEFINES += LINUX_64
        } else {
            DEFINES += LINUX_32
        }
        LIBS += -lz
    }

        isEmpty(PREFIX) {
                PREFIX = /usr
        }
        BINDIR = $$PREFIX/bin
        DATADIR = $$PREFIX/share
        PKGDATADIR = $$DATADIR/fritzing

        DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

        target.path =$$BINDIR

        desktop.path = $$DATADIR/applications
        desktop.files += fritzing.desktop

        manpage.path = $$DATADIR/man/man1
        manpage.files += Fritzing.1

        icon.path = $$DATADIR/icons
        icon.extra = install -D -m 0644 $$PWD/resources/images/fritzing_icon.png $(INSTALL_ROOT)$$DATADIR/icons/fritzing.png

        parts.path = $$PKGDATADIR
        parts.files += parts

        help.path = $$PKGDATADIR
        help.files += help

        sketches.path = $$PKGDATADIR
        sketches.files += sketches

        bins.path = $$PKGDATADIR
        bins.files += bins

        translations.path = $$PKGDATADIR/translations
        translations.extra = find $$PWD/translations -name "*.qm" -size +128c -exec cp -pr {} $(INSTALL_ROOT)$$PKGDATADIR/translations \\;

        syntax.path = $$PKGDATADIR/translations/syntax
        syntax.files += translations/syntax/*.xml

        INSTALLS += target desktop manpage icon parts sketches bins translations syntax help
}

ICON = resources/system_icons/macosx/fritzing_icon.icns

macx {
    FILE_ICONS.files = resources/system_icons/macosx/mac_fz_icon.icns resources/system_icons/macosx/mac_fzz_icon.icns resources/system_icons/macosx/mac_fzb_icon.icns resources/system_icons/macosx/mac_fzp_icon.icns resources/system_icons/macosx/mac_fzm_icon.icns resources/system_icons/macosx/mac_fzpz_icon.icns
    FILE_ICONS.path = Contents/Resources
    QMAKE_BUNDLE_DATA += FILE_ICONS
}

QT += core gui svg xml network sql # opengl
greaterThan(QT_MAJOR_VERSION, 4) {
    QT += widgets printsupport concurrent serialport
} else {
    include($$QTSERIALPORT_PROJECT_ROOT/src/serialport/qt4support/serialport.prf)
}

RC_FILE = fritzing.rc
RESOURCES += phoenixresources.qrc


# Fritzing is using libgit2 since version 0.9.3

LIBGIT2INCLUDE = ../libgit2/include
exists($$LIBGIT2INCLUDE/git2.h) {
    message("found libgit2 include path at $$LIBGIT2INCLUDE")
}
else {
    message("Fritzing requires libgit2")
    message("Build it from the repo at https://github.com/libgit2")
    message("See https://github.com/fritzing/fritzing-app/wiki for details.")

    error("libgit2 include path not found in $$LIBGIT2INCLUDE")
}

INCLUDEPATH += $$LIBGIT2INCLUDE

win32 {
    contains(QMAKE_TARGET.arch, x86_64) {
            LIBGIT2LIB = ../libgit2/build64
    }
    else {
            LIBGIT2LIB = ../libgit2/build32
    }

    exists($$LIBGIT2LIB/git2.lib) {
        message("found libgit2 library in $$LIBGIT2LIB")
    }
    else {
        error("libgit2 library not found in $$LIBGIT2LIB")
    }
}

unix {
    LIBGIT2LIB = ../libgit2/build
    macx {
        exists($$LIBGIT2LIB/libgit2.dylib) {
            message("found libgit2 library in $$LIBGIT2LIB")
        }
        else {
            error("libgit2 library not found in $$LIBGIT2LIB")
        }
    }
    !macx {
        exists($$LIBGIT2LIB/libgit2.so) {
            message("found libgit2 library in $$LIBGIT2LIB")
        }
        else {
            error("libgit2 library not found in $$LIBGIT2LIB")
        }
    }
}

LIBS += -L$$LIBGIT2LIB -lgit2

include(pri/kitchensink.pri)
include(pri/mainwindow.pri)
include(pri/partsbinpalette.pri)
include(pri/partseditor.pri)
include(pri/referencemodel.pri)
include(pri/svg.pri)
include(pri/help.pri)
include(pri/version.pri)
include(pri/eagle.pri)
include(pri/utils.pri)
include(pri/dock.pri)
include(pri/items.pri)
include(pri/autoroute.pri)
include(pri/dialogs.pri)
include(pri/connectors.pri)
include(pri/infoview.pri)
include(pri/model.pri)
include(pri/sketch.pri)
include(pri/translations.pri)
include(pri/program.pri)
include(pri/qtsysteminfo.pri)

!contains(DEFINES, QUAZIP_INSTALLED) {
        include(pri/quazip.pri)
}
contains(DEFINES, QUAZIP_INSTALLED) {
        INCLUDEPATH += /usr/include/quazip /usr/include/minizip
        LIBS += -lquazip -lminizip
}

TARGET = Fritzing
TEMPLATE = app


message("libs $$LIBS")