File: Lisp.st

package info (click to toggle)
gnu-smalltalk 3.2.4-2.1
  • links: PTS, VCS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 32,688 kB
  • ctags: 14,104
  • sloc: ansic: 87,424; sh: 22,729; asm: 8,465; perl: 4,513; cpp: 3,548; xml: 1,669; awk: 1,581; yacc: 1,357; makefile: 1,237; lisp: 855; lex: 843; sed: 258; objc: 124
file content (2698 lines) | stat: -rw-r--r-- 65,547 bytes parent folder | download | duplicates (6)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087
2088
2089
2090
2091
2092
2093
2094
2095
2096
2097
2098
2099
2100
2101
2102
2103
2104
2105
2106
2107
2108
2109
2110
2111
2112
2113
2114
2115
2116
2117
2118
2119
2120
2121
2122
2123
2124
2125
2126
2127
2128
2129
2130
2131
2132
2133
2134
2135
2136
2137
2138
2139
2140
2141
2142
2143
2144
2145
2146
2147
2148
2149
2150
2151
2152
2153
2154
2155
2156
2157
2158
2159
2160
2161
2162
2163
2164
2165
2166
2167
2168
2169
2170
2171
2172
2173
2174
2175
2176
2177
2178
2179
2180
2181
2182
2183
2184
2185
2186
2187
2188
2189
2190
2191
2192
2193
2194
2195
2196
2197
2198
2199
2200
2201
2202
2203
2204
2205
2206
2207
2208
2209
2210
2211
2212
2213
2214
2215
2216
2217
2218
2219
2220
2221
2222
2223
2224
2225
2226
2227
2228
2229
2230
2231
2232
2233
2234
2235
2236
2237
2238
2239
2240
2241
2242
2243
2244
2245
2246
2247
2248
2249
2250
2251
2252
2253
2254
2255
2256
2257
2258
2259
2260
2261
2262
2263
2264
2265
2266
2267
2268
2269
2270
2271
2272
2273
2274
2275
2276
2277
2278
2279
2280
2281
2282
2283
2284
2285
2286
2287
2288
2289
2290
2291
2292
2293
2294
2295
2296
2297
2298
2299
2300
2301
2302
2303
2304
2305
2306
2307
2308
2309
2310
2311
2312
2313
2314
2315
2316
2317
2318
2319
2320
2321
2322
2323
2324
2325
2326
2327
2328
2329
2330
2331
2332
2333
2334
2335
2336
2337
2338
2339
2340
2341
2342
2343
2344
2345
2346
2347
2348
2349
2350
2351
2352
2353
2354
2355
2356
2357
2358
2359
2360
2361
2362
2363
2364
2365
2366
2367
2368
2369
2370
2371
2372
2373
2374
2375
2376
2377
2378
2379
2380
2381
2382
2383
2384
2385
2386
2387
2388
2389
2390
2391
2392
2393
2394
2395
2396
2397
2398
2399
2400
2401
2402
2403
2404
2405
2406
2407
2408
2409
2410
2411
2412
2413
2414
2415
2416
2417
2418
2419
2420
2421
2422
2423
2424
2425
2426
2427
2428
2429
2430
2431
2432
2433
2434
2435
2436
2437
2438
2439
2440
2441
2442
2443
2444
2445
2446
2447
2448
2449
2450
2451
2452
2453
2454
2455
2456
2457
2458
2459
2460
2461
2462
2463
2464
2465
2466
2467
2468
2469
2470
2471
2472
2473
2474
2475
2476
2477
2478
2479
2480
2481
2482
2483
2484
2485
2486
2487
2488
2489
2490
2491
2492
2493
2494
2495
2496
2497
2498
2499
2500
2501
2502
2503
2504
2505
2506
2507
2508
2509
2510
2511
2512
2513
2514
2515
2516
2517
2518
2519
2520
2521
2522
2523
2524
2525
2526
2527
2528
2529
2530
2531
2532
2533
2534
2535
2536
2537
2538
2539
2540
2541
2542
2543
2544
2545
2546
2547
2548
2549
2550
2551
2552
2553
2554
2555
2556
2557
2558
2559
2560
2561
2562
2563
2564
2565
2566
2567
2568
2569
2570
2571
2572
2573
2574
2575
2576
2577
2578
2579
2580
2581
2582
2583
2584
2585
2586
2587
2588
2589
2590
2591
2592
2593
2594
2595
2596
2597
2598
2599
2600
2601
2602
2603
2604
2605
2606
2607
2608
2609
2610
2611
2612
2613
2614
2615
2616
2617
2618
2619
2620
2621
2622
2623
2624
2625
2626
2627
2628
2629
2630
2631
2632
2633
2634
2635
2636
2637
2638
2639
2640
2641
2642
2643
2644
2645
2646
2647
2648
2649
2650
2651
2652
2653
2654
2655
2656
2657
2658
2659
2660
2661
2662
2663
2664
2665
2666
2667
2668
2669
2670
2671
2672
2673
2674
2675
2676
2677
2678
2679
2680
2681
2682
2683
2684
2685
2686
2687
2688
2689
2690
2691
2692
2693
2694
2695
2696
2697
2698
"======================================================================
|
|   Lisp interpreter written in Smalltalk
|
|
 ======================================================================"


"======================================================================
|
| Written by Aoki Atsushi and Nishihara Satoshi.
| Modified by Paolo Bonzini (removed GUI and compiler for subset of Smalltalk).
|
| This file is part of GNU Smalltalk.
|
| GNU Smalltalk is free software; you can redistribute it and/or modify it
| under the terms of the GNU General Public License as published by the Free
| Software Foundation; either version 2, or (at your option) any later version.
| 
| GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
| ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
| FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
| details.
| 
| You should have received a copy of the GNU General Public License along with
| GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
| Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.  
|
 ======================================================================"

SequenceableCollection subclass:  #LispList
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Examples-Lisp'!

LispList subclass:  #LispCons
	instanceVariableNames: 'head tail '
	classVariableNames: 'VerticalLevel HorizontalLevel '
	poolDictionaries: ''
	category: 'Examples-Lisp'!

LispList subclass:  #LispNil
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Examples-Lisp'!

Object subclass:  #LispScanner
	instanceVariableNames: 'source mark token tokenType failBlock '
	classVariableNames: 'ScanningTable '
	poolDictionaries: ''
	category: 'Examples-Lisp'!

LispScanner subclass:  #LispParser
	instanceVariableNames: 'prevMark prevToken prevTokenType '
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Examples-Lisp'!

Object subclass:  #LispTable
	instanceVariableNames: 'properties '
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Examples-Lisp'!

Object subclass:  #LispInterpreter
	instanceVariableNames: 'lispTable bindStack failBlock textValue textCollector '
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Examples-Lisp'!



!LispList class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispList class methodsFor: 'instance creation'!

cell
    ^self subclassResponsibility!

head: headObject 
    ^self subclassResponsibility!

head: headObject tail: tailObject 
    ^self subclassResponsibility!

list: anArray 
    "LispCons list: #(1 2 3 4)"

    | size list |
    size := anArray size.
    list := self null.
    size
	to: 1
	by: -1
	do: [:i | list := self head: (anArray at: i)
			tail: list].
    ^list!

new: anInteger 
    "LispCons new: 5"

    | newList |
    newList := self null.
    anInteger timesRepeat: [newList := self head: self null tail: newList].
    ^newList!

null
    ^self subclassResponsibility!

with: anObject 
    "LispCons with: 1"

    ^self head: anObject!

with: firstObject with: secondObject 
    "LispCons with: 1 with: 2"

    ^self head: firstObject tail: (self with: secondObject)!

with: firstObject with: secondObject with: thirdObject 
    "LispCons with: 1 with: 2 with: 3"

    ^self head: firstObject tail: (self with: secondObject with: thirdObject)!

with: firstObject with: secondObject with: thirdObject with: fourthObject 
    "LispCons with: 1 with: 2 with: 3 with: 4"

    ^self head: firstObject tail: (self
	    with: secondObject
	    with: thirdObject
	    with: fourthObject)! !

!LispList methodsFor: 'accessing'!

at: indexInteger put: anObject 
    ^self subscriptOutOfBoundsError: indexInteger!

size
    | tally |
    tally := 0.
    self do: [:each | tally := tally + 1].
    ^tally! !

!LispList methodsFor: 'private'!

subscriptOutOfBoundsError: index 
    ^self error: 'subscript out of bounds: ' , index printString! !

!LispList methodsFor: 'testing'!

isCons
    ^self null not!

null
    ^false! !



!LispCons class methodsFor: 'class initialization'!

initialize
    "LispCons initialize."

    HorizontalLevel := VerticalLevel := nil! !

!LispCons class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispCons class methodsFor: 'examples'!

example1
    "LispCons example1."

    | list |
    list := LispCons list: #(1 2 3 4 5 6 7 8 9 10 ).
    Transcript nl; show: list printString.
    ^list!

example2
    "LispCons example2."

    | null list |
    null := LispCons null.
    list := LispCons list: #(1 2 ).
    list := LispCons head: list tail: null.
    list := LispCons head: list tail: null.
    Transcript nl; show: list printString.
    ^list!

