File: soversions.awk

package info (click to toggle)
glibc 2.19-18+deb8u7
  • links: PTS, VCS
  • area: main
  • in suites: jessie-backports
  • size: 204,748 kB
  • sloc: ansic: 970,427; asm: 241,207; sh: 10,069; makefile: 8,476; cpp: 3,595; perl: 2,077; pascal: 1,839; awk: 1,704; yacc: 317; sed: 73
file content (74 lines) | stat: -rw-r--r-- 1,518 bytes parent folder | download | duplicates (10)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
# awk script for shlib-versions.v -> soversions.i; see Makeconfig.

BEGIN {
  config = cpu "-" vendor "-" os;
  configs[config] = "DEFAULT";
}

{ thiscf = $1 }

$2 == "ABI" {
  if ((config ~ thiscf) && !abiname) {
    abiname = $3;
    sub(/@CPU@/, cpu, abiname);
    sub(/@VENDOR@/, vendor, abiname);
    sub(/@OS@/, os, abiname);
  }
  next;
}

# Obey the first matching DEFAULT line.
$2 == "DEFAULT" {
  $1 = $2 = "";
  default_set[++ndefault_set] = thiscf "\n" $0;
  next
}

# Collect all lib lines before emitting anything, so DEFAULT
# can be interspersed.
{
  lib = number = $2;
  sub(/=.*$/, "", lib);
  sub(/^.*=/, "", number);
  if ((thiscf FS lib) in numbers) next;
  numbers[thiscf FS lib] = number;
  order[thiscf FS lib] = ++order_n;
  if (NF > 2) {
    $1 = $2 = "";
    versions[thiscf FS lib] = $0
  }
}

END {
  for (elt in numbers) {
    split(elt, x);
    cf = x[1];
    lib = x[2];
    for (c in configs)
      if (c ~ cf) {
	if (elt in versions)
	  set = versions[elt];
	else {
	  set = (c == config) ? default_setname : "";
	  for (i = 1; i <= ndefault_set; ++i) {
	    split(default_set[i], x, "\n");
	    if (c ~ x[1]) {
	      set = x[2];
	      break;
	    }
	  }
	}
	line = set ? (lib FS numbers[elt] FS set) : (lib FS numbers[elt]);
	if (!((c FS lib) in lineorder) || order[elt] < lineorder[c FS lib]) {
	  lineorder[c FS lib] = order[elt];
	  lines[c FS lib] = configs[c] FS line;
	}
      }
  }
  if (abiname) {
    print "ABI", abiname
  }
  for (c in lines) {
    print lines[c]
  }
}