File: gammaray-qt-ci-only.pro

package info (click to toggle)
gammaray 2.9.0-2.1
  • links: PTS, VCS
  • area: main
  • in suites: buster
  • size: 19,704 kB
  • sloc: cpp: 89,250; ansic: 1,185; sh: 141; lex: 93; yacc: 90; xml: 57; makefile: 29
file content (40 lines) | stat: -rw-r--r-- 1,431 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
# qmake -> cmake wrapper for the Qt CI system
#
# DO NOT USE THIS UNLESS YOU KNOW WHAT YOU ARE DOING!
#
# This only supports a tiny subset of the CMake build system,
# hardcoded for the needs of integration with the Qt CI system.
#
# If you are building GammaRay yourself, please use CMake as
# described in Install. txt

requires(linux:!android|win32:!winphone:!winrt)
requires(!integrity)
requires(!cross_compile)

win32: requires(!contains(QMAKE_HOST.version_string,  $$re_escape(8.1)))

message("QMake wrapper for the GammaRay build system is only supported for the Qt CI.")
message("If you are seeing this and you are not the Qt CI, please refer to Install.txt!")

# additional indirection is needed as the above requires conditions don't work correctly
# in aux templates, on some platforms
TEMPLATE = subdirs
SUBDIRS += qt-ci-wrapper

# forward non-built-in targets too
QMAKE_EXTRA_TARGETS += gammaray_build_docs gammaray_build_qch_docs
gammaray_build_docs.CONFIG = recursive
gammaray_build_docs.recurse_target = docs
gammaray_build_docs.target = docs
gammaray_build_qch_docs.target = qch_docs
gammaray_build_qch_docs.depends = docs

# add dummy qmake targets for doc build - only qch_docs triggers the build
DOC_TARGETS = \
    prepare_docs generate_docs html_docs \
    install_html_docs uninstall_html_docs \
    install_qch_docs uninstall_qch_docs \
    install_docs uninstall_docs

QMAKE_EXTRA_TARGETS += $$DOC_TARGETS