example3
    "LispCons example3."

    | x y z |
    x := LispCons list: #(1 2 3 ).
    y := LispCons list: #(4 5 6 ).
    z := LispCons list: #(1 2 3 4 5 6 ).
    Transcript nl; show: '(setq x ''(1 2 3)) => ' , x printString.
    Transcript nl; show: '(setq y ''(4 5 6)) => ' , y printString.
    Transcript nl; show: '(setq z ''(1 2 3 4 5 6)) => ' , z printString.
    Transcript nl; show: '(append x y) => ' , (x append: y) printString.
    Transcript nl; show: '(length z) => ' , z length printString.
    Transcript nl; show: '(member 3 z) => ' , (z member: 3) printString.
    Transcript nl; show: '(nth 4 z) => ' , (z nth: 4) printString.
    ^z!

example4
    "LispCons example4."

    | list |
    list := LispCons list: #(1 2 ).
    list := LispCons head: list tail: (LispCons list: #(3 4 )).
    list := LispCons head: list tail: (LispCons list: #(5 6 )).
    Transcript nl; show: list saveString.
    ^list!

example5
    "LispCons example5."

    | list |
    list := LispCons loadFrom: '
	    (PetriNet Aoki
		(Place p1 p2 p3 p4 p5)
		(Transition t1 t2 t3 t4 t5)
		(InputFunction
		    (t1 p1 p2 p3 p4 p5)
		    (t2 . p4)
		    (t3 . p5))
		(OutputFunction
		    (t1 p1 p2 p3 p4 p5)
		    (t2 . p4)
		    (t3 . p5))
		(Marking {#(1 2 3 4 5)})))'.
    Transcript nl; show: list saveString.
    ^list!

example6
    "LispCons example6."

    | list |
    list := LispCons loadFrom: '(aaa bbb ccc)'.
    Transcript nl; show: list saveString.
    ^list!

example7
    "LispCons example7."

    | list |
    list := LispCons loadFrom: ' `(`(1 2 `3) . `4 ) '.
    Transcript nl; show: list saveString.
    ^list! !

!LispCons class methodsFor: 'instance creation'!

cell
    ^super new head: self null tail: self null!

head: headObject 
    ^super new head: headObject tail: self null!

head: headObject tail: tailObject 
    ^super new head: headObject tail: tailObject!

list: anArray 
    | size list |
    size := anArray size.
    list := self null.
    size
	to: 1
	by: -1
	do: [:i | list := self head: (anArray at: i)
			tail: list].
    ^list!

loadFrom: aStream 
    "by nishis, 1998/04/19 07:51"

    | list |
    list := LispParser parse: aStream.
    ^list!

new
    ^self cell!

null
    ^LispNil null! !

!LispCons class methodsFor: 'level accessing'!

horizontalLevel
    HorizontalLevel isNil ifTrue: [HorizontalLevel := 50].
    ^HorizontalLevel!

horizontalLevel: anInteger 
    HorizontalLevel := anInteger!

verticalLevel
    VerticalLevel isNil ifTrue: [VerticalLevel := 10].
    ^VerticalLevel!

verticalLevel: anInteger 
    VerticalLevel := anInteger! !

!LispCons class methodsFor: 'utilities'!

classHierarchy: aClass 
    "LispCons classHierarchy: Number."

    | theClass list |
    aClass isMeta
	ifTrue: [theClass := aClass soleInstance]
	ifFalse: [theClass := aClass].
    list := self subclassHierarchy: theClass.
    (theClass allSuperclasses select: [:each | each isMeta not])
	do: [:each | list := self head: each name tail: (self head: list tail: self null)].
    ^list!

subclassHierarchy: aClass 
    "LispCons subclassHierarchy: Number."

    | theClass list collection sub |
    aClass isMeta
	ifTrue: [theClass := aClass soleInstance]
	ifFalse: [theClass := aClass].
    list := self null.
    theClass subclasses isEmpty
	ifFalse: 
	    [collection := SortedCollection sortBlock: [:x :y | x name > y name].
	    collection addAll: (theClass subclasses select: [:each | each isMeta not]).
	    collection
		do: 
		    [:each | 
		    sub := self subclassHierarchy: each.
		    list := self head: sub tail: list]].
    ^self head: theClass name tail: list!

superclassHierarchy: aClass 
    "LispCons superclassHierarchy: Number."

    | theClass list |
    aClass isMeta
	ifTrue: [theClass := aClass soleInstance]
	ifFalse: [theClass := aClass].
    list := self head: theClass name tail: self null.
    (theClass allSuperclasses select: [:each | each isMeta not])
	do: [:each | list := self head: each name tail: (self head: list tail: self null)].
    ^list! !

!LispCons methodsFor: 'accessing'!

at: indexInteger
    | count |
    count := 1.
    self
	mapcdr: 
	    [:cdr | 
	    indexInteger = count ifTrue: [^cdr head].
	    count := count + 1].
    ^self subscriptOutOfBoundsError: indexInteger!

at: indexInteger put: anObject 
    | count |
    count := 1.
    self
	mapcdr: 
	    [:cdr | 
	    indexInteger = count ifTrue: [^cdr head: anObject].
	    count := count + 1].
    ^self subscriptOutOfBoundsError: indexInteger!

head
    ^head!

head: anObject 
    ^head := anObject!

head: headObject tail: tailObject 
    self head: headObject.
    self tail: tailObject!

tail
    ^tail!

tail: anObject 
    ^tail := anObject! !

!LispCons methodsFor: 'adding'!

add: newObject 
    ^self nconc: (self class head: newObject tail: self class null)! !

!LispCons methodsFor: 'enumerating'!

collect: aBlock 
    | list result |
    list := self.
    result := self class null.
    [list isKindOf: self class]
	whileTrue: 
	    [result := self class head: (aBlock value: list head)
			tail: result.
	    list := list tail].
    ^result reverse!

do: aBlock 
    | list |
    list := self.
    [list isKindOf: self class]
	whileTrue: 
	    [aBlock value: list head.
	    list := list tail]! !

!LispCons methodsFor: 'functions'!

append: list 
    (tail isKindOf: self class)
	ifFalse: [^self class head: head tail: list].
    ^self class head: head tail: (tail append: list)!

last
    | list |
    list := self class head: nil tail: self.
    self do: [:each | list := list tail].
    ^list!

length
    | count |
    count := 0.
    self do: [:each | count := count + 1].
    ^count!

mapcdr: aBlock 
    | list |
    list := self.
    [list isKindOf: self class]
	whileTrue: 
	    [aBlock value: list.
	    list := list tail]!

member: anObject 
    | list |
    list := self.
    self do: 
	[:each | 
	each = anObject ifTrue: [^list].
	list := list tail].
    ^self species null!

memq: anObject 
    | list |
    list := self.
    self do: 
	[:each | 
	each == anObject ifTrue: [^list].
	list := list tail].
    ^self species null!

nconc: list 
    self last rplacd: list!

nth: nth 
    | count list |
    nth <= 0 ifTrue: [^self species null].
    count := 1.
    list := self.
    list do: 
	[:each | 
	count >= nth ifTrue: [^each].
	count := count + 1].
    ^self species null!

reverse
    | list |
    list := self class null.
    self do: [:each | list := self class head: each tail: list].
    ^list!

rplaca: anObject 
    self head: anObject!

rplacd: anObject 
    self tail: anObject! !

!LispCons methodsFor: 'pretty printing'!

ppOn: aStream 
    self
	ppOn: aStream
	list: self
	position: 0.
    aStream nl!

ppOn: aStream list: list position: position 
    (list isKindOf: self class)
	ifFalse: [^self ppOn: aStream object: list].
    (list head isKindOf: self class) not
	ifTrue: 
	    [aStream nextPutAll: '('.
	    self ppOn: aStream object: list head.
	    (list tail isKindOf: LispList)
		ifTrue: [self
			ppOn: aStream
			tail: list tail
			position: position + 1]
		ifFalse: 
		    [aStream nextPutAll: ' . '.
		    self ppOn: aStream object: list tail].
	    aStream nextPutAll: ')']
	ifFalse: 
	    [aStream nextPutAll: '('.
	    self
		ppOn: aStream
		list: list head
		position: position + 1.
	    (list tail isKindOf: self class)
		ifTrue: [(list tail head isKindOf: self class)
			ifTrue: 
			    [aStream nl.
			    self ppOn: aStream spaceAndTab: position.
			    self
				ppOn: aStream
				tail: list tail
				position: position]
			ifFalse: 
			    [self ppOn: aStream space: 1.
			    self
				ppOn: aStream
				tail: list tail
				position: position + 1]]
		ifFalse: [(list tail isKindOf: LispList)
			ifFalse: 
			    [aStream nextPutAll: ' . '.
			    self ppOn: aStream object: list tail]].
	    aStream nextPutAll: ')']!

ppOn: aStream object: anObject 
    (anObject isKindOf: Symbol)
	ifTrue: [^aStream nextPutAll: anObject asString].
    (anObject isKindOf: String)
	ifTrue: 
	    [aStream nextPutAll: '"'.
	    anObject
		do: 
		    [:char | 
		    char = $" ifTrue: [aStream nextPut: $"].
		    aStream nextPut: char].
	    ^aStream nextPutAll: '"'].
    (anObject isKindOf: Number)
	ifTrue: [^anObject storeOn: aStream].
    (anObject isMemberOf: LispNil)
	ifTrue: [^aStream nextPutAll: 'nil'].
    aStream nextPutAll: '{'.
    aStream nextPutAll: (anObject printString contractTo: 80).
    aStream nextPutAll: '}'!

ppOn: aStream space: anInteger 
    anInteger timesRepeat: [aStream nextPut: Character space]!

ppOn: aStream spaceAndTab: anInteger 
    | tabs spaces |
    tabs := anInteger // self tabStop.
    spaces := anInteger \\ self tabStop.
    tabs * (self tabStop // 4) timesRepeat: [aStream tab].
    spaces timesRepeat: [aStream space]!

ppOn: aStream tail: list position: position 
    list null ifTrue: [^self].
    (list tail isKindOf: LispList)
	ifTrue: [list tail null
		ifTrue: 
		    [self ppOn: aStream space: 1.
		    self
			ppOn: aStream
			list: list head
			position: position + 1]
		ifFalse: 
		    [self ppOn: aStream space: 1.
		    self
			ppOn: aStream
			list: list head
			position: position + 1.
		    aStream nl.
		    self ppOn: aStream spaceAndTab: position.
		    self
			ppOn: aStream
			tail: list tail
			position: position]]
	ifFalse: 
	    [self ppOn: aStream space: 1.
	    self
		ppOn: aStream
		list: list head
		position: position + 1.
	    aStream nextPutAll: ' . '.
	    self ppOn: aStream object: list tail]!

ppString
    | stream |
    stream := WriteStream on: (String new: 20).
    self ppOn: stream.
    ^stream contents! !

!LispCons methodsFor: 'printing'!

printOn: aStream 
    self printOn: aStream level: 0!

printOn: aStream level: level 
    | verticalLevel |
    verticalLevel := self class verticalLevel.
    (verticalLevel ~= 0 and: [level >= verticalLevel])
	ifTrue: 
	    [aStream nextPutAll: '( ... )'.
	    ^self].
    self null ifTrue: [^super printOn: aStream].
    aStream nextPutAll: '('.
    (head isKindOf: self class)
	ifTrue: [head printOn: aStream level: level + 1]
	ifFalse: [self printOn: aStream object: head].
    (tail isKindOf: LispList)
	ifTrue: [self
		printOn: aStream
		tail: tail
		level: level]
	ifFalse: 
	    [aStream nextPutAll: ' . '.
	    self printOn: aStream object: tail.
	    ^aStream nextPutAll: ')']!

printOn: aStream object: anObject 
    (anObject isKindOf: Symbol)
	ifTrue: [^aStream nextPutAll: anObject asString].
    (anObject isKindOf: String)
	ifTrue: 
	    [aStream nextPutAll: '"'.
	    anObject
		do: 
		    [:char | 
		    char = $" ifTrue: [aStream nextPut: $"].
		    aStream nextPut: char].
	    ^aStream nextPutAll: '"'].
    (anObject isKindOf: Number)
	ifTrue: [^anObject storeOn: aStream].
    (anObject isMemberOf: LispNil)
	ifTrue: [^aStream nextPutAll: 'nil'].
    aStream nextPutAll: '{'.
    aStream nextPutAll: (anObject printString contractTo: 80).
    aStream nextPutAll: '}'!

printOn: aStream tail: cdr level: level 
    | tailPart count horizontalLevel |
    cdr null ifTrue: [^aStream nextPutAll: ')'].
    tailPart := cdr.
    count := 1.
    horizontalLevel := self class horizontalLevel.
    tailPart do: 
	[:each | 
	(horizontalLevel ~= 0 and: [count >= horizontalLevel])
	    ifTrue: 
		[aStream nextPutAll: ' ... )'.
		^self].
	aStream nextPutAll: ' '.
	(each isKindOf: self class)
	    ifTrue: [tailPart head printOn: aStream level: level + 1]
	    ifFalse: [self printOn: aStream object: each].
	tailPart := tailPart tail.
	count := count + 1].
    (tailPart isKindOf: LispList)
	ifTrue: [aStream nextPutAll: ')']
	ifFalse: 
	    [aStream nextPutAll: ' . '.
	    self printOn: aStream object: tailPart.
	    aStream nextPutAll: ')']! !

!LispCons methodsFor: 'private'!

tabStop
    ^8! !

!LispCons methodsFor: 'saving'!

saveOn: aStream 
    self
	saveOn: aStream
	list: self
	position: 0.
    aStream nl!

saveOn: aStream list: list position: position 
    | location length |
    (list isKindOf: self class)
	ifFalse: [^self saveOn: aStream object: list].
    (list head isKindOf: self class) not
	ifTrue: 
	    [aStream nextPutAll: '('.
	    location := aStream position.
	    self saveOn: aStream object: list head.
	    (list tail isKindOf: LispList)
		ifTrue: 
		    [length := aStream position - location min: 40.
		    length := 0.
		    self
			saveOn: aStream
			tail: list tail
			position: position + 1 + length]
		ifFalse: 
		    [aStream nextPutAll: ' . '.
		    self saveOn: aStream object: list tail].
	    aStream nextPutAll: ')']
	ifFalse: 
	    [aStream nextPutAll: '('.
	    self
		saveOn: aStream
		list: list head
		position: position + 1.
	    (list tail isKindOf: self class)
		ifTrue: [(list tail head isKindOf: self class)
			ifTrue: 
			    [aStream nl.
			    self saveOn: aStream spaceAndTab: position.
			    self
				saveOn: aStream
				tail: list tail
				position: position]
			ifFalse: 
			    [self saveOn: aStream space: 1.
			    self
				saveOn: aStream
				tail: list tail
				position: position + 1]]
		ifFalse: [(list tail isKindOf: LispList)
			ifFalse: 
			    [aStream nextPutAll: ' . '.
			    self saveOn: aStream object: list tail]].
	    aStream nextPutAll: ')']!

saveOn: aStream object: anObject 
    | string |
    (anObject isKindOf: Symbol)
	ifTrue: [^aStream nextPutAll: anObject asString].
    (anObject isKindOf: String)
	ifTrue: 
	    [aStream nextPutAll: '"'.
	    anObject
		do: 
		    [:char | 
		    char = $" ifTrue: [aStream nextPut: $"].
		    aStream nextPut: char].
	    ^aStream nextPutAll: '"'].
    (anObject isKindOf: Integer)
	ifTrue: [^anObject storeOn: aStream].
    (anObject isKindOf: Float)
	ifTrue: [^anObject storeOn: aStream].
    "(anObject isKindOf: Double)
	ifTrue: [^anObject storeOn: aStream]."
    (anObject isMemberOf: LispNil)
	ifTrue: [^aStream nextPutAll: 'nil'].
    aStream nextPutAll: '{'.
    ((anObject isKindOf: Point)
	or: [anObject isKindOf: Rectangle])
	ifTrue: [string := anObject printString]
	ifFalse: [string := anObject storeString].
    aStream nextPutAll: string.
    aStream nextPutAll: '}'!

saveOn: aStream space: anInteger 
    anInteger timesRepeat: [aStream nextPut: Character space]!

saveOn: aStream spaceAndTab: anInteger 
    | tabs spaces |
    tabs := anInteger // self tabStop.
    spaces := anInteger \\ self tabStop.
    tabs timesRepeat: [aStream tab].
    spaces timesRepeat: [aStream space]!

saveOn: aStream tail: list position: position 
    list null ifTrue: [^self].
    (list tail isKindOf: LispList)
	ifTrue: [list tail null
		ifTrue: 
		    [self saveOn: aStream space: 1.
		    self
			saveOn: aStream
			list: list head
			position: position + 1]
		ifFalse: 
		    [self saveOn: aStream space: 1.
		    self
			saveOn: aStream
			list: list head
			position: position + 1.
		    aStream nl.
		    self saveOn: aStream spaceAndTab: position.
		    self
			saveOn: aStream
			tail: list tail
			position: position]]
	ifFalse: 
	    [self saveOn: aStream space: 1.
	    self
		saveOn: aStream
		list: list head
		position: position + 1.
	    aStream nextPutAll: ' . '.
	    self saveOn: aStream object: list tail]!

saveString
    | stream |
    stream := WriteStream on: (String new: 20).
    self saveOn: stream.
    ^stream contents! !

!LispCons methodsFor: 'testing'!

= anObject 
    (anObject isKindOf: self class)
	ifFalse: [^false].
    self head = anObject head ifTrue: [^self tail = anObject tail].
    ^false! !


LispCons initialize!

LispNil class instanceVariableNames: 'null '!

!LispNil class methodsFor: 'class initialization'!

initialize
    "LispNil initialize."

    self null! !

!LispNil class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispNil class methodsFor: 'instance creation'!

cell
    ^LispCons cell!

head: headObject 
    ^self shouldNotImplement!

head: headObject tail: tailObject 
    ^self shouldNotImplement!

new
    ^self null!

null
    null isNil ifTrue: [null := super new].
    ^null! !

!LispNil methodsFor: 'accessing'!

head
    ^self!

tail
    ^self! !

!LispNil methodsFor: 'adding'!

add: newObject 
    ^self shouldNotImplement! !

!LispNil methodsFor: 'enumerating'!

do: aBlock 
    ^self! !

!LispNil methodsFor: 'functions'!

append: list 
    ^list!

length
    ^0!

mapcdr: aBlock 
    ^self!

member: anObject 
    ^self!

nconc: list 
    ^list!

nth: nth 
    ^self!

reverse
    ^self! !

!LispNil methodsFor: 'pretty printing'!

ppOn: aStream 
    aStream nextPutAll: 'nil'.
    aStream nl!

ppString
    ^'nil\' withCRs! !

!LispNil methodsFor: 'printing'!

printOn: aStream 
    aStream nextPutAll: 'nil'! !

!LispNil methodsFor: 'saving'!

saveOn: aStream 
    aStream nextPutAll: 'nil'!

saveString
    ^'nil'! !

!LispNil methodsFor: 'testing'!

null
    ^true! !


LispNil initialize!

!LispScanner class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispScanner class methodsFor: 'initialize-release'!

initialize
    | newTable |
    newTable := Array new: 256 withAll: #xBinary.
    newTable atAll: #(9 10 11 12 13 32) put: #xDelimiter.
    newTable atAll: ($0 asInteger to: $9 asInteger) put: #xDigit.
    newTable atAll: ($A asInteger to: $Z asInteger) put: #xSymbol.
    newTable atAll: ($a asInteger to: $z asInteger) put: #xSymbol.
    128 to: 256 do: [:i | newTable at: i put: #xSymbol].
    newTable at: $' asInteger put: #quote.
    newTable at: $" asInteger put: #xDoubleQuote.
    newTable at: ${ asInteger put: #xBrace.
    newTable at: $+ asInteger put: #xSign.
    newTable at: $- asInteger put: #xSign.
    newTable at: $< asInteger put: #xSymbol.
    newTable at: $> asInteger put: #xSymbol.
    newTable at: $= asInteger put: #xSymbol.
    newTable at: $~ asInteger put: #xSymbol.
    newTable at: $* asInteger put: #xSymbol.
    newTable at: $/ asInteger put: #xSymbol.
    newTable at: $_ asInteger put: #xSymbol.
    newTable at: $: asInteger put: #xSymbol.
    newTable at: $, asInteger put: #xSymbol.
    newTable at: $\ asInteger put: #xSymbol.
    newTable at: $% asInteger put: #xComment.
    newTable at: $( asInteger put: #leftParenthesis.
    newTable at: $) asInteger put: #rightParenthesis.
    newTable at: $[ asInteger put: #leftParenthesis.
    newTable at: $] asInteger put: #rightParenthesis.
    newTable at: $. asInteger put: #period.
    newTable at: $` asInteger put: #quote.
    newTable at: $! asInteger put: #eof.
    ScanningTable := newTable! !

!LispScanner class methodsFor: 'instance creation'!

new
    ^(super new) initScanner; yourself! !

!LispScanner methodsFor: 'initialize-release'!

initScanner
    failBlock := 
	[:errorMessage || label string |
	    label := errorMessage , ' near ' , (token printString contractTo: 10).
	    string := source upToEnd.
	    string isEmpty
		ifTrue: [string := '--> end of file']
		ifFalse: [string := '--> ' , (string contractTo: 30)].
	    self error: 'scan error   ', label, Character nl asString, string].
    !

on: inputStream 
    source := inputStream.
    mark := source position! !

!LispScanner methodsFor: 'private'!

nextChar
    | char |
    source atEnd ifTrue: [ ^$! ].
    char := source next.
    char = Character cr
	ifTrue: 
	    [char := Character nl. source peekFor: char].
    ^char!

peekChar
    | char |
    char := source peek.
    char = Character cr ifTrue: [char := Character nl].
    char isNil ifTrue: [char := $! ].
    ^char!

unNextChar
    source skip: -1! !

!LispScanner methodsFor: 'reading'!

numberFrom: aStream 
    ^Number readFrom: aStream!

objectFrom: aStream 
    "POSSIBLE PORTABILITY PROBLEM HERE!"
    | buffer char |
    buffer := WriteStream on: (String new: 20).
    char := aStream next.
    
    [char := aStream next.
    char = $}]
	whileFalse: 
	    [char == nil ifTrue: [^failBlock value: 'Syntax error unmatched ${'].
	    buffer nextPut: char].
    ^Behavior
	evaluate: buffer contents
	to: nil
	ifError: []!

stringFrom: aStream 
    | buffer char string |
    buffer := WriteStream on: (String new: 20).
    char := aStream next.
    char = $" ifTrue: [
	[char := aStream peek.
	char ~~ nil]
	    whileTrue: 
		[char = $"
		    ifTrue: 
			[aStream next.
			char := aStream peek.
			char = $" ifFalse: [^String fromString: buffer contents]].
		buffer nextPut: aStream next]].
    string := aStream upToEnd.
    string size > 100 ifTrue: [string := string copyFrom: 1 to: 100].
    ^failBlock value: 'Syntax error unmatched $'''!

symbolFrom: aStream 
    | buffer char type |
    buffer := WriteStream on: (String new: 20).
    char := aStream peek.
    [char notNil and: [(type := self tableAt: char) == #xSymbol or: [type == #xDigit or: [type == #xSign]]]]
	whileTrue: 
	    [buffer nextPut: aStream next.
	    char := aStream peek].
    buffer contents = 'nil' ifTrue: [^LispNil null].
    ^Symbol intern: buffer contents! !

!LispScanner methodsFor: 'scanning'!

multiChar: type 
    self perform: type!

nextToken
    | char |
    mark := source position.
    char := self peekChar.
    tokenType := self tableAt: char.
    [tokenType == #xDelimiter]
	whileTrue: 
	    [self nextChar.
	    char := self peekChar.
	    tokenType := self tableAt: char].
    (tokenType at: 1) = $x
	ifTrue: [self multiChar: tokenType]
	ifFalse: [self singleChar: tokenType].
    ^token!

singleChar: type 
    self nextChar.
    token := type!

tableAt: char
    | index |
    index := char asInteger.
    ^index = 0
	ifFalse: [ScanningTable at: index]
	ifTrue: [#xBinary]!

unNextToken
    source position: mark! !

!LispScanner methodsFor: 'x'!

xBinary
    ^failBlock value: 'Syntax error ' , source peek printString!

xBrace
    tokenType := #object.
    token := self objectFrom: source!

xComment
    | char |
    [(char := self nextChar) = Character nl]
	whileFalse: [char == nil ifTrue: [^self nextToken]].
    ^self nextToken!

xDigit
    tokenType := #number.
    token := self numberFrom: source!

xDoubleQuote
    tokenType := #string.
    token := self stringFrom: source!

xSign
    | char sign |
    sign := self nextChar.
    char := self peekChar.
    char isDigit
	ifTrue: 
	    [tokenType := #number.
	    token := self numberFrom: source.
	    sign == $- ifTrue: [token := token negated]]
	ifFalse: 
	    [self unNextChar.
	    tokenType := #symbol.
	    token := self symbolFrom: source]!

xSymbol
    tokenType := #symbol.
    token := self symbolFrom: source! !


LispScanner initialize!

!LispParser class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispParser class methodsFor: 'examples'!

example1
    "LispParser example1."

    | list |
    list := LispParser parse: '(1 2 3 4 (5 6 7 8 9) 10)'.
    ^list!

example2
    "LispParser example2."

    | list |
    list := LispParser parse: '
	    (10 (1 2)
	     20 (3 4 . 100)
	     30 (5 6) . 200)
    '.
    ^list!

example3
    "LispParser example3."

    | list |
    list := LispParser parse: '
	    (PetriNet Aoki
		(Place
		    (p1 . {100@100})
		    (p2 . {200@200})
		    (p3 . {300@300})
		    (p4 . {400@400})
		    (p5 . {500@500}))
		(Transition
		    (t1 . {100@100})
		    (t2 . {200@200})
		    (t3 . {300@300})
		    (t4 . {400@400})
		    (t5 . {500@500}))
		(InputFunction
		    (t1 p1 p2 p3 p4 p5)
		    (t2 . p4)
		    (t3 . p5))
		(OutputFunction
		    (t1 p1 p2 p3 p4 p5)
		    (t2 . p4)
		    (t3 . p5))
		(Marking {#(1 2 3 4 5)}))'.
    Transcript nl; show: list saveString.
    list := LispParser parse: list saveString.
    ^list!

example4
    "LispParser example4."

    | list |
    list := LispParser parse: '(1 2 3 4 (5 6 7 ~ 8 9) 10)'.
    ^list!

example5
    "LispParser example5."

    | list |
    list := LispParser parse: '(1 2 3 4 (5 6 7 {100@100 8 9) 10)'.    "error"
    ^list!

example6
    "LispParser example6."

    | list |
    list := LispParser parse: '(1 2 3 4 (5 6 7 ''aaaaa 8 9) 10)'.
    ^list!

example7
    "LispParser example7."

    | list |
    list := LispParser parse: ' `(`(1 2 `3) . `4) '.    "`(`(1 2 `3) . `4) -> (quote ((quote (1 2 (quote 3))) quote 4))"
    ^list! !

!LispParser class methodsFor: 'private'!

makeStream: aStream 

    ^(aStream respondsTo: #next) "HACK"
	ifTrue: [aStream]
	ifFalse: [ReadStream on: aStream asString].! !

!LispParser class methodsFor: 'utilities'!

parse: aStream 
    ^self new parse: (self makeStream: aStream)!

parse: aStream ifFail: aBlock 
    ^self new parse: (self makeStream: aStream)
	ifFail: aBlock! !

!LispParser methodsFor: 'parsing'!

parse: sourceStream 
    | label string |
    ^self parse: sourceStream
	ifFail: 
	    [:errorMessage | 
	    label := errorMessage , ' near ' , (token printString contractTo: 20).
	    string := source upToEnd.
	    string isEmpty
		ifTrue: [string := '--> end of file']
		ifFalse: [string := '--> ' , (string contractTo: 30)].
	    self error: 'parse error   ', label, Character nl asString, string.
	    ^LispNil null]!

parse: sourceStream ifFail: aBlock 
    | result |
    self init: sourceStream ifFail: aBlock.
    result := self scan.
    ^result! !

!LispParser methodsFor: 'private'!

init: sourceStream ifFail: aBlock 
    super on: sourceStream.
    failBlock := aBlock! !

!LispParser methodsFor: 'scan and parse'!

scan
    source atEnd ifTrue: [^LispCons null].
    ^self scanList!

scanList
    | expression |
    self nextToken.
    tokenType == #eof ifTrue: [^LispCons null].
    tokenType == #number ifTrue: [^token].
    tokenType == #string ifTrue: [^token].
    tokenType == #object ifTrue: [^token].
    tokenType == #symbol ifTrue: [^token].
    tokenType == #quote
	ifTrue: 
	    [expression := LispCons head: self scanList tail: LispCons null.
	    ^LispCons head: #quote tail: expression].
    tokenType == #leftParenthesis ifTrue: [^self scanListAux].
    ^failBlock value: 'Syntax error'!

scanListAux
    | cdr |
    self nextToken.
    tokenType == #eof ifTrue: [^LispCons null].
    tokenType == #rightParenthesis ifTrue: [^LispCons null].
    tokenType == #leftParenthesis ifTrue: [^LispCons head: self scanListAux tail: self scanListAux].
    tokenType == #number ifTrue: [^LispCons head: token tail: self scanListAux].
    tokenType == #string ifTrue: [^LispCons head: token tail: self scanListAux].
    tokenType == #object ifTrue: [^LispCons head: token tail: self scanListAux].
    tokenType == #symbol ifTrue: [^LispCons head: token tail: self scanListAux].
    tokenType == #period
	ifTrue: 
	    [cdr := self scanList.
	    self nextToken.
	    tokenType == #rightParenthesis
		ifTrue: [^cdr]
		ifFalse: [^failBlock value: 'Syntax error']].
    tokenType == #quote
	ifTrue: 
	    [cdr := LispCons head: self scanList tail: LispCons null.
	    cdr := LispCons head: #quote tail: cdr.
	    ^LispCons head: cdr tail: self scanListAux].
    self unNextToken.
    ^failBlock value: 'Syntax error'! !

!LispParser methodsFor: 'scanning'!

nextToken
    prevMark := mark.
    prevToken := token.
    prevTokenType := tokenType.
    ^super nextToken!

unNextToken
    super unNextToken.
    mark := prevMark.
    token := prevToken.
    tokenType := prevTokenType! !



!LispTable class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispTable class methodsFor: 'instance creation'!

new
    ^super new initialize! !

!LispTable methodsFor: 'accessing'!

at: symbol 
    ^self getprop: symbol key: #apval!

at: symbol put: value 
    self intern: symbol.
    ^self
	putprop: symbol
	key: #apval
	value: value!

identifiers
    ^properties keys asSortedCollection! !

!LispTable methodsFor: 'adding'!

add: symbol 
    self intern: symbol! !

!LispTable methodsFor: 'initialize-release'!

initialize
    properties := Dictionary new! !

!LispTable methodsFor: 'private'!

errorSymbolNotFound
    self error: 'symbol not found'!

intern: symbol 
    (properties includesKey: symbol)
	ifFalse: [properties at: symbol put: Dictionary new].
    ^symbol! !

!LispTable methodsFor: 'property access'!

getprop: identifier key: key 
    | property |
    property := properties at: identifier ifAbsent: [^self errorSymbolNotFound].
    ^property at: key ifAbsent: [^nil]!

putprop: identifier key: key value: value 
    | property |
    property := properties at: identifier ifAbsent: [^self errorSymbolNotFound].
    ^property at: key put: value!

remprop: identifier key: key 
    | property |
    property := properties at: identifier ifAbsent: [^self errorSymbolNotFound].
    ^property removeKey: key ifAbsent: [^nil]! !

!LispTable methodsFor: 'removing'!

remove: symbol
    ^properties removeKey: symbol ifAbsent: [^nil]! !



!LispInterpreter class methodsFor: 'copyright'!

copyright
    ^'Copyright (C) 1995-1998 AOKI Atsushi, All Rights Reserved.'!

system
    ^'Goodies'!

version
    ^'003'! !

!LispInterpreter class methodsFor: 'examples'!

example01
    "LispInterpreter example01."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    nil

    '.
    ^aList!

example02
    "LispInterpreter example02."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    123

    '.
    ^aList!

example03
    "LispInterpreter example03."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    "abc"

    '.
    ^aList!

example04
    "LispInterpreter example04."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (cons 3 4)

    '.
    ^aList!

example05
    "LispInterpreter example05."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (quote (3 4))

    '.
    ^aList!

example06
    "LispInterpreter example06."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (car (quote (3 4)))

    '.
    ^aList!

example07
    "LispInterpreter example07."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (cdr (quote (3 4)))

    '.
    ^aList!

example08
    "LispInterpreter example08."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (cons (car `(1 2 3)) `(3 4))

    '.
    ^aList!

example09
    "LispInterpreter example09."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (+ 1 2 3 4 5 6 7 8 9 10)

    '.
    ^aList!

example10
    "LispInterpreter example10."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (progn
	(setq x 100)
	(setq y 200 z 300)
	(+ x y z))

    '.
    ^aList!

example11
    "LispInterpreter example11."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (progn
	(defun plus (x y) (+ x y))
	(plus 3 4))

    '.
    ^aList!

example12
    "LispInterpreter example12."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (progn
	(defun concat (x y) 
	    (cond
		((atom x) y)
		(t (cons
			(car x)
			(concat (cdr x) y)))))
	(concat `(1 2 3) `(4 5)))

    '.
    ^aList!

example13
    "LispInterpreter example13."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (progn
	(defun plus nlambda (x) (plus1 x))
	(defun plus1 lambda (x)
	    (cond
		((null x) 0)
		(t (+ (car x) (plus1 (cdr x))))))
	(plus 1 2 3 4 5 6 7 8 9 10))

    '.
    ^aList!

example14
    "LispInterpreter example14."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    ((lambda (x y) (cons x (cons y nil))) 3 4)

    '.
    ^aList!

example15
    "LispInterpreter example15."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    ((nlambda (x) x) 1 2 3 4 5 6 7 8 9 10)

    '.
    ^aList!

example16
    "LispInterpreter example16."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (progn
	(setq x 100)
	(setq y 200)
	(do
	    (x y)
	    (setq x 10000)
	    (setq y 20000)
	    (send {Transcript} `nl)
	    (send {Transcript} `show: (send x `printString))
	    (send {Transcript} `nl)
	    (send {Transcript} `show: (send y `printString)))
	(send {Transcript} `nl)
	(send {Transcript} `show: (send x `printString))
	(send {Transcript} `nl)
	(send {Transcript} `show: (send y `printString)))

    '.
    ^aList!

example17
    "LispInterpreter example17."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (do
	(count)
	(setq count 1)
	(while
	    (<= count 100)
	    do
	    (send {Transcript} `nl)
	    (send {Transcript} `show: (send count `printString))
	    (setq count (+ count 1))))

    '.
    ^aList!

