File: configure.ac.in

package info (click to toggle)
gecode 3.4.0-1
  • links: PTS
  • area: main
  • in suites: squeeze
  • size: 10,136 kB
  • ctags: 16,905
  • sloc: cpp: 124,581; perl: 2,004; makefile: 1,453; sh: 247
file content (329 lines) | stat: -rw-r--r-- 9,014 bytes parent folder | download
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
dnl
dnl Main authors:
dnl   Guido Tack <tack@gecode.org>
dnl
dnl Copyright:
dnl   Guido Tack, 2004, 2005
dnl
dnl Last modified:
dnl   $Date: 2010-06-17 16:07:40 +0200 (Thu, 17 Jun 2010) $
dnl   by $Author: tack $
dnl   $Revision: 11085 $
dnl
dnl This file is part of Gecode, the generic constraint
dnl development environment:
dnl   http://www.gecode.org
dnl
dnl Permission is hereby granted, free of charge, to any person obtaining
dnl a copy of this software and associated documentation files (the
dnl "Software"), to deal in the Software without restriction, including
dnl without limitation the rights to use, copy, modify, merge, publish,
dnl distribute, sublicense, and/or sell copies of the Software, and to
dnl permit persons to whom the Software is furnished to do so, subject to
dnl the following conditions:
dnl
dnl The above copyright notice and this permission notice shall be
dnl included in all copies or substantial portions of the Software.
dnl
dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
dnl EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
dnl NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
dnl LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
dnl OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
dnl WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
dnl
dnl

AC_REVISION([$Id: configure.ac.in 11085 2010-06-17 14:07:40Z tack $])
AC_PREREQ(2.53)
AC_INIT(GECODE, 3.4.0, users@gecode.org)
AC_CONFIG_HEADERS([gecode/support/config.hpp])
AC_CONFIG_SRCDIR(gecode/kernel.hh)

ac_gecode_soversion=23
AC_SUBST(GECODE_SOVERSION, ${ac_gecode_soversion})

# checks for programs

: ${CXXFLAGS=""} dnl we do not want autoconf's default
: ${CFLAGS=""}   dnl we do not want autoconf's default
: ${DLLFLAGS=""}   dnl we do not want autoconf's default
: ${GLDFLAGS=""}   dnl we do not want autoconf's default

dnl include Gecode specific macros
m4_include([gecode.m4])

dnl determine the operating system
AC_GECODE_GET_OS

if test "${CXX}x" = "x" -a "${CC}x" = "x" -a "${host_os}" = "windows"; then
  CC=cl
  CXX=cl
fi

AC_PROG_CXX
AC_PROG_CC
AC_LANG(C++)

AC_PROG_RANLIB

dnl check whether we have certain programs we need
AC_CHECK_PROG(PROG_DIFF, diff, [ok])
 if test "${PROG_DIFF}x" = "x"; then
    AC_MSG_ERROR([In order to compile Gecode, you need the diff tool.])
 fi
AC_CHECK_PROG(PROG_TAR, tar, [ok])
 if test "${PROG_TAR}x" = "x"; then
    AC_MSG_ERROR([In order to compile Gecode, you need the tar tool.])
 fi
AC_CHECK_PROG(PROG_MAKE, make, [ok])
 if test "${PROG_MAKE}x" = "x"; then
    AC_MSG_ERROR([In order to compile Gecode, you need the make tool.])
 fi
AC_CHECK_PROG(PROG_SED, sed, [ok])
 if test "${PROG_SED}x" = "x"; then
    AC_MSG_ERROR([In order to compile Gecode, you need the sed tool.])
 fi
AC_CHECK_PROG(PROG_PERL, perl, [ok])
 if test "${PROG_PERL}x" = "x"; then
    AC_MSG_ERROR([In order to compile Gecode, you need perl.])
 fi

dnl determine which compiler we are using
AC_CXX_COMPILER_VENDOR(ac_gecode_compiler_vendor)
case $ac_gecode_compiler_vendor in
gnu)
  AC_CHECK_GCC_VERSION(4,2)
  ;;
