File: check-textrel.awk

package info (click to toggle)
glibc 2.19-18+deb8u7
  • links: PTS, VCS
  • area: main
  • in suites: jessie-backports
  • size: 204,748 kB
  • sloc: ansic: 970,427; asm: 241,207; sh: 10,069; makefile: 8,476; cpp: 3,595; perl: 2,077; pascal: 1,839; awk: 1,704; yacc: 317; sed: 73
file content (41 lines) | stat: -rw-r--r-- 952 bytes parent folder | download | duplicates (26)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
# This awk script expects to get command-line files that are each
# the output of 'readelf -d' on a single shared object.
# It exits successfully (0) if none contained any TEXTREL markers.
# It fails (1) if any did contain a TEXTREL marker.
# It fails (2) if the input did not take the expected form.

BEGIN { result = textrel = sanity = 0 }

function check_one(name) {
  if (!sanity) {
    print name ": *** input did not look like readelf -d output";
    result = 2;
  } else if (textrel) {
    print name ": *** text relocations used";
    result = result ? result : 1;
  } else {
    print name ": OK";
  }

  textrel = sanity = 0;
}

FILENAME != lastfile {
  if (lastfile)
    check_one(lastfile);
  lastfile = FILENAME;
}

$1 == "Tag" && $2 == "Type" { sanity = 1 }
$2 == "(TEXTREL)" { textrel = 1 }
$2 == "(FLAGS)" {
  for (i = 3; i <= NF; ++i) {
    if ($i == "TEXTREL")
      textrel = 1;
  }
}

END {
  check_one(lastfile);
  exit(result);
}