1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
/*
* This file is part of gitg
*
* Copyright (C) 2019 - Alberto Fanjul
*
* gitg is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* gitg is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with gitg. If not, see <http://www.gnu.org/licenses/>.
*/
namespace Gitg
{
public class FontManager: Object
{
private Settings d_font_settings;
private Settings d_global_settings;
private Gtk.CssProvider css_provider;
public FontManager (Gtk.TextView text_view, bool plugin) {
if (plugin) {
d_font_settings = try_settings(Gitg.Config.APPLICATION_ID + ".preferences.interface");
d_global_settings = try_settings("org.gnome.desktop.interface");
} else {
d_font_settings = new Settings(Gitg.Config.APPLICATION_ID + ".preferences.interface");
d_global_settings = new Settings("org.gnome.desktop.interface");
}
css_provider = new Gtk.CssProvider();
if (d_font_settings != null) {
d_font_settings.changed["use-default-font"].connect((s, k) => {
update_font_settings();
});
d_font_settings.changed["monospace-font-name"].connect((s, k) => {
update_font_settings();
});
}
if (d_global_settings != null) {
d_global_settings.changed["monospace-font-name"].connect((s, k) => {
update_font_settings();
});
}
text_view.get_style_context().add_provider(css_provider, Gtk.STYLE_PROVIDER_PRIORITY_SETTINGS);
update_font_settings();
}
private Settings? try_settings(string schema_id)
{
var source = SettingsSchemaSource.get_default();
if (source == null)
{
return null;
}
if (source.lookup(schema_id, true) != null)
{
return new Settings(schema_id);
}
return null;
}
private void update_font_settings()
{
var fname = d_font_settings.get_string("monospace-font-name");
if (d_font_settings.get_boolean("use-default-font") && d_global_settings != null) {
fname = d_global_settings.get_string("monospace-font-name");
}
var font_desc = Pango.FontDescription.from_string(fname);
var css = "textview { %s }".printf(Dazzle.pango_font_description_to_css(font_desc));
try
{
css_provider.load_from_data(css);
}
catch(Error e)
{
warning("Error applying font: %s", e.message);
}
}
}
}
|