intel)
  ;;
microsoft)
  ;;
*)
  ;;
esac

dnl check whether we want to build universal binaries on Mac OS X
AC_GECODE_UNIVERSAL

dnl check whether the user wants a prefix or suffixes for the libraries
AC_GECODE_USER_SUFFIX

dnl check whether we want to build a framework bundle on Mac OS X
AC_GECODE_FRAMEWORK

dnl check whether we want to build static libraries
AC_GECODE_STATICLIBS

dnl check whether we want to have assertions and debugging options
AC_GECODE_DEBUG

dnl check whether we want to have support for finding memory leaks
AC_GECODE_LEAK_DEBUG

dnl check whether we want audit code in our build
AC_GECODE_AUDIT

dnl check whether we want to produce code suitable for profiling
AC_GECODE_PROFILE

dnl check whether we want to produce code instrumented for gcov
AC_GECODE_GCOV

dnl check platform specific behaviour of arithmetic
AC_GECODE_CHECK_ARITH

dnl check whether we compile with boost support
AC_GECODE_BOOST

dnl checking for thread support
AC_GECODE_THREADS

dnl checking for timer to use
AC_GECODE_TIMER

case $ac_gecode_compiler_vendor in
gnu)
  dnl general compiler flags
  AC_GECODE_UNIX_PATHS
  AC_GECODE_GCC_GENERAL_SWITCHES
  dnl check whether we want to use visibility attributes with gcc
  AC_GECODE_GCC_VISIBILITY

  if test "${enable_debug:-no}" = "no" -a "${enable_gcov:-no}" = "no"; then
    dnl compiler flags for an optimized build
    AC_GECODE_GCC_OPTIMIZED_SWITCHES

    AC_GECODE_CHECK_COMPILERFLAG([-ffast-math])
    AC_GECODE_CHECK_COMPILERFLAG([-mthreads])
  else
    if test "${enable_debug:-no}" = "yes"; then
      dnl compiler flags for a debug build
      AC_GECODE_GCC_DEBUG_SWITCHES
    fi
  fi

  ;;
intel)
  dnl flags for creating dlls
  case $host_os in
     windows*)
       AC_GECODE_MSVC_SWITCHES
       ;;
     *)
       dnl check whether we want to use visibility attributes with gcc
       AC_GECODE_GCC_VISIBILITY
       dnl general compiler flags
       AC_GECODE_UNIX_PATHS
       AC_GECODE_GCC_GENERAL_SWITCHES

       if test "${enable_debug:-no}" = "no"; then
         dnl compiler flags for an optimized build
	 AC_GECODE_GCC_OPTIMIZED_SWITCHES
       else
         dnl compiler flags for a debug build
	 AC_GECODE_GCC_DEBUG_SWITCHES
       fi
       ;;
  esac
  ;;
microsoft)
  AC_GECODE_MSVC_SWITCHES
  ;;
*)
  AC_MSG_ERROR(Gecode currently only supports the GNU and Microsoft compilers.)
  ;;
esac

dnl find out what parts the user wants to build

AC_GECODE_DOC_SWITCHES

dnl ------------------------------------------------------------------
dnl Enabling of non-variable contribs
dnl @CONTRIBS@

dnl ------------------------------------------------------------------
dnl Definition of variable types

dnl Include contributor's vtis
dnl @VTIS@

AC_GECODE_VIS

dnl AC_GECODE_VTI(float,
dnl        [float variable library (requires boost interval library)],
dnl        no,
dnl				[\$(top_srcdir)/contribs/float/var-imp/float.vis]],
dnl				[
dnl	ac_gecode_save_CPPFLAGS="${CPPFLAGS}"
dnl   	CPPFLAGS="${CPPFLAGS}${CPPFLAGS:+ } ${BOOST_CPPFLAGS}"
dnl	AC_CHECK_HEADER([boost/numeric/interval.hpp],[],[
dnl	AC_MSG_ERROR([The boost interval library could not be found.])])
dnl	CPPFLAGS="${ac_gecode_save_CPPFLAGS}"
dnl        ],[])

