File: Man.st

package info (click to toggle)
gnu-smalltalk 3.2.4-2.1
  • links: PTS, VCS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 32,688 kB
  • ctags: 14,104
  • sloc: ansic: 87,424; sh: 22,729; asm: 8,465; perl: 4,513; cpp: 3,548; xml: 1,669; awk: 1,581; yacc: 1,357; makefile: 1,237; lisp: 855; lex: 843; sed: 258; objc: 124
file content (427 lines) | stat: -rw-r--r-- 9,300 bytes parent folder | download | duplicates (6)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
"======================================================================
|
|   BLOX man page viewer
|
|
 ======================================================================"

 
"======================================================================
|
| Copyright 1999 Free Software Foundation, Inc.
| Written by Paolo Bonzini.
|
| This file is part of GNU Smalltalk.
|
| GNU Smalltalk is free software; you can redistribute it and/or modify it
| under the terms of the GNU General Public License as published by the Free
| Software Foundation; either version 2, or (at your option) any later version.
| 
| GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
| ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
| FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
| details.
| 
| You should have received a copy of the GNU General Public License along with
| GNU Smalltalk; see the file LICENSE.  If not, write to the Free Software
| Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.  
|
 ======================================================================"

PackageLoader fileInPackage: 'Blox'!
Namespace current: BLOX!

BExtended subclass: #ManViewer
    instanceVariableNames: 'input separator label'
    classVariableNames: 'OpenParenExpansions'
    poolDictionaries: ''
    category: 'Graphics-Examples'!

!ManViewer class methodsFor: 'initializing'!

initialize
    OpenParenExpansions := Dictionary new
	at: 'em' put: ' -- ';
	at: 'en' put: ' - ';
	at: 'lq' put: $` asString;
	at: 'rq' put: $' asString;
	yourself
! !

!ManViewer class methodsFor: 'starting'!

openOn: fileName
    | window text |
    window := BWindow new.
    window width: 560 height: 300.

    text := self new: window.
    [ text parse: (FileStream open: fileName mode: FileStream read) ]
	ifCurtailed: [ window destroy ].

    window label: text label.

    window map.
    Blox idle.
    window activate.
    text activate.

    Blox dispatchEvents: window
! !

!ManViewer methodsFor: 'accessing'!

label
    ^label ifNil: [ 'Man page viewer' ]
!

newPrimitive
    ^(BText new: self parent)
	font: self normal font;
	yourself
!

parse: stream
    input := stream.
    separator := ''.
    [ stream atEnd ] whileFalse: [
	self parseLine: (stream upTo: Character nl)
    ].
    input close.
    input := nil.

    self primitive gotoLine: 1 end: false
!

text: string
    self parse: (ReadStream on: string)
! !

!ManViewer methodsFor: 'private - gui'!

label: string
    label := string
!

insert: line fonts: fonts
    | attributes font |
    font := 2.
    attributes := fonts collect: [ :each | self perform: each ].

    self primitive insertAtEnd: separator.
    separator := ''.
    self breakIntoArguments: line do: [ :each |
	font := 3 - font.
	self primitive
	    insertAtEnd: (each copyWith: Character space)
	    attribute: (attributes at: font)
    ]
!

insertEndSpace: line fonts: fonts
    | attributes font |
    font := 2.
    attributes := fonts collect: [ :each | self perform: each ].

    self primitive insertAtEnd: separator.
    separator := ''.
    self breakIntoArguments: line do: [ :each |
	font := 3 - font.
	self primitive
	    insertAtEnd: each
	    attribute: (attributes at: font)
    ].
    self primitive space
!

nl
    self primitive nl
! !

!ManViewer methodsFor: 'fonts'!

big
    ^BTextAttributes font: 'Courier 9 bold italic'
!

bold
    ^BTextAttributes font: 'Courier 9 bold'
!

italic
    ^BTextAttributes font: 'Courier 9 italic'
!

normal
    ^BTextAttributes font: 'Courier 9'
!

separatePara
    ^(String new: 2) atAllPut: Character nl; yourself
! !

!ManViewer methodsFor: 'parsing'!

dispatch: directive line: line
    "Parse a line in the format `.<directive> <line>' "
    | symbol |
    directive = '\"' ifTrue: [ ^self ].
    symbol := ('parse', directive asUppercase, ':') asSymbol.

    (self class includesSelector: symbol)
	ifTrue: [ self perform: symbol with: line ]
!

parseLine: line
    | directive |
    line isEmpty ifTrue: [ ^self ].

    (line at: 1) = $.
	ifFalse: [
	    self parseQuoted: line.
	]
	ifTrue: [ 
	    line size < 3 ifTrue: [ ^self ].
	    directive := (line at: 3) = Character space
		ifTrue: [ (line copyFrom: 2 to: 2) ]
		ifFalse: [ (line copyFrom: 2 to: 3) ].

	    self dispatch: directive line: line.
	]
!

