1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
|
#(C) Graham Ellis, October 2005
#####################################################################
InstallGlobalFunction(NonabelianTensorSquare,
function(arg)
local
AG, SizeOrList,
gensAG, NiceGensAG,
G, gensG, relsG,
BG, GhomBG, BG1homF, BG2homF,
F, relsT, gensF, gensF1, gensF2,
AF, FhomAF,
AGhomG, G1homF, G2homF, AG1homF, AG2homF,
SF, gensSF, gensSFG, FhomSF, AFhomSF, AG1homSF, AG2homSF, SFhomAG,
AFhomSSF,SSF,gensSF2,SSFhomSF,
TensorSquare, delta,
Trans,
CrossedPairing, action,
UpperBound,
Todd,i,v,w,x,y,z;
if not IsFinite(arg[1]) then return NonabelianTensorSquare_inf(arg[1]); fi;
Todd:=16; #Use Todd-Coxeter if Order(G)<Todd and G is not nilpotent.
#####################################################################
UpperBound:=function(AG)
local Facts, p,P,hom,bnd;
Facts:=SSortedList(Factors(Order(AG)));
bnd:=1;
for p in Facts do
P:=SylowSubgroup(AG,p);
hom:=NonabelianTensorSquare(P).homomorphism;
bnd:=bnd*Order(Source(hom))/Order(DerivedSubgroup(P));
od;
return bnd*Order(DerivedSubgroup(AG))*Order(AG)^2;
end;
#####################################################################
AG:=arg[1];
if Length(arg)>1 then SizeOrList:=arg[2]*Order(AG)^2;
else
if not IsSolvable(AG) then SizeOrList:=0;
else
if not IsNilpotent(AG) and Size(AG)>Todd
then SizeOrList:=UpperBound(AG); fi;
if not IsNilpotent(AG) and Size(AG)<=Todd then SizeOrList:=0;fi;
if IsNilpotent(AG) then SizeOrList:=-1; fi;
fi;
fi;
# AG and SF are groups whose elements are essentially enumerated. AG is
# isomorphic to G and to BG. SF is equal to F/relsT and AF. Two isomorphic
# copies of AG lie inside SF, and the homomorphisms AG1homSF, AG2homSF
# identify the two copies. delta is the commutator map from TensorSquare to AG.
# The homomorphisms GhomBG, AGhomG, FhomSF, FhomAF, AFhomSF are all
# isomorphisms. The relationship between the groups is summarized in the
# following diagrams: AG->G->BG->F->AF->SF and SF->AG.
gensAG:=ReduceGenerators(GeneratorsOfGroup(AG),AG);
AGhomG:=IsomorphismFpGroupByGenerators(AG,gensAG);
G:=Range(AGhomG);
gensG:=FreeGeneratorsOfFpGroup(G);
relsG:=RelatorsOfFpGroup(G);
BG:=Group(gensG);
GhomBG:=GroupHomomorphismByImagesNC(G,BG, GeneratorsOfGroup(G),gensG);
#I hope GhomBG really is the identity map!
F:=FreeGroup(2*Length(gensG));
gensF:=GeneratorsOfGroup(F); gensF1:=[]; gensF2:=[];
for i in [1..Length(gensG)] do
Append(gensF1,[gensF[i]]);
Append(gensF2,[gensF[Length(gensG)+i]]);
od;
BG1homF:=GroupHomomorphismByImagesNC(BG,F,gensG,gensF1);
G1homF:=GroupHomomorphismByFunction(G,F,x->Image(BG1homF,Image(GhomBG,x)));
BG2homF:=GroupHomomorphismByImagesNC(BG,F,gensG,gensF2);
G2homF:=GroupHomomorphismByFunction(G,F,x->Image(BG2homF,Image(GhomBG,x)));
AG1homF:=GroupHomomorphismByFunction(AG,F,g->Image(G1homF,Image(AGhomG,g)));
AG2homF:=GroupHomomorphismByFunction(AG,F,g->Image(G2homF,Image(AGhomG,g)));
if IsSolvable(AG) then
NiceGensAG:=Pcgs(AG);
else
NiceGensAG:=List(UpperCentralSeries(AG),x->GeneratorsOfGroup(x));
NiceGensAG[1]:=[Identity(AG)];
NiceGensAG:=Flat(NiceGensAG);
Trans:=RightTransversal(AG,Group(NiceGensAG));
Append(NiceGensAG,Elements(Trans));
fi;
relsT:=[];
for x in relsG do
Append(relsT,[Image(BG1homF,x), Image(BG2homF,x)]);
od;
for z in NiceGensAG do
for x in gensAG do
for y in gensAG do
v:=Comm(Image(AG1homF,x),Image(AG2homF,y))^Image(AG1homF,z) ;
w:=Comm(Image(AG2homF,y^z),Image(AG1homF,x^z) );
Append(relsT,[v*w]);
v:=Comm(Image(AG1homF,x),Image(AG2homF,y))^Image(AG2homF,z);
Append(relsT,[v*w]);
od;
od;
od;
#####################################################################IF
if SizeOrList=0 then
AF:=F/relsT;
FhomAF:=
GroupHomomorphismByImagesNC(F,AF,GeneratorsOfGroup(F),GeneratorsOfGroup(AF));
AFhomSF:=IsomorphismSimplifiedFpGroup(AF);
SF:=Image(AFhomSF);
FhomSF:=
GroupHomomorphismByFunction(F,SF,x->Image(AFhomSF,Image(FhomAF,x)) );
else
AF:=F/relsT;
FhomAF:=
GroupHomomorphismByImagesNC(F,AF,GeneratorsOfGroup(F),GeneratorsOfGroup(AF));
AFhomSSF:=IsomorphismSimplifiedFpGroup(AF);
SSF:=Image(AFhomSSF);
if SizeOrList=-1 then #if nilpotent
SSFhomSF:=EpimorphismNilpotentQuotient(SSF);
#SSFhomSF:=IsomorphismPcGroup(SSF);
else #if solvable and big
SSFhomSF:=EpimorphismSolvableQuotient(SSF,SizeOrList);
fi;
SF:=Range(SSFhomSF);
gensSF2:=List(GeneratorsOfGroup(AF),x->Image(SSFhomSF,Image(AFhomSSF,x)));
AFhomSF:=GroupHomomorphismByImagesNC(AF,SF,GeneratorsOfGroup(AF),gensSF2);
FhomSF:=
GroupHomomorphismByFunction(F,SF,x->Image(AFhomSF,Image(FhomAF,x)) );
fi;
#####################################################################FI
AG1homSF:=GroupHomomorphismByFunction(AG,SF,x->Image(FhomSF,Image(AG1homF,x)));
AG2homSF:=GroupHomomorphismByFunction(AG,SF,x->Image(FhomSF,Image(AG2homF,x)));
TensorSquare:=NormalIntersection(
NormalClosure(SF,Group(List(GeneratorsOfGroup(AG),x->Image(AG1homSF,x)))),
NormalClosure(SF,Group(List(GeneratorsOfGroup(AG),x->Image(AG2homSF,x))))
);
gensSF:=List(gensF,x->Image(FhomSF,x));
gensSFG:=[];
for i in [1..Length(gensAG)] do
Append(gensSFG,[gensAG[i]]);
od;
for i in [1..Length(gensAG)] do
Append(gensSFG,[gensAG[i]]);
od;
SFhomAG:=GroupHomomorphismByImagesNC(SF,AG,gensSF,gensSFG);
delta:=GroupHomomorphismByImagesNC(TensorSquare,AG,
GeneratorsOfGroup(TensorSquare),
List(GeneratorsOfGroup(TensorSquare),x->Image(SFhomAG,x)));
#####################################################################
CrossedPairing:=function(x,y)
return Comm(Image(AG1homSF,x), Image(AG2homSF,y));
end;
#####################################################################
#####################################################################
action:=function(x,t)
return Image(AG1homSF,x) * t * Image(AG1homSF,x)^-1;
end;
#####################################################################
return rec(homomorphism:=delta, pairing:=CrossedPairing, action:=action,nu:=SF);
end);
#####################################################################
#####################################################################
InstallGlobalFunction(ThirdHomotopyGroupOfSuspensionB,
function(arg) local T;
if Length(arg)>1 then
if arg[2]=0 then
return ThirdHomotopyGroupOfSuspensionB_alt(arg[1]);
else
return AbelianInvariants(Kernel(
NonabelianTensorSquare(arg[1],arg[2]).homomorphism));
fi;
else
T:=NonabelianTensorSquare(arg[1]).homomorphism;
if IsAbelian(arg[1]) then return AbelianInvariants(Source(T));
else
return AbelianInvariants(Kernel(T));
fi;
fi;
end);
#####################################################################
#####################################################################
InstallGlobalFunction(FourthHomotopyGroupOfDoubleSuspensionB,
function(arg) local T;
T:=NonabelianSymmetricSquare(arg[1]).homomorphism;
if IsAbelian(arg[1]) then return AbelianInvariants(Source(T));
else
return AbelianInvariants(Kernel(T));
fi;
end);
#####################################################################
#####################################################################
InstallGlobalFunction(TensorCentre,
function(G)
local x,g,TC,h,Boole;
if IsTrivial(Centre(G)) then return Centre(G); fi;
h:=NonabelianTensorSquare(G).pairing;
TC:=[];
for g in Center(G) do
Boole:=true;
for x in G do
if not Order(h(g,x))=1 then Boole:=false; break; fi;
od;
if Boole then Append(TC,[g]); fi;
od;
return Group(Concatenation(TC,[Identity(G)]));
end);
######################################################################
######################################################################
InstallGlobalFunction(NonabelianTensorSquareAsCrossedModule,
function(G)
local delta, pairing, act, C;
C:=NonabelianTensorSquare(G);
delta:=C.homomorphism;
act:=C.action;
return Objectify(HapCrossedModule,rec(
map:=delta,
action:=act
));
end);
#######################################################################
######################################################################
InstallGlobalFunction(NonabelianTensorSquareAsCatOneGroup,
function(G)
local C;
C:=NonabelianTensorSquareAsCrossedModule(G);
return CatOneGroupByCrossedModule(C);
end);
#######################################################################
|