AC_GECODE_VTI(set,
	[finite set library (implies --enable-int-vars)],
	yes,
	[\$(top_srcdir)/gecode/set/var-imp/set.vis],
	[enable_int_vars="yes";
	 AC_SUBST(LINKSET,[${LINKLIBDIR}${LINKPREFIX}${SET}${DLL_ARCH}${LINKSUFFIX}])
	],
	[
	 AC_SUBST(LINKSET,[])
	]
	)

AC_GECODE_VTI(int, finite domain library, yes,
	[\$(top_srcdir)/gecode/int/var-imp/int.vis \$(top_srcdir)/gecode/int/var-imp/bool.vis],
	[
  	 AC_SUBST(LINKINT,[${LINKLIBDIR}${LINKPREFIX}${INT}${DLL_ARCH}${LINKSUFFIX}])
	],
	[
	 AC_SUBST(LINKINT,[])
	])

dnl End of definition of variable types
dnl ------------------------------------------------------------------

AC_GECODE_QT
AC_GECODE_GIST
AC_GECODE_FLEXBISON
AC_FUNC_MMAP

AC_GECODE_ENABLE_MODULE(driver, yes,
	[build script commandline driver library],
	[enable_search="yes";
         enable_int="yes";
	])

AC_GECODE_ENABLE_MODULE(graph, yes,
	[build graph library],
	[enable_int="yes";
	])

AC_GECODE_ENABLE_MODULE(flatzinc, yes,
  [build FlatZinc interpreter],
  [enable_search="yes";
   enable_driver="yes";
   enable_minimodel="yes";
   enable_graph="yes";
   enable_scheduling="yes";
  ])

AC_GECODE_ENABLE_MODULE(scheduling, yes,
	[build scheduling library],
	[enable_int="yes";
	])

AC_GECODE_ENABLE_MODULE(driver, yes,
	[build script commandline driver library],
	[enable_search="yes";
         enable_int="yes";
	])

AC_GECODE_ENABLE_MODULE(examples, yes,
	[build examples for the enabled variable types],
	[enable_search="yes";
         enable_driver="yes";
         enable_minimodel="yes";
	])

AC_GECODE_ENABLE_MODULE(minimodel, yes,
	[build modeling support library for the enabled variable types])

AC_GECODE_ENABLE_MODULE(search, yes,
        [build search engines])

dnl Configure contributions
AC_CONFIG_SUBDIRS()
dnl @SUBDIRS@

AC_SUBST(VERSION, ${PACKAGE_VERSION})
AC_SUBST(DLLFLAGS, ${DLLFLAGS})
AC_SUBST(GLDFLAGS, ${GLDFLAGS})
AC_SUBST(ALLVIS, ${ac_gecode_vis})

VERSION_DASHES=`echo $PACKAGE_VERSION | sed -e s/\\\\./-/g`
AC_DEFINE_UNQUOTED(GECODE_VERSION,
  "${PACKAGE_VERSION}",
  [Gecode version])
AC_DEFINE_UNQUOTED(GECODE_LIBRARY_VERSION,
  "${VERSION_DASHES}",
  [Gecode version])

ac_gecode_library_architecture=-${VERSION_DASHES}${ac_gecode_library_architecture}
if test   "$ac_gecode_compiler_vendor" == "microsoft" \
       -o \( "$ac_gecode_compiler_vendor" == "intel" \
            -a "$host_os" == "windows" \) ; then
  AC_SUBST(DLL_ARCH,[${ac_gecode_library_architecture}])
else
  AC_SUBST(DLL_ARCH,[""])
fi

AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([doxygen.conf:doxygen/doxygen.conf.in])
AC_CONFIG_FILES([doxygen.hh:doxygen/doxygen.hh.in])
AC_OUTPUT