File: tee.awk

package info (click to toggle)
gawk 1%3A3.1.5.dfsg-4
  • links: PTS
  • area: main
  • in suites: etch, etch-m68k
  • size: 9,144 kB
  • ctags: 3,545
  • sloc: ansic: 31,602; awk: 4,970; sh: 4,409; yacc: 2,634; makefile: 1,358; sed: 16
file content (39 lines) | stat: -rw-r--r-- 683 bytes parent folder | download | duplicates (4) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
# tee.awk --- tee in awk
#
# Arnold Robbins, arnold@gnu.org, Public Domain
# May 1993
# Revised December 1995

BEGIN    \
{
    for (i = 1; i < ARGC; i++)
        copy[i] = ARGV[i]

    if (ARGV[1] == "-a") {
        append = 1
        delete ARGV[1]
        delete copy[1]
        ARGC--
    }
    if (ARGC < 2) {
        print "usage: tee [-a] file ..." > "/dev/stderr"
        exit 1
    }
    ARGV[1] = "-"
    ARGC = 2
}
{
    # moving the if outside the loop makes it run faster
    if (append)
        for (i in copy)
            print >> copy[i]
    else
        for (i in copy)
            print > copy[i]
    print
}
END    \
{
    for (i in copy)
        close(copy[i])
}