plugins {
    id 'java'
    id 'maven'
    id 'signing'
}

compileJava {
    options.compilerArgs = ['-proc:none', '-Xlint:all','-Werror','-Xdiags:verbose']
}
compileTestJava {
    options.compilerArgs = ['-proc:none', '-Xlint:all','-Werror','-Xdiags:verbose']
}

repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://artifactory.broadinstitute.org/artifactory/libs-snapshot/" }
}

dependencies {
    compile 'commons-io:commons-io:2.7'
    compile 'org.broadinstitute:gatk-native-bindings:1.0.0'
    compile 'commons-logging:commons-logging:1.2'
    compile 'com.github.samtools:htsjdk:2.21.1'
    testCompile 'org.testng:testng:7.4.0'
}

 wrapper {
    gradleVersion = '5.6'
}

//===================================================================
// build
//===================================================================
final nativeBuildDir = "$buildDir/native"

task cmakeConfig(type: Exec) {
    // hide stdout, but print stderr
    standardOutput = new ByteArrayOutputStream()
    doFirst {mkdir nativeBuildDir}
    workingDir nativeBuildDir
    commandLine 'cmake', '-Wno-dev', projectDir
    inputs.files fileTree(projectDir) {include '**/CMakeLists.txt'}
    outputs.files "$nativeBuildDir/Makefile"
}

task cmakeBuild(type: Exec) {
    def soCompression = file("$nativeBuildDir/libgkl_compression.so")
    // hide stdout, but print stderr
    standardOutput = new ByteArrayOutputStream()
    workingDir nativeBuildDir
    //Run only if we never executed copyNativeLib.
    if (!soCompression.exists()) commandLine 'make', 'install'
    else commandLine 'true'
}

task copyNativeLib(type: Copy) {
    from nativeBuildDir
    into "$buildDir/classes/java/main/com/intel/gkl/native"
    include '*.so'
    include '*.dylib'
}

task buildOnMac(type: Exec) {
    String mac_host = project.ext.properties.mac_host ? project.ext.properties.mac_host : "gkl-mac"
    workingDir '.'
    commandLine 'scripts/buildOnMac.sh', mac_host
    onlyIf {project.hasProperty('mac') || project.hasProperty('mac_host') || gradle.taskGraph.hasTask(uploadArchives)}
}

compileJava.finalizedBy copyNativeLib
copyNativeLib.finalizedBy buildOnMac
copyNativeLib.dependsOn cmakeBuild
cmakeBuild.dependsOn cmakeConfig
test.dependsOn copyNativeLib
//===================================================================
// test
//===================================================================

test {
    def longTestsEnabled = System.getProperty('long_tests')

    def additionalJvmArgs = []

    if (longTestsEnabled != null){
        additionalJvmArgs.add '-Xmx24G'
    }
    useTestNG {
    }
    scanForTestClasses = false
    // propagate system properties to test JVM
    systemProperties = System.getProperties()

    if (project.hasProperty('debug')) {
        jvmArgs('-verbose:jni', '-Xcheck:jni', '-XX:+RestoreMXCSROnJNICalls', *additionalJvmArgs)
    }
    else {
        jvmArgs('-Xcheck:jni', '-XX:+RestoreMXCSROnJNICalls', *additionalJvmArgs)
    }

    testLogging {
        if (!System.env.CI.toString().toBoolean()) {
            events "passed", "skipped", "failed", "standardOut", "standardError"
        }
        afterSuite { desc, result ->
            if (!desc.parent) { // will match the outermost suite
                println "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
            }
        }
    }

    // always rerun tests
    outputs.upToDateWhen { false }
}

//===================================================================
// release
//===================================================================

final isRelease = project.hasProperty("release")
def getDebianVersion() {
    def dpkgStdOut = new ByteArrayOutputStream()
    exec {
        commandLine "dpkg-parsechangelog", "-S", "Version"
        standardOutput = dpkgStdOut
    }
    return dpkgStdOut.toString().trim().replaceFirst(/(-gradle)?([+]dfsg[.0-9]*)?-[^-]+$/, "")
}

version = getDebianVersion()
// version = (isRelease ? gitVersion() : gitVersion() + "-SNAPSHOT").replaceAll(".dirty", "")

group = "com.intel.gkl"

jar {
    baseName = "gkl"
    // include LICENSE file in jar
    from "LICENSE"
    exclude('**/*.so')
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}

signing {
    required { isRelease && gradle.taskGraph.hasTask(uploadArchives) }
    sign configurations.archives
}

install.doFirst { println "Version: $version" }

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

//            repository(url: uri('testMaven'))
            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: project.findProperty("sonatypeUsername"), password: project.findProperty("sonatypePassword"))
                proxy(host: "proxy-us.intel.com", port: 912, type: 'https')
            }

//            snapshotRepository(url: uri('testMavenSnapshot'))
            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: project.findProperty("sonatypeUsername"), password: project.findProperty("sonatypePassword"))
                proxy(host: "proxy-us.intel.com", port: 912, type: 'https')
            }

            pom.project {
                name 'Intel Genomics Kernel Library (GKL)'
                packaging 'jar'
                description 'Genomics compute kernels optimized for Intel Architecture'
                url 'https://github.com/Intel-HLS/GKL'
                scm {
                    connection 'scm:git@github.com:Intel-HLS/GKL.git'
                    developerConnection 'scm:git@github.com:Intel-HLS/GKL.git'
                    url 'scm:git@github.com:Intel-HLS/GKL.git'
                }
                licenses {
                    license {
                        name 'MIT License'
                        url 'https://opensource.org/licenses/MIT'
                        distribution 'repo'
                    }
                    license {
                        name 'BSD 3-Clause'
                        url 'https://opensource.org/licenses/BSD-3-Clause'
                        distribution 'repo'
                    }
                    license {
                        name 'Zlib License'
                        url 'https://opensource.org/licenses/Zlib'
                        distribution 'repo'
                    }

                }
                developers {
                    developer {
                        name = "Keith Mannthey"
                        email = "keith.mannthey@intel.com"
                    }
                    developer {
                        name = "Priya Vaidya"
                        email = "priya.n.vaidya@intel.com"
                    }
                    developer {
                        name = "Marissa Powers"
                        email = "marissa.e.powers@intel.com"
                    }
                }
            }
        }
    }
}