1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
|
/* commandl.l: Debugger command lexical scanner
Copyright (c) 2002-2008 Philip Kendall
$Id: commandl.l 4130 2010-05-18 12:06:19Z fredm $
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License along
with this program; if not, write to the Free Software Foundation, Inc.,
51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
Author contact information:
E-mail: philip-fuse@shadowmagic.org.uk
*/
%{
#include <config.h>
#include <ctype.h>
#include "debugger.h"
#include "debugger_internals.h"
#include "mempool.h"
#include "commandy.h"
#define YY_INPUT(buf,result,max_size) \
{ \
int retval; \
if( !debugger_command_input( buf, &retval, max_size ) ) retval = YY_NULL; \
result = (yy_size_t)retval; \
}
#define YY_NO_INPUT
%}
ID [a-z][a-z0-9]+
%option caseless
%s COMMANDSTATE1
%x COMMANDSTATE2
%%
ba|bas|base { return BASE; }
br|bre|brea|break|breakp|breakpo|breakpoi|breakpoin|breakpoint { return BREAK;}
co|con|cont|contin|continu|continue { return CONTINUE; }
com|comm|comma|comman|command|commands { BEGIN(COMMANDSTATE1); return COMMANDS; }
cond|condi|condit|conditi|conditio|condition { return CONDITION; }
cl|cle|clea|clear { return CLEAR; }
del|dele|delet|delete { return DEBUGGER_DELETE; }
di|dis|disa|disas|disass|disasse|disassm|disassmb|diasassmbl|disassemble {
return DISASSEMBLE; }
ev|eve|even|event { return EVENT; }
ex|exi|exit { return EXIT; }
fi|fin|fini|finis|finish { return FINISH; }
if { return IF; }
i|ig|ign|igno|ignor|ignore { return DEBUGGER_IGNORE; }
n|ne|nex|next { return NEXT; }
o|ou|out { return DEBUGGER_OUT; } /* Different name to avoid clashing
with OUT from z80/z80_macros.h */
p|po|por|port { return PORT; }
pr|pri|prin|print { return DEBUGGER_PRINT; }
r|re|rea|read { return READ; }
se|set { return SET; }
s|st|ste|step { return STEP; }
t|tb|tbr|tbre|tbrea|tbreak|tbreakp|tbreakpo|tbreakpoi|tbreakpoin|tbreakpoint {
return TBREAK; }
ti|tim|time { return TIME; }
w|wr|wri|writ|write { return WRITE; }
a|b|c|d|e|f|h|l { yylval.reg = debugger_register_hash( yytext );
return DEBUGGER_REGISTER; }
"a'"|"b'"|"c'"|"d'"|"e'"|"f'"|"h'"|"l'" {
yylval.reg = debugger_register_hash( yytext );
return DEBUGGER_REGISTER; }
af|bc|de|hl|"af\'"|"bc\'"|"de\'"|"hl\'" {
yylval.reg = debugger_register_hash( yytext );
return DEBUGGER_REGISTER; }
sp|pc|ix|iy { yylval.reg = debugger_register_hash( yytext );
return DEBUGGER_REGISTER; }
"(" { return '('; }
")" { return ')'; }
"!" { yylval.token = '!'; return NEGATE; }
"~" { yylval.token = '~'; return NEGATE; }
/* The hex constants used here are the appropriate Unicode characters */
"==" { yylval.token = DEBUGGER_TOKEN_EQUAL_TO; return EQUALITY; }
"!=" { yylval.token = DEBUGGER_TOKEN_NOT_EQUAL_TO;
return EQUALITY; }
"<" { yylval.token = '<'; return COMPARISON; }
">" { yylval.token = '>'; return COMPARISON; }
"<=" { yylval.token = DEBUGGER_TOKEN_LESS_THAN_OR_EQUAL_TO;
return COMPARISON; }
">=" { yylval.token = DEBUGGER_TOKEN_GREATER_THAN_OR_EQUAL_TO;
return COMPARISON; }
"+" { return '+'; }
"-" { return '-'; }
"*" { yylval.token = '*'; return TIMES_DIVIDE; }
"/" { yylval.token = '/'; return TIMES_DIVIDE; }
"&" { return '&'; }
"^" { return '^'; }
"|" { return '|'; }
"&&" { return LOGICAL_AND; }
"||" { return LOGICAL_OR; }
":" { return ':'; }
$[[:xdigit:]]+ { yylval.integer = strtol( yytext+1, NULL, 16 );
if( YY_START == COMMANDSTATE1 ) BEGIN( COMMANDSTATE2 );
return NUMBER; }
0x[[:xdigit:]]+ { yylval.integer = strtol( yytext+2, NULL, 16 );
if( YY_START == COMMANDSTATE1 ) BEGIN( COMMANDSTATE2 );
return NUMBER; }
[[:digit:]]+ { yylval.integer = atoi( yytext );
if( YY_START == COMMANDSTATE1 ) BEGIN( COMMANDSTATE2 );
return NUMBER; }
[cdrx][[:digit:]]+ { yylval.integer = debugger_page_hash( yytext ); return PAGE; }
{ID} { yylval.string = mempool_strdup( debugger_memory_pool, yytext ); return STRING; }
${ID} { yylval.string = mempool_strdup( debugger_memory_pool, yytext + 1 ); return VARIABLE; }
\n { return '\n'; }
[ ]+ /* Swallow whitespace */
. { if( 0 ) unput( '\0' ); /* Prevent warning about yyunput
being defined and not used */
return DEBUGGER_ERROR; }
/* Debugger command parsing */
<COMMANDSTATE2>{
end { BEGIN(INITIAL); return DEBUGGER_END; }
[^\n]* { yylval.string = mempool_strdup( debugger_memory_pool, yytext ); return STRING; }
\n { return '\n'; }
}
|
