File: pepe.sed

package info (click to toggle)
gnu-smalltalk 3.2.4-2.1
  • links: PTS, VCS
  • area: main
  • in suites: jessie, jessie-kfreebsd
  • size: 32,688 kB
  • ctags: 14,104
  • sloc: ansic: 87,424; sh: 22,729; asm: 8,465; perl: 4,513; cpp: 3,548; xml: 1,669; awk: 1,581; yacc: 1,357; makefile: 1,237; lisp: 855; lex: 843; sed: 258; objc: 124
file content (72 lines) | stat: -rwxr-xr-x 1,250 bytes parent folder | download | duplicates (7)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
#! /bin/sed -nf

$a\
!

/^PepeImage installMethodWithSelector:/! {
  /./ {
    # Print the last method category
    x
    s/''/'/g
    /./p
    s/.*//p
    x
  }

  s/^PepeImage installClassWithName: '\([^']*\)' superclassName: '\([^']*\)' classVariableNames: '\([^']*\)' instanceVariableNames: '\([^']*\)'\.$/\2 subclass: #\1\
    instanceVariableNames: '\4'\
    classVariableNames: '\3'\
    poolDictionaries: ''\
    category: ''!/

  /./p
  b
}

# Concatenate a full Pepe command into hold space
:a
H 
/^\(.*[^']\)\{0,1\}\(''\)*'\.$/! {
  n
  ba
}

#---------- Process method declarations

x
s/^\n*//

# If hold space is empty, just insert the definition
/methodsFor:/! bt

# Check if we can merge the two methods
tx
:x
s/^\(!\([^ ]*\( class\)\{0,1\}\) methodsFor: nil!\([^!]*!\)*\) !\nPepeImage installMethodWithSelector: '\([^']*\)' inClassWithName: '\2' source: '\(.*\)'\.$/\1\
\
\6! !/

tz

#-------

# No, print the first category  
i\

h
s/\nPepeImage.*//
s/''/'/g
p

g
s/^\([^\n]*\n\)*PepeImage/PepeImage/

:t
s/^PepeImage installMethodWithSelector: '\([^']*\)' inClassWithName: '\([^']*\)' source: '\(.*\)'\.\(\nPepeImage installMethodWithSelector:\|$\)/\
!\2 methodsFor: nil!\
\
\3! !\4/

# And put the second back into hold space
:z
x