example18
    "LispInterpreter example18."

    | aList |
    aList := LispInterpreter evaluateFrom: '

    (do
	(count)
	(setq count 1)
	(repeat
	    (send {Transcript} `nl)
	    (send {Transcript} `show: (send count `printString))
	    (setq count (+ count 1))
	    until
	    (<= count 100)))

    '.
    ^aList! !

!LispInterpreter class methodsFor: 'instance creation'!

new
    ^super new initialize! !

!LispInterpreter class methodsFor: 'printing'!

printString: anObject 
    "LispInterpreter printString: 'string'."
    "LispInterpreter printString: #symbol."
    "LispInterpreter printString: 123."
    "LispInterpreter printString: 123.456."
    "LispInterpreter printString: 123.456e7."
    "LispInterpreter printString: LispNil null."
    "LispInterpreter printString: nil."

    | aStream |
    aStream := WriteStream on: (String new: 32).
    (anObject isKindOf: LispCons)
	ifTrue: [anObject printOn: aStream level: 0]
	ifFalse: [LispCons new printOn: aStream object: anObject].
    ^aStream contents! !

!LispInterpreter class methodsFor: 'public access'!

evaluate: sExpression 
    ^self new evaluateTopLevel: sExpression ifFail: [:errorMessage | self error: errorMessage]!

evaluate: sExpression ifFail: aBlock 
    ^self new evaluateTopLevel: sExpression ifFail: aBlock!

evaluateFrom: aStream 
    ^self new evaluateTopLevel: (LispParser parse: aStream)
	ifFail: [:errorMessage | self error: errorMessage]!

evaluateFrom: aStream ifFail: aBlock 
    ^self new evaluateTopLevel: (LispCons parse: aStream ifFail: aBlock)
	ifFail: aBlock! !

!LispInterpreter methodsFor: 'accessing'!

textCollector
    ^textCollector!

textCollector: anObject
    textCollector := anObject! !

!LispInterpreter methodsFor: 'error handling'!

fatal: message 
    bindStack reverseDo: [:assoc | assoc key notNil ifTrue: [assoc value notNil
		ifTrue: [self
			putprop: assoc key
			key: #apval
			value: assoc value]
		ifFalse: [self remprop: assoc key key: #apval]]].
    ^failBlock value: '*** Error: ' , message! !

!LispInterpreter methodsFor: 'evaluating'!

evaluate: sExpression 
    | apval |
    (sExpression isKindOf: LispList)
	ifTrue: [^self listEvaluate: sExpression].
    (sExpression isKindOf: Symbol)
	ifTrue: 
	    [sExpression = #t ifTrue: [^#t].
	    lispTable intern: sExpression.
	    apval := lispTable getprop: sExpression key: #apval.
	    apval isNil ifTrue: [^self fatal: (self printString: sExpression)
			, ' is unbound atom'].
	    ^apval].
    ^sExpression!

evaluateTopLevel: sExpression 
    ^self evaluateTopLevel: sExpression ifFail:
	[:errorMessage | 
	Transcript show: errorMessage; nl.
	LispNil null]!

evaluateTopLevel: sExpression ifFail: aBlock 
    failBlock := aBlock.
    ^self evaluate: sExpression!

listEvaluate: sExpression 
    | funcName arguList funcBody |
    sExpression null ifTrue: [^sExpression].
    funcName := sExpression head.
    arguList := sExpression tail.
    (funcName isKindOf: LispCons)
	ifTrue: 
	    [funcBody := funcName.
	    funcBody head = #lambda
		ifTrue: 
		    [funcBody := LispCons head: #lambda tail: funcBody.
		    ^self exprEval: funcBody arguList: arguList].
	    funcBody head = #nlambda
		ifTrue: 
		    [funcBody := LispCons head: #nlambda tail: funcBody.
		    ^self fexprEval: funcBody arguList: arguList].
	    ^self fatal: 'unexpected function ' , (self printString: funcBody)].
    (funcName isKindOf: Symbol)
	ifFalse: [^self fatal: 'null function ' , (self printString: funcName)].
    funcBody := self getprop: funcName key: #fexpr.
    funcBody = LispNil null ifFalse: [^self fexprEval: funcBody arguList: arguList].
    funcBody := self getprop: funcName key: #expr.
    funcBody = LispNil null ifFalse: [^self exprEval: funcBody arguList: arguList].
    funcBody := self getprop: funcName key: #fsubr.
    funcBody = LispNil null ifFalse: [^self fsubrEval: funcBody arguList: arguList].
    funcBody := self getprop: funcName key: #subr.
    funcBody = LispNil null ifFalse: [^self subrEval: funcBody arguList: arguList].
    ^self fatal: 'undefined function ' , (self printString: funcName)! !

!LispInterpreter methodsFor: 'fsubr functions'!

fsubrAdd: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for +'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v + a]].
    ^v!

fsubrCond: arguList 
    | result |
    arguList do: [:each | (self evaluate: each head)
	    ~= LispNil null
	    ifTrue: 
		[result := LispNil null.
		(each tail isKindOf: LispCons)
		    ifTrue: [each tail do: [:expr | result := self evaluate: expr]].
		^result]].
    ^LispNil null!

fsubrDefun: arguList 
    | funcName funcType |
    funcName := arguList head.
    (funcName isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected function name ' , (self printString: funcName) , ' for defun'].
    funcType := arguList tail head.
    funcType = #lambda
	ifTrue: 
	    [self
		putprop: funcName
		key: #expr
		value: arguList.
	    ^funcName].
    funcType = #nlambda
	ifTrue: 
	    [self
		putprop: funcName
		key: #fexpr
		value: arguList.
	    ^funcName].
    self
	putprop: funcName
	key: #expr
	value: (LispCons head: funcName tail: (LispCons head: #lambda tail: arguList tail)).
    ^funcName!

fsubrDiv: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for /'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v / a]].
    ^v!

fsubrDo: arguList 
    | locals executions result |
    locals := arguList head.
    executions := arguList tail.
    self bindMark.
    locals do: [:lvar | self bind: lvar value: LispNil null].
    result := LispNil null.
    executions do: [:each | result := self evaluate: each].
    self unbind.
    ^result!

fsubrIdiv: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for //'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v // a]].
    ^v!

fsubrIf: arguList 
    | predicate then list truePart falsePart bool result |
    predicate := arguList head.
    then := arguList tail head.
    list := arguList tail tail.
    truePart := LispNil null.
    falsePart := LispNil null.
    bool := true.
    list do: [:each | each = #else
	    ifTrue: [bool := false]
	    ifFalse: [bool
		    ifTrue: [truePart := LispCons head: each tail: truePart]
		    ifFalse: [falsePart := LispCons head: each tail: falsePart]]].
    then = #then ifFalse: [^self fatal: 'unexpected format for if'].
    truePart := truePart reverse.
    falsePart := falsePart reverse.
    result := LispNil null.
    (self evaluate: predicate)
	= LispNil null
	ifTrue: [falsePart do: [:each | result := self evaluate: each]]
	ifFalse: [truePart do: [:each | result := self evaluate: each]].
    ^result!

fsubrMlt: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for *'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v * a]].
    ^v!

fsubrMod: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for \\'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v \\ a]].
    ^v!

fsubrProgn: arguList 
    | result |
    result := LispNil null.
    arguList do: [:each | result := self evaluate: each].
    ^result!

fsubrQuote: arguList
    ^arguList head!

fsubrRepeat: arguList 
    | reverse predicate until executions result |
    reverse := arguList reverse.
    predicate := reverse head.
    until := reverse tail head.
    executions := reverse tail tail reverse.
    until = #until ifFalse: [^self fatal: 'unexpected format for repeat'].
    result := LispNil null.
    executions do: [:each | result := self evaluate: each].
    [(self evaluate: predicate)
	= LispNil null]
	whileFalse: [executions do: [:each | result := self evaluate: each]].
    ^result!

fsubrSend: arguList 
    | list receiver selector arguments result |
    list := arguList.
    receiver := self evaluate: list head.
    list := list tail.
    selector := self evaluate: list head.
    (selector isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected selector ' , (self printString: selector) , ' for send'].
    list := list tail.
    arguments := OrderedCollection new.
    [list isKindOf: LispCons]
	whileTrue: 
	    [arguments add: (self evaluate: list head).
	    list := list tail].
    result := receiver perform: selector withArguments: arguments asArray.
    ^result!

fsubrSetq: arguList 
    | list a1 a2 |
    list := arguList.
    a2 := LispNil null.
    [list isKindOf: LispCons]
	whileTrue: 
	    [a1 := list head.
	    (a1 isKindOf: Symbol)
		ifFalse: [^self fatal: 'unexpected variable ' , (self printString: a1) , ' for setq'].
	    list := list tail.
	    a2 := self evaluate: list head.
	    self
		putprop: a1
		key: #apval
		value: a2.
	    list := list tail].
    ^a2!

fsubrSub: arguList 
    | v a |
    v := LispNil null.
    arguList
	do: 
	    [:each | 
	    a := self evaluate: each.
	    (a isKindOf: Number)
		ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a) , ' for -'].
	    v = LispNil null
		ifTrue: [v := a]
		ifFalse: [v := v - a]].
    ^v!

fsubrWhile: arguList 
    | predicate do executions result |
    predicate := arguList head.
    do := arguList tail head.
    executions := arguList tail tail.
    do = #do ifFalse: [^self fatal: 'unexpected format for while'].
    result := LispNil null.
    [(self evaluate: predicate)
	= LispNil null]
	whileFalse: [executions do: [:each | result := self evaluate: each]].
    ^result! !

!LispInterpreter methodsFor: 'func eval'!

exprEval: funcBody arguList: arguList 
    | expression funcName lvarList lvar result |
    expression := funcBody.
    funcName := expression head.
    expression := expression tail.
    expression := expression tail.
    lvarList := expression head.
    expression := expression tail.
    arguList length ~= lvarList length ifTrue: [^self fatal: 'too few or many arguments ' , (self printString: arguList) , ' vs ' , (self printString: lvarList) , ' for ' , funcName].
    self bindMark.
    arguList
	do: 
	    [:each | 
	    lvar := lvarList head.
	    self bind: lvar value: (self evaluate: each).
	    lvarList := lvarList tail].
    expression do: [:each | result := self evaluate: each].
    self unbind.
    ^result!

fexprEval: funcBody arguList: arguList 
    | expression funcName lvarList lvar result |
    expression := funcBody.
    funcName := expression head.
    expression := expression tail.
    expression := expression tail.
    lvarList := expression head.
    expression := expression tail.
    lvarList length ~= 1 ifTrue: [^self fatal: 'too few or many arguments ' , (self printString: lvarList) , ' for ' , (self printString: funcName)].
    self bindMark.
    lvar := lvarList head.
    self bind: lvar value: arguList.
    expression do: [:each | result := self evaluate: each].
    self unbind.
    ^result!

fsubrEval: funcBody arguList: arguList 
    | messageSelector |
    messageSelector := funcBody tail head.
    ^self perform: messageSelector with: arguList!

subrEval: funcBody arguList: arguList 
    | funcName messageSelector arguCount arguBuffer list |
    funcName := funcBody head.
    messageSelector := funcBody tail head.
    arguCount := funcBody tail tail head.
    arguBuffer := OrderedCollection new.
    list := arguList.
    arguCount
	timesRepeat: 
	    [list null ifTrue: [^self fatal: 'too few arguments for ' , (self printString: funcName)].
	    arguBuffer add: (self evaluate: list head).
	    list := list tail].
    list null not ifTrue: [^self fatal: 'too many arguments for ' , (self printString: funcName)].
    arguBuffer isEmpty
	ifTrue: [^self perform: messageSelector]
	ifFalse: [^self perform: messageSelector with: arguBuffer asArray]! !

!LispInterpreter methodsFor: 'initialize-release'!

initialize
    lispTable := LispTable new.
    bindStack := OrderedCollection new.
    failBlock := [:errorMessage | self error: errorMessage].
    textCollector := Transcript.
    self initializeSubrFunctions.
    self initializeFsubrFunctions.
    self initializeExprFunctions.
    self initializeFexprFunctions!

initializeExprFunctions
    self evaluateTopLevel: (LispParser parse: '

    % Expr Functions
    (progn

	% ++
	(defun ++ lambda (x)
	    (+ x 1))

	% --
	(defun -- lambda (x)
	    (- x 1))

	% assoc
	(defun assoc lambda (x a)
	    (cond
		((null a) nil)
		((equal x (car (car a))) (car a))
		(t (assoc x (cdr a)))))

	% copy
	(defun copy lambda (x)
	    (cond
		((null x) nil)
		(t (cons (car x) (copy (cdr x))))))

	% mapc
	(defun mapc lambda (f x)
	    (cond
		((null x) nil)
		(t (progn
		    (eval (cons f (cons `(car x) nil)))
		    (mapc f (cdr x))))))

	% mapcar
	(defun mapcar lambda (f x)
	    (cond
		((null x) nil)
		(t (cons
		    (eval (cons f (cons `(car x) nil)))
		    (mapcar f (cdr x))))))
	    
	) % end

    ')!

initializeFexprFunctions
    self evaluateTopLevel: (LispParser parse: '

    % Expr Functions
    (progn

	% and
	(defun and nlambda (x)
	    (do    (list)
		(setq list x)
		(while
		    (if (null list) then nil else (eval (car list)))
		    do
		    (setq list (cdr list)))
		(if (null list) then t else nil)))

	% list
	(defun list nlambda (x)
	    (mapcar `eval x))

	% or
	(defun or nlambda (x)
	    (do    (list)
		(setq list x)
		(while
		    (if (null list) then nil else (not (eval (car list))))
		    do
		    (setq list (cdr list)))
		(if (null list) then nil else t)))

	) % end

    ')!

initializeFsubrFunctions
    self setFsubrFunc: #(#* #fsubrMlt:).
    self setFsubrFunc: #(#+ #fsubrAdd:).
    self setFsubrFunc: #(#- #fsubrSub:).
    self setFsubrFunc: #(#/ #fsubrDiv:).
    self setFsubrFunc: #(#// #fsubrIdiv:).
    self setFsubrFunc: #(#cond #fsubrCond:).
    self setFsubrFunc: #(#defun #fsubrDefun:).
    self setFsubrFunc: #(#do #fsubrDo:).
    self setFsubrFunc: #(#if #fsubrIf:).
    self setFsubrFunc: #(#progn #fsubrProgn:).
    self setFsubrFunc: #(#quote #fsubrQuote:).
    self setFsubrFunc: #(#repeat #fsubrRepeat:).
    self setFsubrFunc: #(#send #fsubrSend:).
    self setFsubrFunc: #(#setq #fsubrSetq:).
    self setFsubrFunc: #(#while #fsubrWhile:).
    self setFsubrFunc: #(#\\ #fsubrMod:).!

initializeSubrFunctions
    self setSubrFunc: #(#< #subrLt: 2).
    self setSubrFunc: #(#<= #subrLe: 2).
    self setSubrFunc: #(#= #subrEqual: 2).
    self setSubrFunc: #(#== #subrEq: 2).
    self setSubrFunc: #(#> #subrGt: 2).
    self setSubrFunc: #(#>= #subrGe: 2).
    self setSubrFunc: #(#append #subrAppend: 2).
    self setSubrFunc: #(#atom #subrAtom: 1).
    self setSubrFunc: #(#car #subrCar: 1).
    self setSubrFunc: #(#cdr #subrCdr: 1).
    self setSubrFunc: #(#cons #subrCons: 2).
    self setSubrFunc: #(#consp #subrConsp: 1).
    self setSubrFunc: #(#dtpr #subrConsp: 1).
    self setSubrFunc: #(#doublep #subrDoublep: 1).
    self setSubrFunc: #(#eq #subrEq: 2).
    self setSubrFunc: #(#equal #subrEqual: 2).
    self setSubrFunc: #(#eval #subrEval: 1).
    self setSubrFunc: #(#exprs #subrExprs 0).
    self setSubrFunc: #(#fexprs #subrFexprs 0).
    self setSubrFunc: #(#floatp #subrFloatp: 1).
    self setSubrFunc: #(#fsubrs #subrFsubrs 0).
    self setSubrFunc: #(#gc #subrGc 0).
    self setSubrFunc: #(#gensym #subrGensym 0).
    self setSubrFunc: #(#getprop #subrGetprop: 2).
    self setSubrFunc: #(#integerp #subrIntegerp: 1).
    self setSubrFunc: #(#last #subrLast: 1).
    self setSubrFunc: #(#length #subrLength: 1).
    self setSubrFunc: #(#listp #subrListp: 1).
    self setSubrFunc: #(#member #subrMember: 2).
    self setSubrFunc: #(#memq #subrMemq: 2).
    self setSubrFunc: #(#nconc #subrNconc: 2).
    self setSubrFunc: #(#neq #subrNeq: 2).
    self setSubrFunc: #(#nequal #subrNequal: 2).
    self setSubrFunc: #(#not #subrNull: 1).
    self setSubrFunc: #(#nth #subrNth: 2).
    self setSubrFunc: #(#null #subrNull: 1).
    self setSubrFunc: #(#numberp #subrNumberp: 1).
    self setSubrFunc: #(#oblist #subrOblist 0).
    self setSubrFunc: #(#pp #subrPp: 1).
    self setSubrFunc: #(#princ #subrPrinc: 1).
    self setSubrFunc: #(#print #subrPrint: 1).
    self setSubrFunc: #(#putprop #subrPutprop: 3).
    self setSubrFunc: #(#remprop #subrRemprop: 2).
    self setSubrFunc: #(#reverse #subrReverse: 1).
    self setSubrFunc: #(#rplaca #subrRplaca: 2).
    self setSubrFunc: #(#rplacd #subrRplacd: 2).
    self setSubrFunc: #(#stringp #subrStringp: 1).
    self setSubrFunc: #(#subrs #subrSubrs 0).
    self setSubrFunc: #(#symbolp #subrSymbolp: 1).
    self setSubrFunc: #(#terpri #subrTerpri 0).
    self setSubrFunc: #(#~= #subrNequal: 2).
    self setSubrFunc: #(#~~ #subrNeq: 2)! !

!LispInterpreter methodsFor: 'printing'!

printString: anObject 
    ^self class printString: anObject! !

!LispInterpreter methodsFor: 'private'!

setFsubrFunc: bodyArray 
    self
	putprop: (bodyArray at: 1) asSymbol
	key: #fsubr
	value: (LispCons list: bodyArray)!

setSubrFunc: bodyArray 
    self
	putprop: (bodyArray at: 1) asSymbol
	key: #subr
	value: (LispCons list: bodyArray)! !

!LispInterpreter methodsFor: 'property access'!

getprop: identifier key: key 
    | value |
    lispTable intern: identifier.
    value := lispTable getprop: identifier key: key.
    value isNil ifTrue: [^LispNil null].
    ^value!

putprop: identifier key: key value: value 
    lispTable intern: identifier.
    ^lispTable
	putprop: identifier
	key: key
	value: value!

remprop: identifier key: key 
    | value |
    lispTable intern: identifier.
    value := lispTable remprop: identifier key: key.
    value isNil ifTrue: [^LispNil null].
    ^value! !

!LispInterpreter methodsFor: 'shallow binding'!

bind: symbol value: value 
    | saveValue assoc |
    lispTable intern: symbol.
    saveValue := lispTable getprop: symbol key: #apval.
    assoc := Association key: symbol value: saveValue.
    bindStack addLast: assoc.
    self
	putprop: symbol
	key: #apval
	value: value!

bindMark
    | assoc |
    assoc := Association key: nil value: nil.
    bindStack addLast: assoc!

unbind
    | assoc |
    
    [assoc := bindStack removeLast.
    assoc key notNil]
	whileTrue: [assoc value notNil
		ifTrue: [self
			putprop: assoc key
			key: #apval
			value: assoc value]
		ifFalse: [self remprop: assoc key key: #apval]]! !

!LispInterpreter methodsFor: 'subr functions'!

subrAppend: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for append'].
    (a2 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for append'].
    ^a1 append: a2!

subrAtom: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: LispCons) ifFalse: [^#t].
    ^LispNil null!

subrCar: arguArray 
    | list |
    list := arguArray at: 1.
    (list isKindOf: LispCons)
	ifTrue: [^list head].
    (list isKindOf: LispNil)
	ifTrue: [^LispNil null].
    ^self fatal: 'unexpected argument ' , (self printString: list) , ' for car'!

subrCdr: arguArray 
    | list |
    list := arguArray at: 1.
    (list isKindOf: LispCons)
	ifTrue: [^list tail].
    (list isKindOf: LispNil)
	ifTrue: [^LispNil null].
    ^self fatal: 'unexpected argument ' , (self printString: list) , ' for cdr'!

subrCons: arguArray 
    ^LispCons head: (arguArray at: 1)
	tail: (arguArray at: 2)!

subrConsp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: LispCons)
	ifTrue: [^#t].
    ^LispNil null!

subrDoublep: arguArray 
    | a1 |
    ^self subrFloatp: arguArray
    "a1 := arguArray at: 1.
    (a1 isKindOf: Double)
	ifTrue: [^#t].
    ^LispNil null"!

subrEq: arguArray 
    | bool |
    (arguArray at: 1)
	== (arguArray at: 2)
	ifTrue: [bool := #t]
	ifFalse: [bool := LispNil null].
    ^bool!

subrEqual: arguArray 
    | bool |
    (arguArray at: 1)
	= (arguArray at: 2)
	ifTrue: [bool := #t]
	ifFalse: [bool := LispNil null].
    ^bool!

subrEval: arguArray 
    ^self evaluate: (arguArray at: 1)!

subrExprs
    | list |
    list := LispNil null.
    self subrOblist reverse do: [:id | (self getprop: id key: #expr)
	    = LispNil null ifFalse: [list := LispCons head: id tail: list]].
    ^list!

subrFexprs
    | list |
    list := LispNil null.
    self subrOblist reverse do: [:id | (self getprop: id key: #fexpr)
	    = LispNil null ifFalse: [list := LispCons head: id tail: list]].
    ^list!

subrFloatp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: Float)
	ifTrue: [^#t].
    ^LispNil null!

subrFsubrs
    | list |
    list := LispNil null.
    self subrOblist reverse do: [:id | (self getprop: id key: #fsubr)
	    = LispNil null ifFalse: [list := LispCons head: id tail: list]].
    ^list!

subrGc
    "ObjectMemory globalCompactingGC."
    Smalltalk compact.
    Transcript nl; show: 'garbage collecting'.
    ^#t!

subrGe: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for >='].
    (a2 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for >='].
    a1 >= a2 ifTrue: [^#t].
    ^LispNil null!

subrGensym
    | clock |
    (Delay forMilliseconds: 1) wait.
    clock := Time millisecondClockValue.
    ^('id' , clock printString) asSymbol!

subrGetprop: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for getprop'].
    (a2 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for getprop'].
    ^self getprop: a1 key: a2!

subrGt: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for >'].
    (a2 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for >'].
    a1 > a2 ifTrue: [^#t].
    ^LispNil null!

subrIntegerp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: Integer)
	ifTrue: [^#t].
    ^LispNil null!

subrLast: arguArray 
    | list |
    list := arguArray at: 1.
    (list isKindOf: LispCons)
	ifTrue: [^list last].
    ^self fatal: 'unexpected argument ' , (self printString: list) , ' for last'!

subrLe: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for <='].
    (a2 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for <='].
    a1 <= a2 ifTrue: [^#t].
    ^LispNil null!

subrLength: arguArray 
    | list |
    list := arguArray at: 1.
    (list isKindOf: LispCons)
	ifTrue: [^list length].
    ^self fatal: 'unexpected argument ' , (self printString: list) , ' for length'!

subrListp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: LispList)
	ifTrue: [^#t].
    ^LispNil null!

subrLt: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for <'].
    (a2 isKindOf: LispList)
	ifTrue: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for <'].
    a1 < a2 ifTrue: [^#t].
    ^LispNil null!

subrMember: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a2 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for member'].
    ^a2 member: a1!

subrMemq: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a2 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for memq'].
    ^a2 memq: a1!

subrNconc: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for nconc'].
    a1 nconc: a2.
    ^a1!

subrNeq: arguArray 
    | bool |
    ((arguArray at: 1)
	== (arguArray at: 2)) not
	ifTrue: [bool := #t]
	ifFalse: [bool := LispNil null].
    ^bool!

subrNequal: arguArray 
    | bool |
    ((arguArray at: 1)
	= (arguArray at: 2)) not
	ifTrue: [bool := #t]
	ifFalse: [bool := LispNil null].
    ^bool!

subrNth: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: Number)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for nth'].
    (a2 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for nth'].
    ^a2 nth: a1!

subrNull: arguArray 
    ((arguArray at: 1)
	isMemberOf: LispNil)
	ifTrue: [^#t].
    ^LispNil null!

subrNumberp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: Number)
	ifTrue: [^#t].
    ^LispNil null!

subrOblist
    | list |
    list := LispNil null.
    lispTable identifiers reverseDo: [:each | list := LispCons head: each tail: list].
    ^list!

subrPp: arguArray 
    | a pretty |
    a := arguArray at: 1.
    pretty := a ppString.
    textCollector show: pretty.
    ^a!

subrPrinc: arguArray 
    | a |
    a := arguArray at: 1.
    (a isKindOf: String)
	ifTrue: [textCollector show: a]
	ifFalse: [textCollector show: (self printString: a)].
    ^a!

subrPrint: arguArray 
    | a |
    a := self subrPrinc: arguArray.
    textCollector nl.
    ^a!

subrPutprop: arguArray 
    | a1 a2 a3 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    a3 := arguArray at: 3.
    (a1 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for putprop'].
    (a2 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for putprop'].
    ^self
	putprop: a1
	key: a2
	value: a3!

subrRemprop: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for remprop'].
    (a2 isKindOf: Symbol)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for remprop'].
    ^self remprop: a1 key: a2!

subrReverse: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a1) , ' for reverse'].
    ^a1 reverse!

subrRplaca: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for rplaca'].
    a1 rplaca: a2.
    ^a1!

subrRplacd: arguArray 
    | a1 a2 |
    a1 := arguArray at: 1.
    a2 := arguArray at: 2.
    (a1 isKindOf: LispCons)
	ifFalse: [^self fatal: 'unexpected argument ' , (self printString: a2) , ' for rplacd'].
    a1 rplacd: a2.
    ^a1!

subrStringp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    ((a1 isKindOf: String)
	and: [(a1 isKindOf: Symbol) not])
	ifTrue: [^#t].
    ^LispNil null!

subrSubrs
    | list |
    list := LispNil null.
    self subrOblist reverse do: [:id | (self getprop: id key: #subr)
	    = LispNil null ifFalse: [list := LispCons head: id tail: list]].
    ^list!

subrSymbolp: arguArray 
    | a1 |
    a1 := arguArray at: 1.
    (a1 isKindOf: Symbol) ifTrue: [^#t].
    ^LispNil null!

subrTerpri
    textCollector nl.
    ^#t! !