1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
|
------------------------------------------------------------------------------
-- --
-- GNAT COMPILER COMPONENTS --
-- --
-- S Y S T E M . V A L U E _ I --
-- --
-- B o d y --
-- --
-- Copyright (C) 1992-2024, Free Software Foundation, Inc. --
-- --
-- GNAT is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
-- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
-- or FITNESS FOR A PARTICULAR PURPOSE. --
-- --
-- As a special exception under Section 7 of GPL version 3, you are granted --
-- additional permissions described in the GCC Runtime Library Exception, --
-- version 3.1, as published by the Free Software Foundation. --
-- --
-- You should have received a copy of the GNU General Public License and --
-- a copy of the GCC Runtime Library Exception along with this program; --
-- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
-- <http://www.gnu.org/licenses/>. --
-- --
-- GNAT was originally developed by the GNAT team at New York University. --
-- Extensive contributions were provided by Ada Core Technologies Inc. --
-- --
------------------------------------------------------------------------------
with System.Val_Util; use System.Val_Util;
package body System.Value_I is
-- Ghost code, loop invariants and assertions in this unit are meant for
-- analysis only, not for run-time checking, as it would be too costly
-- otherwise. This is enforced by setting the assertion policy to Ignore.
pragma Assertion_Policy (Ghost => Ignore,
Loop_Invariant => Ignore,
Assert => Ignore,
Assert_And_Cut => Ignore,
Subprogram_Variant => Ignore);
------------------
-- Scan_Integer --
------------------
procedure Scan_Integer
(Str : String;
Ptr : not null access Integer;
Max : Integer;
Res : out Int)
is
procedure Prove_Is_Int_Of_Uns
(Minus : Boolean;
Uval : Uns;
Val : Int)
with Ghost,
Pre => Spec.Uns_Is_Valid_Int (Minus, Uval)
and then
(if Minus and then Uval = Uns (Int'Last) + 1 then Val = Int'First
elsif Minus then Val = -(Int (Uval))
else Val = Int (Uval)),
Post => Spec.Is_Int_Of_Uns (Minus, Uval, Val);
-- Unfold the definition of Is_Int_Of_Uns
procedure Prove_Is_Int_Of_Uns
(Minus : Boolean;
Uval : Uns;
Val : Int)
is null;
Uval : Uns;
-- Unsigned result
Minus : Boolean;
-- Set to True if minus sign is present, otherwise to False
Unused_Start : Positive;
-- Saves location of first non-blank (not used in this case)
Non_Blank : constant Positive :=
First_Non_Space_Ghost (Str, Ptr.all, Max)
with Ghost;
Fst_Num : constant Positive :=
(if Str (Non_Blank) in '+' | '-' then Non_Blank + 1
else Non_Blank)
with Ghost;
begin
Scan_Sign (Str, Ptr, Max, Minus, Unused_Start);
if Str (Ptr.all) not in '0' .. '9' then
Ptr.all := Unused_Start;
Bad_Value (Str);
end if;
Scan_Raw_Unsigned (Str, Ptr, Max, Uval);
pragma Assert
(Uval = U_Spec.Scan_Raw_Unsigned_Ghost (Str, Fst_Num, Max));
-- Deal with overflow cases, and also with largest negative number
if Uval > Uns (Int'Last) then
if Minus and then Uval = Uns (Int'Last) + 1 then
Res := Int'First;
else
Bad_Value (Str);
end if;
-- Negative values
elsif Minus then
Res := -(Int (Uval));
-- Positive values
else
Res := Int (Uval);
end if;
Prove_Is_Int_Of_Uns
(Minus => Str (Non_Blank) = '-',
Uval => Uval,
Val => Res);
end Scan_Integer;
-------------------
-- Value_Integer --
-------------------
function Value_Integer (Str : String) return Int is
begin
-- We have to special case Str'Last = Positive'Last because the normal
-- circuit ends up setting P to Str'Last + 1 which is out of bounds. We
-- deal with this by converting to a subtype which fixes the bounds.
if Str'Last = Positive'Last then
declare
subtype NT is String (1 .. Str'Length);
procedure Prove_Is_Integer_Ghost with
Ghost,
Pre => Str'Length < Natural'Last
and then not Only_Space_Ghost (Str, Str'First, Str'Last)
and then Spec.Is_Integer_Ghost (Spec.Slide_To_1 (Str)),
Post => Spec.Is_Integer_Ghost (NT (Str));
procedure Prove_Is_Integer_Ghost is null;
begin
Prove_Is_Integer_Ghost;
return Value_Integer (NT (Str));
end;
-- Normal case where Str'Last < Positive'Last
else
declare
V : Int;
P : aliased Integer := Str'First;
Non_Blank : constant Positive := First_Non_Space_Ghost
(Str, Str'First, Str'Last)
with Ghost;
Fst_Num : constant Positive :=
(if Str (Non_Blank) in '+' | '-' then Non_Blank + 1
else Non_Blank)
with Ghost;
begin
declare
P_Acc : constant not null access Integer := P'Access;
begin
Scan_Integer (Str, P_Acc, Str'Last, V);
end;
pragma Assert
(P = U_Spec.Raw_Unsigned_Last_Ghost
(Str, Fst_Num, Str'Last));
Scan_Trailing_Blanks (Str, P);
pragma Assert
(Spec.Is_Value_Integer_Ghost (Spec.Slide_If_Necessary (Str), V));
return V;
end;
end if;
end Value_Integer;
end System.Value_I;
|