breakIntoArguments: line do: aBlock
    | stream argument |
    stream := ReadStream on: line.
    [ stream atEnd ifTrue: [ ^self ]. stream peek isSeparator ]
	 whileFalse: [ stream next ].

    [
	[ stream atEnd ifTrue: [ ^self ]. stream peek isSeparator ]
	    whileTrue: [ stream next ].
	stream atEnd
    ]   whileFalse: [
	argument := (stream peekFor: $")
	    ifTrue: [ self upToQuote: stream ]
	    ifFalse: [ self nextWord: stream ].

	aBlock value: argument
    ].
!

nextWord: line
    | ws ch |
    ws := WriteStream on: (String new: 10).
    [ line atEnd or: [ (ch := line next) isSeparator ] ] whileFalse: [
	ch = $\
	    ifTrue: [ self parseQuoted: line on: ws ]
	    ifFalse: [ ws nextPut: ch ]
    ].
    ^ws contents
!

upToQuote: line
    | ws ch |
    ws := WriteStream on: (String new: 10).
    [ line atEnd or: [ (ch := line next) == $" ] ] whileFalse: [
	ch = $\
	    ifTrue: [ self parseQuoted: line on: ws ]
	    ifFalse: [ ws nextPut: ch ]
    ].
    ^ws contents
!

parseQuoted: line
    | stream |
    self primitive insertAtEnd: separator.
    stream := ReadStream on: line.
    [ stream atEnd ifTrue: [ ^self ].
      stream next isSeparator ] whileTrue: [ ].
    
    stream skip: -1.
    self parseQuotedStream: stream size: line size.
    separator := ' '.
!

parseQuotedStream: stream size: size
    | ws ch newFont font |
    font := self normal.
    ws := WriteStream on: (String new: size).

    [ stream atEnd ] whileFalse: [
	ch := stream next.
	ch = $\
	    ifFalse: [ ws nextPut: ch ]
	    ifTrue: [
		newFont := self parseQuoted: stream on: ws.
		newFont isNil ifFalse: [
		    self primitive
			insertAtEnd: ws contents
	 		attribute: font.
		    font := self perform: newFont.
	  	    ws reset.
		]
	    ]
    ].
    self primitive
	insertAtEnd: (self rtrimSeparators: ws contents)
	attribute: font
!

parseQuoted: line on: ws 
    | ch s |
    line atEnd ifTrue: [ ^nil ].
    ch := line next.

    ch == $* ifTrue: [
	line atEnd ifTrue: [ ^nil ].
	ch := line next
    ].
    ch == $& ifTrue: [ ws nextPut: line next. ^nil ].
    ch == $( ifTrue: [
	line atEnd ifTrue: [ ^nil ].
	s := String with: line next.
	line atEnd ifTrue: [ ^nil ].
	s := s copyWith: line next.
	s := OpenParenExpansions at: s ifAbsent: [ ^nil ].
	ws nextPutAll: s.
	^nil
    ].
    ch == $c ifTrue: [ ^nil ].
    ch == $d ifTrue: [ ^nil ].
    ch == $^ ifTrue: [ ^nil ].
    ch == $| ifTrue: [ ^nil ].
    ch == $e ifTrue: [ ws nextPut: $\. ^nil ].

    ch == $f ifTrue: [
	line atEnd ifTrue: [ ^nil ].
	ch := line next.
	ch == $B ifTrue: [ ^#bold ].
	ch == $I ifTrue: [ ^#italic ].
	ch == $P ifTrue: [ ^#normal ].
	ch == $R ifTrue: [ ^#normal ].
    ].
    (ch == $s) ifFalse: [ ws nextPut: ch. ^nil ].

    [ line atEnd ifTrue: [ ^nil ]. line peek isDigit ]
	whileFalse: [ line next ].
    [ line atEnd ifTrue: [ ^nil ]. line peek isDigit ]
	whileTrue: [ line next ].
    ^nil
!

rtrimSeparators: line
    | size last |
    size := line size.
    last := line findLast: [ :each | each isSeparator not ].
    
    ^last = 0
	ifTrue: [ line ]
	ifFalse: [ line copyFrom: 1 to: last ]
! !

!ManViewer methodsFor: 'man macros'!

parseTH: line
    | first second |
    self breakIntoArguments: line do: [ :each |
	second isNil ifFalse: [
	    self label: 'Viewing ', first, '(', second, ') man page'.
	    ^self
	].
	first isNil
	    ifTrue: [ first := each asLowercase ]
	    ifFalse: [ second := each ]
    ].
!

parseSH: line
    separator := self separatePara.
    self insert: line fonts: #(#big #big).
    separator := Character nl asString.
!

parseSS: line
    self nl; insert: line fonts: #(#bold #bold); nl
!

parseBI: line
    self insertEndSpace: line fonts: #(#bold #italic)
!

parseB: line
    self insert: line fonts: #(#bold #bold)
!

parseBR: line
    self insertEndSpace: line fonts: #(#bold #normal)
!

parseSP: line
    separator := Character nl asString.
!

parseNL: line
    separator := Character nl asString.
!

parseBR: line
    separator := Character nl asString.
!

parsePD: line
    "not supported"
!

parsePP: line
    separator := self separatePara.
!

parseLP: line
    separator := self separatePara.
!

parseTP: line
    separator := Character nl asString.
!

parseIP: line
    separator := Character nl asString.
    self insert: line, '   ' fonts: #(#bold #bold)
!

parseI: line
    self insert: line fonts: #(#italic #italic)
!

parseIB: line
    self insertEndSpace: line fonts: #(#italic #bold)
!

parseIR: line
    self insertEndSpace: line fonts: #(#italic #normal)
!

parseRI: line
    self insertEndSpace: line fonts: #(#normal #italic)
!

parseRB: line
    self insertEndSpace: line fonts: #(#normal #bold)
!

parseSB: line
    self insertEndSpace: line fonts: #(#normal #bold)
!

parseNormal: line
    self insert: line fonts: #(#normal #normal)
!

parseSM: line
    self insert: line fonts: #(#normal #normal)
! !

ManViewer initialize!

Namespace current: Smalltalk!