File: ree.gi

package info (click to toggle)
gap 4r8p6-2
  • links: PTS
  • area: main
  • in suites: stretch
  • size: 33,476 kB
  • ctags: 7,663
  • sloc: ansic: 108,841; xml: 47,807; sh: 3,628; perl: 2,342; makefile: 796; asm: 62; awk: 6
file content (88 lines) | stat: -rw-r--r-- 2,526 bytes parent folder | download | duplicates (5)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
#############################################################################
##
#W  ree.gi                     GAP library
##
##
#Y  (C) 2001 School Math. Sci., University of St Andrews, Scotland
##

#############################################################################
##
#M  ReeGroupCons( <IsMatrixGroup>, <q> )
##
InstallMethod(ReeGroupCons,"matrix",true,
  [IsMatrixGroup,IsPosInt],0, 
function ( filter, q )
local theta, m, f, bas, one, zero, x, h, r, gens, G, i;

  m:=Int((LogInt(q,3)-1)/2);
  if m<0 or q<>3^(1+2*m) then
    Error("Usage: ReeGroup(<filter>,3^(1+2m))");
  fi;

  theta:=3^m;
  f:=GF(q);
  bas:=BasisVectors(Basis(f));
  one:=One(f);
  zero:=Zero(f);

  x:=function(t,u,v)
    return 
    [[1,t^theta,-u^theta,(t*u)^theta-v^theta,-u-t^(3*theta+1)-(t*v)^theta,
    -v-(u*v)^theta-t^(3*theta+2)-t^theta*u^(2*theta),
    t^theta*v-u^(theta+1)+t^(4*theta+2)-v^(2*theta)
       -t^(3*theta+1)*u^theta-(t*u*v)^theta],
    [0,1,t,u^theta+t^(theta+1),
    -t^(2*theta+1)-v^theta,-u^(2*theta)+t^(theta+1)*u^theta+t*v^theta,
    v+t*u-t^(2*theta+1)*u^theta-(u*v)^theta-t^(3*theta+2)-t^(theta+1)*v^theta],
    [0,0,1,t^theta,-t^(2*theta),v^theta+(t*u)^theta,
    u+t^(3*theta+1)-(t*v)^theta-t^(2*theta)*u^theta],
    [0,0,0,1,t^theta,u^theta,(t*u)^theta-v^theta],
    [0,0,0,0,1,-t,u^theta+t^(theta+1)],
    [0,0,0,0,0,1,-t^theta],
    [0,0,0,0,0,0,1]]*one;
  end;

  h:=function(t)
    return [[t^theta,0,0,0,0,0,0],
    [0,t^(1-theta),0,0,0,0,0],
    [0,0,t^(2*theta-1),0,0,0,0],
    [0,0,0,1,0,0,0],
    [0,0,0,0,t^(1-2*theta),0,0],
    [0,0,0,0,0,t^(theta-1),0],
    [0,0,0,0,0,0,t^(-theta)]]*one;
  end;

  r:=[[0,0,0,0,0,0,-1],
  [0,0,0,0,0,-1,0],
  [0,0,0,0,-1,0,0],
  [0,0,0,-1,0,0,0],
  [0,0,-1,0,0,0,0],
  [0,-1,0,0,0,0,0],
  [-1,0,0,0,0,0,0]]*one;

  # this generating set is not very good -- there is a 2-generator set. AH
  gens:=[];
  for i in bas do
    Add(gens,x(i,zero,zero));
    Add(gens,x(zero,i,zero));
    Add(gens,x(zero,zero,i));
  od;

  Add(gens,h(PrimitiveRoot(f)));
  Add(gens,r);
  G:=Group(gens,One(gens[1]));
  SetName(G,Concatenation("Ree(",String(q),")"));
  SetDimensionOfMatrixGroup(G,7);
  SetFieldOfMatrixGroup(G,f);
  SetIsFinite(G,true);
  SetSize(G,q^3*(q-1)*(q^3+1));
  if q > 3 then SetIsSimpleGroup(G,true); fi;
  return G;
end );

PermConstructor(ReeGroupCons,[IsPermGroup,IsObject], IsMatrixGroup);

#############################################################################
##
#E  ree.gi . . . . . . . . . . . . . . . . . . . . . . . . . . . .  ends here