1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307
|
AC_INIT(installer/gnome-font-install.c)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(gnome-print,0.37)
AM_ACLOCAL_INCLUDE(macros)
dnl ==========================================
dnl LIBGNOMEPRINT Versioning
dnl ==========================================
dnl libtool versioning
dnl increment if the interface has additions, changes, removals.
GNOMEPRINT_CURRENT=16
dnl increment any time the source changes; set to
dnl 0 if you increment CURRENT
GNOMEPRINT_REVISION=11
dnl increment if any interfaces have been added; set to 0
dnl if any interfaces have been removed. removal has
dnl precedence over adding, so set to 0 if both happened.
GNOMEPRINT_AGE=1
AC_SUBST(GNOMEPRINT_CURRENT)
AC_SUBST(GNOMEPRINT_REVISION)
AC_SUBST(GNOMEPRINT_AGE)
dnl ==========================================
dnl END: LIBGNOMEPRINT Versioning
dnl ==========================================
dnl ==========================================
dnl LIBGPA Versioning
dnl ==========================================
dnl increment if the interface has additions, changes, removals.
GPA_CURRENT=0
dnl increment any time the source changes; set to
dnl 0 if you increment CURRENT
GPA_REVISION=0
dnl increment if any interfaces have been added; set to 0
dnl if any interfaces have been removed. removal has
dnl precedence over adding, so set to 0 if both happened.
GPA_AGE=0
AC_SUBST(GPA_CURRENT)
AC_SUBST(GPA_REVISION)
AC_SUBST(GPA_AGE)
dnl ==========================================
dnl END: LIBGPA Versioning
dnl ==========================================
AM_MAINTAINER_MODE
AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CPP
AM_PROG_LIBTOOL
AM_PATH_GLIB(1.2.8)
ALL_LINGUAS="az bg ca da de el es eu et fi fr gl hr hu it ja ko lt lv nl nn no pl pt pt_BR ro ru sk sl sv tr uk wa zh_CN zh_TW"
GNOME_INIT
GNOME_COMPILE_WARNINGS
GNOME_X_CHECKS
AM_GNOME_GETTEXT
AM_PATH_GDK_PIXBUF(0.7.0, , AC_MSG_ERROR([Need gdk-pixbuf-0.7.0 or later!]))
GNOME_XML_CHECK
dnl =======================
dnl LibXML checking
dnl =======================
AC_MSG_CHECKING(for libxml (gnome-xml) version >= 1.8.8)
vers=`$GNOME_CONFIG --modversion xml | sed -e "s/xml.//" | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
if test "$vers" -ge 1008008; then
AC_MSG_RESULT(found)
else
AC_MSG_ERROR(You need at least libxml 1.8.8 for this version of gnome-print)
fi
dnl =======================
dnl END: LibXML checking
dnl =======================
dnl ==========================================
dnl Checks for zlib library.
dnl ==========================================
_cppflags="${CPPFLAGS}"
_ldflags="${LDFLAGS}"
AC_ARG_WITH(zlib,
[ --with-zlib[=DIR] use libz in DIR],[
if test "$withval" != "no"; then
Z_DIR=$withval
CPPFLAGS="${CPPFLAGS} -I$withval/include"
LDFLAGS="${LDFLAGS} -L$withval/lib"
fi
])
AC_CHECK_HEADERS(zlib.h,
AC_CHECK_LIB(z, gzread,[
AC_DEFINE(HAVE_LIBZ)
if test "x${Z_DIR}" != "x"; then
Z_CFLAGS="-I${Z_DIR}/include"
Z_LIBS="-L${Z_DIR}/lib -lz"
else
Z_LIBS="-lz"
fi]))
AC_SUBST(Z_CFLAGS)
AC_SUBST(Z_LIBS)
dnl ==========================================
dnl END: Checks for zlib library.
dnl ==========================================
dnl ==========================================
dnl Gtk-doc documentation
dnl ==========================================
AC_ARG_WITH(html-dir, [ --with-html-dir=PATH path to installed docs ])
if test "x$with_html_dir" = "x" ; then
HTML_DIR='${datadir}/gtk-doc/html'
else
HTML_DIR=$with_html_dir
fi
AC_SUBST(HTML_DIR)
dnl ==========================================
dnl END: Gtk-doc documentation
dnl ==========================================
dnl ============================================
dnl Check for gnome-print-admin optional support
dnl ============================================
admin=
try_admin=false
have_admin=false
AC_ARG_WITH(admin,
[--{with,without}-admin Compile with gnome-print-admin support (UNSTABLE, EXPERIMENTAL)],
if test x$withval = xno; then
try_admin=false;
else
try_admin=true;
fi
)
AC_MSG_CHECKING(gnome-print-admin support)
if $try_admin; then
AC_MSG_RESULT(yes)
have_admin=true
AC_MSG_CHECKING(for LIBGPA >= 0.0)
AC_MSG_RESULT(found)
AC_DEFINE(ENABLE_LIBGPA)
dnl ==========================================
dnl END: gnome-xml checking
dnl ==========================================
dnl =======================
dnl LibGlade checking
dnl =======================
AC_MSG_CHECKING(for Glade libraries >= 0.13)
if gnome-config --libs libglade > /dev/null 2>&1; then
vers=`gnome-config --modversion libglade | awk 'BEGIN { FS = "."; } { print $1 * 1000 + $2;}'`
if test "$vers" -ge 13; then
AC_MSG_RESULT(found)
else
AC_MSG_ERROR(You need at least libglade 0.13 for this version of gnome-print)
fi
else
AC_MSG_ERROR(Did not find libGlade installed)
fi
dnl =======================
dnl END: LibGlade checking
dnl =======================
PRINT_LIBS="$PRINT_LIBS -lgpa"
AC_DEFINE(LIBGPA)
else
AC_MSG_RESULT(nope)
fi
AM_CONDITIONAL(LIBGPA, $have_admin);
if $have_admin; then
LIBGPA_CFLAGS="`xml-config --cflags`"
LIBGPA_LIBS="-lgpa `xml-config --libs`"
dnl *** NOTE : *****
dnl The gtk dependency will be removed once we move to the new glib
dnl and replace the GtkObjects to GlibObjects
dnl *** end NOTE ****
LIBGPA_CFLAGS="${LIBGPA_CFLAGS} `gtk-config --cflags`"
LIBGPA_LIBS="${LIBGPA_LIBS} `gtk-config --libs`"
LIBGPA_LIBDIR='-L${libdir}'
LIBGPA_INCLUDEDIR='-I${includedir}'
LIBGPA_INCLUDEDIR="$LIBGPA_INCLUDEDIR `xml-config --cflags`"
AC_SUBST(LIBGPA_CFLAGS)
AC_SUBST(LIBGPA_LIBS)
AC_SUBST(LIBGPA_INCLUDEDIR)
AC_SUBST(LIBGPA_LIBDIR)
fi
dnl =================================
dnl END: Check for gnome-print-admin
dnl =================================
dnl =================================
dnl Checking for freetype2
dnl =================================
FREETYPE_LIBS=
FREETYPE_CFLAGS=
AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)
if test "x$FREETYPE_CONFIG" = "xno" ; then
AC_MSG_ERROR(You need FreeType2 for that version of gnome-print)
else
FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`
FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`
fi
dnl =================================
dnl END: Checking for freetype2
dnl =================================
LIBGNOMEPRINT_CFLAGS="$FREETYPE_CFLAGS `$GNOME_CONFIG --cflags gnome gnomeui gdk_pixbuf libart xml`"
LIBGNOMEPRINT_LIBS="`$GNOME_CONFIG --libs gnome gnomeui gdk_pixbuf libart xml` $FREETYPE_LIBS"
AC_SUBST(LIBGNOMEPRINT_CFLAGS)
AC_SUBST(LIBGNOMEPRINT_LIBS)
dnl =================================
dnl Variables for printConf.sh
dnl =================================
PRINT_LIBDIR='-L${libdir}'
PRINT_LIBS="-lgnomeprint $LIBGNOMEPRINT_LIBS"
PRINT_INCLUDEDIR="-I${includedir}/gnome-1.0 $LIBGNOMEPRINT_CFLAGS"
AC_SUBST(PRINT_LIBDIR)
AC_SUBST(PRINT_LIBS)
AC_SUBST(PRINT_INCLUDEDIR)
dnl =================================
dnl END: Variables for creating printConf.sh
dnl =================================
dnl echo "FIXME FIXME FIXME -- this is terribly wrong!"
dnl
dnl The is completely contrary to the autoconf/libtool way of doing
dnl things. If solaris needs that option, then libtool should have
dnl put it there. It failed to do that for whoever caused this test
dnl to end up here, but the cause should be fixed -- not patched
dnl with duct tape like this.
dnl
dnl DISABLED BY Chema. 15-Nov-00
dnl AC_CANONICAL_HOST
dnl case $host in
dnl *-*-solaris*)
dnl PRINT_LIBDIR="${PRINT_LIBDIR} -R${libdir}"
dnl ;;
dnl esac
dnl =====================================
dnl For building tests within gnome-print
dnl =====================================
PRINT_TEST_CFLAGS="$LIBGNOMEPRINT_CFLAGS"
PRINT_TEST_LIBS="$LIBGNOMEPRINT_LIBS"
AC_SUBST(PRINT_TEST_CFLAGS)
AC_SUBST(PRINT_TEST_LIBS)
dnl =====================================
dnl END: For building tests within gnome-print
dnl =====================================
AC_PATH_PROGS(PERL, perl5 perl)
AC_SUBST(PERL)
AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)
AC_OUTPUT([
Makefile
fonts/Makefile
gnome-print.spec
profiles/Makefile
libgpa/Makefile
data/Makefile
data/models/Makefile
data/ppds/Makefile
libgnomeprint/Makefile
po/Makefile.in
intl/Makefile
afms/Makefile
afms/adobe/Makefile
fonts/Makefile
tests/Makefile
installer/Makefile],
[sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])
|