1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
|
------------------------------------------------------------------------------
-- G P S --
-- --
-- Copyright (C) 2013, AdaCore --
-- --
-- This is free software; you can redistribute it and/or modify it under --
-- terms of the GNU General Public License as published by the Free Soft- --
-- ware Foundation; either version 3, or (at your option) any later ver- --
-- sion. This software is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHAN- --
-- TABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public --
-- License for more details. You should have received a copy of the GNU --
-- General Public License distributed with this software; see file --
-- COPYING3. If not, go to http://www.gnu.org/licenses for a complete copy --
-- of the license. --
------------------------------------------------------------------------------
with GNATCOLL.Projects; use GNATCOLL.Projects;
with GPS.Core_Kernels; use GPS.Core_Kernels;
with GPS.Intl; use GPS.Intl;
with GPS.Scripts.Files;
package body GPS.Scripts.Projects is
type Project_Properties_Record is new Instance_Property_Record with record
Project : Project_Type;
end record;
Project_Class_Name : constant String := "Project";
Name_Cst : aliased constant String := "name";
Recursive_Cst : aliased constant String := "recursive";
Project_Cmd_Parameters : constant Cst_Argument_List :=
(1 => Name_Cst'Access);
procedure Project_Command_Handler
(Data : in out Callback_Data'Class; Command : String);
procedure Set_Data
(Instance : Class_Instance; Project : Project_Type);
--------------------
-- Create_Project --
--------------------
function Create_Project
(Script : access Scripting_Language_Record'Class;
Project : GNATCOLL.Projects.Project_Type)
return Class_Instance
is
Instance : Class_Instance := No_Class_Instance;
begin
if Project /= No_Project then
Instance := New_Instance
(Script, New_Class (Get_Repository (Script), Project_Class_Name));
Set_Data (Instance, Project);
end if;
return Instance;
end Create_Project;
--------------
-- Get_Data --
--------------
function Get_Data
(Data : Callback_Data'Class;
N : Positive)
return GNATCOLL.Projects.Project_Type
is
Class : constant Class_Type := Get_Project_Class (Get_Kernel (Data));
Inst : constant Class_Instance :=
Nth_Arg (Data, N, Class, Allow_Null => True);
Value : Instance_Property;
begin
if Inst = No_Class_Instance then
return No_Project;
end if;
Value := Get_Data (Inst, Project_Class_Name);
if Value = null then
return No_Project;
else
return Project_Properties_Record (Value.all).Project;
end if;
end Get_Data;
-----------------------
-- Get_Project_Class --
-----------------------
function Get_Project_Class
(Kernel : access GPS.Core_Kernels.Core_Kernel_Record'Class)
return Class_Type is
begin
return New_Class (Kernel.Scripts, Project_Class_Name);
end Get_Project_Class;
-----------------------------
-- Project_Command_Handler --
-----------------------------
procedure Project_Command_Handler
(Data : in out Callback_Data'Class; Command : String)
is
Kernel : constant Core_Kernel := Get_Kernel (Data);
Instance : Class_Instance;
Project : Project_Type;
begin
if Command = Constructor_Method then
Name_Parameters (Data, Project_Cmd_Parameters);
Project := Kernel.Registry.Tree.Project_From_Name
(Nth_Arg (Data, 2));
if Project = No_Project then
Set_Error_Msg (Data, -"No such project: " & Nth_Arg (Data, 2));
else
Instance := Nth_Arg (Data, 1, Get_Project_Class (Kernel));
Set_Data (Instance, Project);
end if;
elsif Command = "root" then
Set_Return_Value
(Data, Create_Project (Get_Script (Data),
Kernel.Registry.Tree.Root_Project));
elsif Command = "name" then
Project := Get_Data (Data, 1);
Set_Return_Value (Data, Project.Name);
elsif Command = "file" then
Project := Get_Data (Data, 1);
Set_Return_Value
(Data,
GPS.Scripts.Files.Create_File
(Get_Script (Data), Project_Path (Project)));
elsif Command = "ancestor_deps" then
declare
Iter : Project_Iterator;
P : Project_Type;
begin
Project := Get_Data (Data, 1);
Set_Return_Value_As_List (Data);
Iter := Find_All_Projects_Importing
(Project, Include_Self => True);
loop
P := Current (Iter);
exit when P = No_Project;
Set_Return_Value
(Data, Create_Project (Get_Script (Data), P));
Next (Iter);
end loop;
end;
elsif Command = "dependencies" then
Name_Parameters (Data, (1 => Recursive_Cst'Access));
declare
Recursive : constant Boolean := Nth_Arg (Data, 2, False);
Iter : Project_Iterator;
P : Project_Type;
begin
Project := Get_Data (Data, 1);
Set_Return_Value_As_List (Data);
Iter := Start
(Project, Recursive => True, Direct_Only => not Recursive);
loop
P := Current (Iter);
exit when P = No_Project;
Set_Return_Value
(Data, Create_Project (Get_Script (Data), P));
Next (Iter);
end loop;
end;
end if;
end Project_Command_Handler;
-----------------------
-- Register_Commands --
-----------------------
procedure Register_Commands
(Kernel : access GPS.Core_Kernels.Core_Kernel_Record'Class)
is
begin
Register_Command
(Kernel.Scripts, Constructor_Method,
Minimum_Args => 1,
Maximum_Args => 1,
Class => Get_Project_Class (Kernel),
Handler => Project_Command_Handler'Access);
Register_Command
(Kernel.Scripts, "root",
Class => Get_Project_Class (Kernel),
Static_Method => True,
Handler => Project_Command_Handler'Access);
Register_Command
(Kernel.Scripts, "name",
Class => Get_Project_Class (Kernel),
Handler => Project_Command_Handler'Access);
Register_Command
(Kernel.Scripts, "file",
Class => Get_Project_Class (Kernel),
Handler => Project_Command_Handler'Access);
Register_Command
(Kernel.Scripts, "ancestor_deps",
Class => Get_Project_Class (Kernel),
Handler => Project_Command_Handler'Access);
Register_Command
(Kernel.Scripts, "dependencies",
Class => Get_Project_Class (Kernel),
Minimum_Args => 0,
Maximum_Args => 1,
Handler => Project_Command_Handler'Access);
end Register_Commands;
--------------
-- Set_Data --
--------------
procedure Set_Data
(Instance : Class_Instance; Project : Project_Type) is
begin
if not Is_Subclass (Instance, Project_Class_Name) then
raise Invalid_Data;
end if;
Set_Data
(Instance, Project_Class_Name,
Project_Properties_Record'(Project => Project));
end Set_Data;
end GPS.Scripts.Projects;
|
