1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
|
#############################################################################
##
## This file is part of GAP, a system for computational discrete algebra.
## This file's authors include Martin Schönert.
##
## Copyright of GAP belongs to its developers, whose names are too numerous
## to list here. Please refer to the COPYRIGHT file for details.
##
## SPDX-License-Identifier: GPL-2.0-or-later
##
#############################################################################
##
#M IsEqualSet( <list1>, <list2> ) . . . . . . . . . . . . . . for two lists
##
InstallMethod( IsEqualSet,
"for two lists",
true,
[ IsList, IsList ], 0,
function( list1, list2 )
return Set( list1 ) = Set( list2 );
end );
#############################################################################
##
#M IsEqualSet( <list1>, <list2> ) . . for two internally represented lists
##
InstallMethod( IsEqualSet,
"for two internally represented lists",
true,
[ IsList and IsInternalRep, IsList and IsInternalRep ], 0,
IS_EQUAL_SET );
#############################################################################
##
#M IsSubsetSet( <list1>, <list2> ) . . . . . . . . . . . . . . for two lists
##
InstallMethod( IsSubsetSet,
"for two lists",
true,
[ IsList, IsList ], 0,
function( list1, list2 )
list1:= Set( list1 );
return ForAll( Set( list2 ), x -> x in list1 );
end );
#############################################################################
##
#M IsSubsetSet( <list1>, <list2> ) . . for two internally represented lists
##
InstallMethod( IsSubsetSet,
"for two internally represented lists",
true,
[ IsList and IsInternalRep, IsList and IsInternalRep ], 0,
IS_SUBSET_SET );
#############################################################################
##
#M AddSet( <set>, <obj> ) . . . . . . . . . . for mutable list, and object
##
InstallMethod( AddSet,
"for mutable list, and object",
true,
[ IsList and IsMutable, IsObject ], 0,
function( set, obj )
local pos, len;
if not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
pos:= PositionSorted( set, obj );
if pos>Length(set) then
set[ pos ]:= obj;
elif set[ pos ] <> obj then
len:= Length( set );
set{ [ pos+1 .. len+1 ] }:= set{ [ pos .. len ] };
set[ pos ]:= obj;
fi;
end );
#############################################################################
##
#M AddSet( <set>, <obj> ) . . . . . for mutable int. repr. list, and object
##
InstallMethod( AddSet,
"for mutable internally represented list, and object",
true,
[ IsList and IsInternalRep and IsMutable, IsObject ], 0,
ADD_SET );
#############################################################################
##
#M RemoveSet( <set>, <obj> ) . . . . for mutable int. repr. list, and object
##
InstallMethod( RemoveSet,
"for mutable internally represented list, and object",
true,
[ IsList and IsInternalRep and IsMutable, IsObject ], 0,
REM_SET );
#############################################################################
##
#M RemoveSet( <set>, <obj> ) . . . . . . . . . for mutable list, and object
##
InstallMethod( RemoveSet,
"for mutable list, and object",
true,
[ IsList and IsMutable, IsObject ], 0,
function( set, obj )
local pos, len;
if not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
pos:= PositionSorted( set, obj );
len:= Length( set );
if pos <= len and set[ pos ] = obj then
set{ [ pos .. len-1 ] }:= set{ [ pos+1 .. len ] };
Unbind( set[ len ] );
fi;
end );
#############################################################################
##
#M UniteSet( <set>, <list> ) . . . . . for two internally represented lists
##
InstallMethod( UniteSet,
"for two internally represented lists, the first being mutable",
true,
[ IsList and IsInternalRep and IsMutable, IsList and IsInternalRep ], 0,
UNITE_SET );
#############################################################################
##
#M UniteSet( <set>, <list> ) . . . . . . . for two lists, the first mutable
##
InstallMethod( UniteSet,
"for two lists, the first being mutable",
true,
[ IsList and IsMutable, IsList ], 0,
function( set, list )
local obj;
if not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
for obj in list do
AddSet( set, obj );
od;
end );
#############################################################################
##
#M IntersectSet( <set>, <list> ) . . . for two internally represented lists
##
InstallMethod( IntersectSet,
"for two internally represented lists, the first being mutable",
true,
[ IsList and IsInternalRep and IsMutable, IsList and IsInternalRep ], 0,
INTER_SET );
#############################################################################
##
#M IntersectSet( <set>, <list> ) . . . . . for two lists, the first mutable
##
InstallMethod( IntersectSet,
"for two lists, the first being mutable",
true,
[ IsList and IsMutable, IsList ], 0,
function( set, list )
local obj,i;
if not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
i:= 1;
while i <= Length( set ) do
obj:= set[i];
if not obj in list then
RemoveSet( set, obj );
else
i:= i+1;
fi;
od;
end );
#############################################################################
##
#M SubtractSet( <set>, <list> ) . . . for two internally represented lists
##
InstallMethod( SubtractSet,
"for two internally represented lists, the first being mutable",
true,
[ IsList and IsInternalRep and IsMutable, IsList and IsInternalRep ], 0,
SUBTR_SET );
#############################################################################
##
#M SubtractSet( <set>, <list> ) . . . . . for two lists, the first mutable
##
InstallMethod( SubtractSet,
"for two lists, the first being mutable",
true,
[ IsList and IsMutable, IsList ], 0,
function( set, list )
local obj;
if not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
for obj in list do
RemoveSet( set, obj );
od;
end );
#############################################################################
##
## Fallback methods to give better user feedback if the first argument is
## not mutable or not a set
##
BindGlobal("_REQUIRE_MUTABLE_SET",
function( set, obj )
if not IsMutable(set) or not IsSSortedList( set ) then
Error( "<set> must be a mutable proper set" );
fi;
TryNextMethod();
end );
InstallOtherMethod( AddSet, "for two objects", [ IsObject, IsObject ], _REQUIRE_MUTABLE_SET);
InstallOtherMethod( RemoveSet, "for two objects", [ IsObject, IsObject ], _REQUIRE_MUTABLE_SET);
InstallOtherMethod( UniteSet, "for two objects", [ IsObject, IsObject ], _REQUIRE_MUTABLE_SET);
InstallOtherMethod( IntersectSet, "for two objects", [ IsObject, IsObject ], _REQUIRE_MUTABLE_SET);
InstallOtherMethod( SubtractSet, "for two objects", [ IsObject, IsObject ], _REQUIRE_MUTABLE_SET);
|
