File: qt-ci-wrapper.pro

package info (click to toggle)
gammaray 3.1.0%2Bds-3
  • links: PTS, VCS
  • area: main
  • in suites: forky, sid, trixie
  • size: 24,796 kB
  • sloc: cpp: 109,174; ansic: 2,156; sh: 336; python: 274; yacc: 90; lex: 82; xml: 61; makefile: 28; javascript: 9; ruby: 5
file content (68 lines) | stat: -rw-r--r-- 2,236 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# This file is part of GammaRay, the Qt application inspection and manipulation tool.
#
# SPDX-FileCopyrightText: 2017 Klarälvdalens Datakonsult AB, a KDAB Group company <info@kdab.com>
#
# SPDX-License-Identifier: GPL-2.0-or-later
#
# Contact KDAB at <info@kdab.com> for commercial licensing options.
#

TEMPLATE = aux

# convert path and command separators to platform format
SHELL_INSTALL_PREFIX = $$shell_path($$[QT_INSTALL_PREFIX])
SHELL_PWD = $$shell_path($$PWD/..)
SHELL_SEP = ;
win32: SHELL_SEP = &

# platform specific cmake arguments
win32-msvc*: CMAKE_PLATFORM_ARGS = -G\"NMake Makefiles\"
win32-g++:  CMAKE_PLATFORM_ARGS = -G\"MinGW Makefiles\"

gammaray_configure.target = gammaray_configure
gammaray_configure.commands = \
    ($$sprintf($$QMAKE_MKDIR_CMD, "build")) $$SHELL_SEP \
    cd build $$SHELL_SEP \
    cmake $$CMAKE_PLATFORM_ARGS \
        -DCMAKE_INSTALL_PREFIX=$$SHELL_INSTALL_PREFIX \
        -DCMAKE_PREFIX_PATH=$$SHELL_INSTALL_PREFIX \
        -DGAMMARAY_INSTALL_QT_LAYOUT=TRUE \
        -DGAMMARAY_BUILD_DOCS=FALSE \
        -DGAMMARAY_DISABLE_FEEDBACK=TRUE \
        -DGAMMARAY_BUILD_UI=FALSE \
        $$GAMMARAY_EXTRA_ARGS $$SHELL_PWD

gammaray_build.target = gammaray_build
gammaray_build.depends += gammaray_configure
gammaray_build.commands = cd build $$SHELL_SEP $(MAKE)

gammaray_test.target = check
gammaray_test.depends += gammaray_configure
gammaray_test.commands = cd build $$SHELL_SEP $(MAKE) test

gammaray_install.target = install
gammaray_install.commands = cd build $$SHELL_SEP $(MAKE) DESTDIR=$(INSTALL_ROOT) install

QMAKE_EXTRA_TARGETS += \
    gammaray_configure \
    gammaray_build \
    gammaray_test \
    gammaray_install

# build documentation directly, the Qt CI can't run CMake at this stage
QMAKE_DOCS = $$PWD/../docs/manual/gammaray-manual.qdocconf
load(qt_docs)
docs.commands = $(MAKE) -f $(MAKEFILE) html_docs && $(MAKE) -f $(MAKEFILE) qch_docs
QMAKE_EXTRA_TARGETS += docs

DOC_TARGETS = \
    install_html_docs uninstall_html_docs \
    install_qch_docs uninstall_qch_docs \
    install_docs uninstall_docs \
    qch_docs prepare_docs generate_docs \
    html_docs
QMAKE_EXTRA_TARGETS += $$DOC_TARGETS

# default target
TARGET = gammaray
PRE_TARGETDEPS += gammaray_build