1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
|
"======================================================================
|
| Examples of CompiledMethod subclasses
|
|
======================================================================"
"======================================================================
|
| Copyright 2006, 2007 Free Software Foundation, Inc.
| Written by Paolo Bonzini.
|
| This file is part of the GNU Smalltalk class library.
|
| The GNU Smalltalk class library is free software; you can redistribute it
| and/or modify it under the terms of the GNU Lesser General Public License
| as published by the Free Software Foundation; either version 2.1, or (at
| your option) any later version.
|
| The GNU Smalltalk class library is distributed in the hope that it will be
| useful, but WITHOUT ANY WARRANTY; without even the implied warranty of
| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser
| General Public License for more details.
|
| You should have received a copy of the GNU Lesser General Public License
| along with the GNU Smalltalk class library; see the file COPYING.LIB.
| If not, write to the Free Software Foundation, 59 Temple Place - Suite
| 330, Boston, MA 02110-1301, USA.
|
======================================================================"
"Inspired by example code from idst-5.7, by Ian Piumarta"
CompiledMethod subclass: #InterpretedMethod
instanceVariableNames: 'bytecodes'
classVariableNames: ''
poolDictionaries: ''
category: 'Examples-VM'!
!InterpretedMethod class methodsFor: 'testing'!
test
"InterpretedMethod test"
| b |
b := Behavior new.
b superclass: Object.
b interpretedMethodAt: #testInterp1 put: #(#push 3 #push 4 #add #return).
b interpretedMethodAt: #testInterp2 put: #(#push 6 #push 7 #mul #return).
Transcript show: '3 + 4 = '. b new testInterp1 printNl.
Transcript show: '6 * 7 = '. b new testInterp2 printNl.
b interpretedMethodAt: #testInterp1 put: #(#push 3 #push 4 #mul #return).
b interpretedMethodAt: #testInterp2 put: #(#push 6 #push 7 #add #return).
Transcript show: '3 * 4 = '. b new testInterp1 printNl.
Transcript show: '6 + 7 = '. b new testInterp2 printNl!
!InterpretedMethod class methodsFor: 'instance creation'!
numArgs: args bytecodes: bc
^(self numArgs: args) bytecodes: bc; yourself! !
!InterpretedMethod methodsFor: 'executing'!
bytecodes: anArray
bytecodes := anArray!
valueWithReceiver: rec withArguments: args
| stack pc insn a b |
pc := 0.
stack := OrderedCollection new.
stack addLast: rec.
stack addAllLast: args.
[
insn := bytecodes at: (pc := pc + 1).
insn == #push ifTrue: [
stack addLast: (bytecodes at: (pc := pc + 1)) ].
insn == #add ifTrue: [
a := stack removeLast.
b := stack removeLast.
stack addLast: a + b ].
insn == #mul ifTrue: [
a := stack removeLast.
b := stack removeLast.
stack addLast: a * b ].
insn == #return ifTrue: [^stack last]
] repeat! !
!Behavior methodsFor: 'methods'!
interpretedMethodAt: aSelector put: bytecodes
^self
addSelector: aSelector
withMethod: (InterpretedMethod numArgs: aSelector numArgs bytecodes: bytecodes)
! !
CompiledMethod subclass: #ForwardingMethod
instanceVariableNames: 'destClass destSelector'
classVariableNames: ''
poolDictionaries: ''
category: 'Examples-VM'!
!ForwardingMethod class methodsFor: 'testing'!
test
| foo bar |
foo := Behavior new.
foo superclass: Object.
foo compile: 'one: a [ (''foo one'' -> a) printNl ]'.
foo compile: 'two: a [ (''foo two'' -> a) printNl. self one: a ]'.
bar := Behavior new.
bar superclass: Object.
bar compile: 'one: a [ (''bar one'' -> a) printNl ]'.
bar addSelector: #two: withMethod: (ForwardingMethod to: foo -> #two:).
foo new two: 1.
bar new two: 2! !
!ForwardingMethod class methodsFor: 'instance creation'!
to: anAssociation
^(self numArgs: anAssociation value numArgs)
destClass: anAssociation key;
destSelector: anAssociation value;
yourself!
!ForwardingMethod methodsFor: 'forwarding'!
destClass
^destClass!
destSelector
^destSelector!
destClass: anObject
destClass := anObject!
destSelector: aSymbol
destSelector := aSymbol!
valueWithReceiver: rec withArguments: args
| method |
method := destClass lookupSelector: destSelector.
^method isNil
ifTrue: [
rec doesNotUnderstand:
(Message selector: self selector arguments: args) ]
ifFalse: [
rec perform: method withArguments: args ]! !
CompiledMethod subclass: #MethodWrapper
instanceVariableNames: 'method methodClass selector'
classVariableNames: 'WrapperList'
poolDictionaries: ''
category: 'Examples-VM'!
!MethodWrapper class methodsFor: 'testing'!
readdWrappersAfter: aWrapper
| all index toAdd |
all := self wrappersFor: aWrapper basicMethod.
index := all identityIndexOf: aWrapper.
toAdd := all copyFrom: index + 1.
all empty.
toAdd do: [ :each | each install ]
!
recordWrapper: aWrapper
(self wrappersFor: aWrapper basicMethod) addLast: aWrapper
!
wrappersFor: aMethod
WrapperList isNil ifTrue: [ WrapperList := IdentityDictionary new ].
^WrapperList at: aMethod ifAbsentPut: [ OrderedCollection new ]
! !
!MethodWrapper methodsFor: 'wrapping'!
beforeMethod
!
afterMethod
!
valueWithReceiver: rec withArguments: args
self beforeMethod.
^[ rec perform: method withArguments: args ]
ensure: [ self afterMethod ]
! !
!CompiledCode methodsFor: 'installing'!
basicMethod
^self
! !
!MethodWrapper methodsFor: 'installing'!
basicMethod
^method basicMethod
!
install
method := self methodClass lookupSelector: selector.
method isNil ifTrue: [ self error: 'cannot find method' ].
self methodClass methodDictionary at: selector put: self.
self class recordWrapper: self.
!
uninstall
method methodClass == self methodClass
ifTrue: [ self methodDictionary at: selector put: method ]
ifFalse: [ self methodDictionary removeKey: selector ifAbsent: [] ].
self class readdWrappersAfter: self.
method := nil.
!
isInstalled
^method notNil
!
methodClass
^methodClass
!
methodDictionary
^methodClass methodDictionary
!
methodClass: aClass
methodClass := aClass
!
selector: aSymbol
selector := aSymbol
! !
!MethodWrapper class methodsFor: 'instance creation'!
on: aSymbol in: aClass
^(self numArgs: aSymbol numArgs)
selector: aSymbol;
methodClass: aClass;
yourself! !
MethodWrapper subclass: #WrapperExample
instanceVariableNames: 'text'
classVariableNames: 'WrapperList'
poolDictionaries: ''
category: 'Examples-VM'!
!WrapperExample class methodsFor: 'installing'!
test
| a b |
a := WrapperExample on: #asArray in: String.
b := WrapperExample on: #asArray in: String.
(a isInstalled->b isInstalled) printNl.
(String includesSelector: #asArray) printNl.
a install: 'wrapper1'.
(a isInstalled->b isInstalled) printNl.
(String includesSelector: #asArray) printNl.
'abc' asArray.
b install: 'wrapper2'.
(a isInstalled->b isInstalled) printNl.
(String includesSelector: #asArray) printNl.
'abc' asArray.
a uninstall.
(a isInstalled->b isInstalled) printNl.
(String includesSelector: #asArray) printNl.
'abc' asArray.
b uninstall.
(a isInstalled->b isInstalled) printNl.
(String includesSelector: #asArray) printNl.
'abc' asArray.
! !
!WrapperExample methodsFor: 'installing'!
install: aString
text := aString.
self install
!
beforeMethod
('before ', text) printNl
!
afterMethod
('after ', text) printNl
! !
InterpretedMethod test!
ForwardingMethod test!
WrapperExample test!
|
