1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# check for mpc library
# sets MPC_CPPFLAGS, MPC_LDFLAGS and MPC_LIBS,
# and MPC=yes/no
AC_DEFUN([AC_CHECK_MPC],[
temp_LIBS="$LIBS"
temp_CPPFLAGS="$CPPFLAGS"
temp_LDFLAGS="$LDFLAGS"
MPC=unknown
AC_ARG_WITH([mpc],
[AS_HELP_STRING([--with-mpc=<location>],
[Location at which the MPC library was installed.
If the argument is omitted, the library is assumed to be reachable
under the standard search path (/usr, /usr/local,...). Otherwise
you must give the <path> to the directory which contains the
library.])],
[if test "$withval" = no; then
MPC=no
elif test "$withval" = yes; then
MPC=yes
else
MPC=yes
MPC_CPPFLAGS="-I$withval/include"
MPC_LDFLAGS="-L$withval/lib"
fi],
[AS_IF([command -v brew --prefix libmpc >/dev/null 2>&1],[
AC_MSG_NOTICE([BREW libmpc detected])
withval=$(brew --prefix)
MPC=yes
MPC_CPPFLAGS="-I$withval/include"
MPC_LDFLAGS="-L$withval/lib"
])]
)
AC_ARG_WITH([mpc-include],
[AS_HELP_STRING([--with-mpc-include=<location>],
[Location at which the mpc include files were installed.])],
[MPC=yes
MPC_CPPFLAGS="-I$withval"]
)
AC_ARG_WITH([mpc-lib],
[AS_HELP_STRING([--with-mpc-lib=<location>],
[Location at which the mpc library files were installed.])],
[MPC=yes
MPC_LDFLAGS="-L$withval"]
)
if test "$MPC" != no; then
if test "$MPFR" = no; then
AC_MSG_ERROR([Cannot have MPC without having MPFR too.])
fi
MPC_LIBS="-lmpc"
AC_LANG_PUSH([C])
temp_status=true
CPPFLAGS="$CPPFLAGS $MPC_CPPFLAGS $MPFR_CPPFLAGS"
AC_CHECK_HEADER(mpc.h,,[temp_status=false],[#include <mpfr.h>])
LDFLAGS="$LDFLAGS $MPC_LDFLAGS $MPFR_LDFLAGS"
AC_CHECK_LIB(mpc,mpc_sqrt,,[temp_status=false])
AC_LANG_POP([C])
if test "$temp_status" = false; then
if test "$MPC" = yes; then
AC_MSG_ERROR([library mpc not found. Using --with-mpc, specify its location, or "no" to disable it.])
else
MPC=no
fi
else
MPC=yes
fi
fi
CPPFLAGS="$temp_CPPFLAGS"
LDFLAGS="$temp_LDFLAGS"
LIBS="$temp_LIBS"
if test "$MPC" != no; then
AC_DEFINE([USE_MPC],1,[use MPC library])
fi
AC_SUBST(MPC_CPPFLAGS)
AC_SUBST(MPC_LDFLAGS)
AC_SUBST(MPC_LIBS)
AM_CONDITIONAL([WITH_MPC_IS_YES],[test x"$MPC" != xno])
])
|
